
Up Up và Array!
Công thức mảng động cho Excel 365 và hơn thế nữa

Ấn phẩm Apress này được xuất bản bởi công ty đã đăng ký APress Media, LLC, một phần của Springer Nature.
Địa chỉ công ty đã đăng ký là: 1 New York Plaza, New York, NY 10004, U.S.A.
Dành tặng cho những người dùng bảng tính sẵn sàng bước tiếp.
Đã bốn năm kể từ khi Microsoft Excel giới thiệu một bộ hàm cho Excel 365, mở ra một cách suy nghĩ và viết công thức hoàn toàn mới. Được gọi là các hàm mảng động (dynamic array functions), chúng thổi vào công thức một sức mạnh hoàn toàn mới: lần đầu tiên, một công thức Excel duy nhất có thể tung ra kết quả trải khắp nhiều ô.
• =SEQUENCE(100)
nhờ đó một chuỗi giá trị liên tiếp, từ 1 đến 100, lấp đầy 100 ô liên tiếp đổ dọc xuống một cột.
• =FILTER(Sales,Salesperson=B6)
xác định tất cả các mục trong một trường – Salesperson – có chứa tên một nhân viên bán hàng được ghi trong ô B6, và trả về tất cả các bản ghi từ một tập dữ liệu tên là Sales mang tên đó – kể cả khi kết quả lên tới hàng nghìn. Số lượng công thức: một. Tiềm năng viết công thức: gần như vô hạn.
Và Excel không giới hạn khả năng mảng động chỉ cho các hàm mới nhất của mình; thực tế, hầu hết các hàm hiện có giờ đây cũng có khả năng trải nhiều ô, một điểm mà Up Up và Array! cố gắng nhấn mạnh.
Giờ thì đúng là Microsoft đã công bố về mảng động vào tháng 9 năm 2018, nhưng có thể máy tính của bạn phải chờ lâu hơn thế mới được cập nhật. Chẳng hạn, máy của tôi được cài đặt – sau khi bị trì hoãn – vào tháng 1 năm 2020. Nhưng không sao. Nếu bạn là người đăng ký Excel 365 thì bạn đã có khả năng mảng động được một thời gian rồi, và cuốn sách này nhằm giúp bạn làm quen với các hàm cũng như tiềm năng to lớn của chúng trong việc trao quyền và tinh gọn những công thức bạn viết – và cả những công thức mà bạn không ngờ rằng mình có thể viết.
Excel đã phát hành bộ hàm mảng động hiện tại của mình theo hai đợt: bộ sáu hàm đầu tiên – SEQUENCE, UNIQUE, SORT, SORTBY, FILTER và RANDARRAY (cùng với hàm @ mà bạn sẽ dùng rất hạn chế, nếu có dùng; nhưng sẽ có thêm về nó trong sách) – ra đời từ thời điểm khởi đầu năm 2018 – và một bộ 14 hàm sau đó được giới thiệu vào đầu năm nay, vẫn đang tiếp tục được triển khai cho người dùng 365 tính đến thời điểm viết bài này.
Nhưng lưu ý rằng trong khi sáu hàm gốc cũng có sẵn cho người sở hữu Excel 2021, Microsoft hiện không có kế hoạch đưa 14 hàm mới hơn vào phiên bản đó – ít nhất là tính đến bây giờ (hãy nhớ rằng Excel 2021 là một ứng dụng nguyên trạng, không thể nhận các bản cập nhật tải lên). Người ta cho rằng 2021 hoặc phiên bản kế nhiệm của nó sẽ sớm có các hàm mới, nhưng ai mà biết? Đến lúc đó nó có thể được gọi là Excel 2023.
Up Up và Array! bắt đầu bằng việc giải quyết vấn đề định nghĩa hóc búa của thuật ngữ array, rồi tiếp tục kể lại một số đặc điểm định hình của công thức mảng, cả xưa lẫn nay. Sách tiếp tục đi vào chi tiết chính các hàm mới, bổ sung phần trình bày bằng nhiều ví dụ và ảnh chụp minh họa. Và bạn có thể nhấp qua những ví dụ đó thông qua các tệp thực hành được lưu tại đây: https://github.com/Apress.
Up Up và Array! là một tác phẩm súc tích dành riêng cho cách hoạt động của các hàm mảng động và những khả năng mới trong việc viết công thức mà chúng khuyến khích. Tôi hy vọng rằng nhờ đó, bạn sẽ thấy trân trọng, và có lẽ còn được truyền cảm hứng, bởi những điều cực kỳ thú vị mà chúng – và bạn – có thể làm.
Abbott Ira Katz
Mọi mã nguồn hoặc tài liệu bổ trợ khác được tác giả tham chiếu trong cuốn sách này đều có sẵn cho độc giả trên GitHub (https://github.com/Apress). Để biết thông tin chi tiết hơn, vui lòng truy cập http://www.apress.com/source-code.
Đừng để bị lừa bởi cái tên trên bìa sách. Trừ khi bạn tự xuất bản, một cuốn sách tất yếu là nỗ lực của cả một tập thể, và khá nhiều cá nhân đã đóng góp vào quá trình đưa cuốn sách này từ đôi tay tài năng của họ đến tay bạn, hoặc màn hình của bạn. Đội ngũ đáng kính này bao gồm:
Vợ tôi, Marsha, người đã cho phép tôi lui vào hậu trường đủ xa để viết nên những gì bạn đang đọc;
Joan Murray, người đã khởi đầu hành trình của tôi;
Jill Balzano, người với những lời khuyên và hỗ trợ luôn thân thiện đã đồng hành cùng tôi trên suốt chặng đường;
Angel Michael Dhanaraj và đội ngũ dàn trang của cô ấy;
Jonathan Gennick, vì sự giám sát sản xuất đáng nể của anh ấy, và
Mikey Bronowski, người với con mắt tinh tường đã rà soát văn bản cùng vô số công thức trong đó, cứu tôi khỏi sai sót và ngượng ngùng trong không ít lần.
Tất cả họ đều có phần trong những điều đúng đắn của cuốn sách; còn điều gì chưa ổn thì tôi xin nhận trách nhiệm.
Mục lục
Giới thiệu về tác giả

Giới thiệu về người phản biện kỹ thuật

Trước đây, Mikey từng là thành viên của Poland Data Community, và hiện là thành viên tích cực đầy tự hào của UK Data Platform kiêm trưởng nhóm SotonDataCloud.org.
Anh ấy dành thời gian rảnh để đóng băng sau ống kính máy ảnh.
1. Vậy thì, Array là gì?
Câu hỏi hay đấy. Thuật ngữ đó – mảng (array) – đã chiếm được chỗ đứng trong đủ loại từ vựng tin học và còn xuất hiện như khách mời trong từ điển của nhiều lĩnh vực khoa học khác. Nhưng dù tất cả những điều đó nghe có vẻ hay ho, bạn vẫn muốn biết mảng có ý nghĩa gì với người dùng Excel, và hiểu biết đó có thể gia tăng giá trị – khá nhiều giá trị đấy – cho công việc của bạn với bảng tính như thế nào.
Một định nghĩa tạm dùng
Định nghĩa mảng bảng tính là một nhiệm vụ mang theo cả tin xấu lẫn tin tốt. Tin xấu là các định nghĩa về mảng bảng tính rất đa dạng. Chẳng hạn, có vẻ như một số tác giả gần như đánh đồng thuật ngữ vùng (range) và mảng (array). Thật vậy – một trang web của Microsoft khẳng định rằng "Bạn có thể nghĩ về một mảng như một hàng hoặc một cột giá trị, hoặc một tổ hợp các hàng và cột giá trị," và điều đó nghe với tôi chẳng khác gì một vùng, khiến tôi chẳng sáng tỏ thêm chút nào; và một trang của Google mô tả mảng gần như y hệt như vậy. Nhưng vì "vùng" dường như thường xuyên đi đôi với "mảng," ta có thể đặt câu hỏi hiển nhiên: Vậy thì tại sao chúng ta lại cần cả hai? Và để chắc chắn bạn đang chú ý, đôi khi Excel còn lôi cả "vector" ra nữa.
Thật vậy, chuyên gia Excel Liam Bastick (https://www.accountingweb.co.uk/tech/excel/xlookup-and-xmatch-two-new-x-men-for-excel) phát biểu rằng "Một mảng là một tập hợp các ô gồm ít nhất hai hàng và ít nhất hai cột," đồng thời khẳng định rằng một vector "là một tập hợp các ô chỉ nằm trên một hàng…hoặc chỉ chạy xuống một cột…" Hừm.
Mặt khác, Mike Girvin, tác giả của cuốn sách gần như huyền thoại về công thức mảng Ctrl-Shift-Enter (một cuốn mà từ đó đến nay đã gần như bị lãng quên, dù ý nghĩa của nhan đề nó sẽ trở nên rõ ràng hơn khi ta tiếp tục), lại thu nhỏ phạm vi và gọi một mảng là "một tập hợp gồm hai mục trở lên." Tôi không thể nói rằng mình được khai sáng. Còn với bậc thầy bảng tính quá cố Chip Pearson, một mảng là một chuỗi giá trị (http://www.cpearson.com/excel/ArrayFormulas.aspx), nhưng bạn đã hiểu ý rồi đấy.
Nhưng đã đến lúc nói tin tốt: Dù có nhầm lẫn đi nữa, tất cả những điều này sẽ không cản trở khả năng làm chủ công thức mảng của bạn. Một khi bạn đã khởi động và chạy được với các công thức, bạn sẽ có thể gạt những chi tiết định nghĩa xuống thành chuyện tranh cãi ở quán nhậu mà thôi – dù nếu bạn tìm được một quán bar nơi khách quen thực sự tranh luận về công thức mảng, thì làm ơn dẫn tôi đến đó nhé; chầu tới tôi mời.

Hình 1-1Đối mặt với một mảng
Bạn đang nhìn vào một mảng – các giá trị 1, 2, và 3 của chúng ta, được bao quanh bởi cặp dấu ngoặc đặc trưng đi kèm một biểu thức mảng. Bản thân tổng số ở phần dưới của ảnh chụp màn hình – 6 – thì không có ngoặc, vì trong số những điều khác, một mảng phải gồm ít nhất hai giá trị (nhưng chuyện đó để sau). Và nếu tôi thay SUM bằng hàm AVERAGE, hoặc MAX, hoặc COUNT rồi lại bấm nút fx, chúng ta sẽ phát hiện rằng mảng kết quả sẽ hiện ra đúng y như ta thấy ở trên – {1,2,3}.

Hình 1-2Kiểm tra, kiểm tra: điểm thi của học sinh để tra cứu
Sau khi nhập tên của bất kỳ học sinh nào vào I1 và viết một công thức VLOOKUP vào I3
• =VLOOKUP(I1,A1:C11,3,0)

Hình 1-3Một mảng khác, lần này được tạo ra bởi một công thức VLOOKUP
Ở đây ta gặp một khác biệt tinh tế so với mảng mà ví dụ SUM của chúng ta bắt được. Nhìn kỹ, bạn sẽ thấy dấu chấm phẩy ngăn cách các mục "phil" và "Bill," cũng như "90" và "Dana." Dấu câu đó báo hiệu rằng cả "Bill" lẫn "Dana" đều xuất hiện ở hàng mới trong cái mà Microsoft ở đây khăng khăng gọi là mảng bảng (table array) (tôi đã nói với bạn là định nghĩa rất đa dạng mà), tức là "Bill" đứng ngay sau "phil" trong mảng, nhưng xuất hiện ở hàng kế tiếp trong bảng tính (xem lại Hình 1-2). Vậy là ta đã học được một cặp quy tắc về ký hiệu mảng: dấu phẩy đặt giữa các giá trị mảng nghĩa là chúng cùng chung một hàng, còn dấu chấm phẩy cho biết các giá trị ngắt tại dấu chấm phẩy và nhảy xuống một hàng mới trong bảng tính – kiểu như một phép ngắt dòng của mảng vậy.
Giờ đến một thứ khác
Nhưng trong cả hai trường hợp của chúng ta – SUM và VLOOKUP – ta đã thấy rằng các công thức chỉ đơn giản là lấy các giá trị từ những ô tương ứng trong bảng tính và tái tạo chúng thành mảng, sẵn sàng cho bất kỳ hàm nào mà người dùng quyết định. Nhưng – và đây là một chữ "nhưng" to đùng – đôi khi một mảng gồm những giá trị không được lấy ra từ bảng tính, mà được chính công thức tạo ra.

Hình 1-4Dàn nhân vật: các từ sẵn sàng cho việc đếm ký tự
• =SUM(LEN(A1:A3))

Hình 1-5Ba từ ngắn gọn: số ký tự của mỗi từ trong vùng dữ liệu
Khác với những ví dụ trước, các giá trị 5, 2 và 8 trong mảng phía trên không hề xuất hiện trong bảng tính; chúng đại diện cho số ký tự riêng lẻ của ba từ trong vùng dữ liệu – và chúng được tính toán bởi, cũng như chỉ tồn tại trong, công thức mà thôi.
Những gì chúng ta đang thấy ở đây là một công thức mảng (array formula), gọi như vậy bởi vì chính công thức đã tạo ra mảng. Tất nhiên, đúng là các ví dụ về SUM và VLOOKUP của chúng ta cũng thể hiện mảng, nhưng ta đã thấy rằng những công thức đó chỉ đơn thuần tái tạo dữ liệu trong bảng tính rồi ném chúng vào công thức. Ở đây, công thức xây dựng mảng từ bên trong, và đó chính là ý nghĩa của công thức mảng: một công thức tạo ra nhiều kết quả – ở đây là 5, 2 và 8.
Ý Nghĩa Thực Sự – và Những Gì Không Phải
Mặt khác, hãy lưu ý lần nữa rằng số ký tự tổng hợp ở công thức phía trên – 15 – không được coi là một mảng. Nhắc lại điểm đã nói trước đó, mảng bao gồm nhiều giá trị. Ở đây, chính các kết quả trung gian, ba số đếm ký tự, mới là thứ kết hợp lại thành mảng.
Và đừng nhầm lẫn giữa nhiều kết quả với nhiều phép tính. Ví dụ, liệu có thể cộng một triệu giá trị bằng hàm SUM không? Chắc chắn là được. Hãy nhớ rằng một bảng tính Excel cho người dùng hơn 17 tỷ ô để tha hồ sử dụng, nên cộng một triệu ô chẳng qua chỉ là chuyện nhỏ. Và đúng vậy – công thức đó sẽ phải thực hiện 999,999 phép tính, đưa từng giá trị ô liên tiếp vào kết quả. Nhưng quá trình khổng lồ đó vẫn chỉ để lại cho ta một kết quả duy nhất – tổng cuối cùng, được đặt vào một ô.
Nhưng một công thức mảng tạo ra một loạt kết quả riêng lẻ, độc lập, trong trường hợp đếm ký tự của chúng ta là 5, 2 và 8. Bộ ba giá trị đó nằm cạnh nhau trong phòng chờ của công thức cho đến khi một hành động hoàn tất nào đó – trong trường hợp này là SUM – thả dù tổng 15 vào một ô duy nhất. Nhưng ba kết quả riêng biệt có trước, và chúng đến từ công thức.
• =AVERAGE(LEN(A1:A3))
trong trường hợp đó kết quả của nó – 5 – sẽ lại tìm đường vào ô của nó. Nhưng ở đây cũng vậy, giá trị trung bình được suy ra từ mảng do công thức tạo ra: 5, 2 và 8.
Lưu ý
Bài viết của Dave Bruns (https://exceljet.net/glossary/array) về "array" khá gần với quan điểm được trình bày ở đây.
Giới thiệu…Mảng Động (Dynamic Arrays)
Giờ đến điểm quan trọng tiếp theo. Hai công thức mảng mà chúng ta đã giới thiệu – công thức tính tổng số ký tự của ba từ và công thức tính trung bình ký tự mỗi từ – là loại công thức thực ra có thể viết được trong bất kỳ phiên bản Excel nào. Và điều đó dẫn đến một điểm mở đầu quan trọng. Có thể bạn mới làm quen với công thức mảng, nhưng công thức mảng không hề mới với Excel; chúng đã chiếm một góc cũ kỹ, ít ai ghé thăm trong kho công cụ của Excel suốt nhiều năm, dù rất nhiều người dùng Excel vẫn e ngại không dám mò mẫm vào góc đó.
Nhưng với sự ra mắt của Office 365, một bước phát triển mới mang tính đột phá đã xuất hiện. Cách viết công thức mảng – nay được gọi là mảng động (dynamic arrays) – đã được cải tiến triệt để và, bạn sẽ vui mừng khi biết điều này, đi kèm với sự gia tăng đáng kể về mức độ dễ sử dụng.
Vậy Có Gì Mới?
• =LEN(A1:A3)

Hình 1-6Đếm ký tự, lần này là từng từ một
• =LEN(A1:A1000)
hẳn đã làm đúng như vậy. Và đó là điều mới mẻ ở Excel. Hãy thử các công thức trên trong phiên bản trước 365 của ứng dụng, bạn sẽ phát hiện ra rằng mình không thể làm được điều đó từ đây. Thay vào đó, điều bạn sẽ phát hiện, ví dụ, là việc viết =LEN(A1:A3) vào ô B1 trong các phiên bản cũ hơn sẽ chỉ đưa một kết quả – 5 – vào B1, ví dụ, độ dài của từ trong A1. Đó là bởi vì các công thức trong Excel trước 365 không có khả năng đặt nhiều kết quả vào nhiều ô, một hạn chế được gọi là giao nhau ngầm (implicit intersection) mà chúng ta sẽ tìm hiểu thêm một chút ở phần sau.
Khả năng một-công-thức/nhiều-ô của mảng động là điều mới mẻ – và to lớn. Nó tinh gọn đáng kể quá trình viết công thức và, với một chút trí tưởng tượng, trao cho người dùng khả năng áp dụng mảng một cách hiệu quả trên vô số tác vụ xử lý dữ liệu, như chúng tôi hy vọng sẽ chứng minh.
Và để tóm tắt cốt truyện đến giờ: Mặc dù theo định nghĩa, mọi công thức mảng đều có thể cho ra nhiều kết quả, nhưng công thức mảng động có thể truyền những kết quả đó đến các ô trong bảng tính, thông qua một quá trình mà Excel gọi là tràn (spilling).
Hơn nữa, nếu (các) vùng được tham chiếu bởi một công thức mảng động thay đổi, số lượng ô bị tràn – tức là kết quả mới của công thức vừa được viết lại – cũng sẽ thay đổi ngay lập tức. Và đó chính là tính động của chúng. Và đừng lo: rất nhiều ví dụ sẽ theo sau.
Và để thúc đẩy những mục tiêu này hơn nữa, Excel đã cho ra mắt một loạt hàm mảng động sẵn sàng tăng cường sức mạnh cho công thức của bạn với hỏa lực đa ô đó – và chúng cũng khá dễ viết. Thực tế, hai đợt hàm mới đã được phát hành, và chúng tôi định xem xét tất cả chúng ở đây – ngay cả khi bạn chưa có đủ tất cả.
Và mặc dù đúng là phần lớn cuốn sách này dành cho các hàm mới, chính vì chúng mới, đừng để những hàm mới làm bạn xao lãng khỏi điểm lớn hơn – cụ thể là gần như tất cả các hàm của Excel – ví dụ, những hàm cũ đáng tin cậy như SUM, AVERAGE, VLOOKUP, MATCH, SEARCH, và nhiều hàm khác – cũng đã được trao sức mạnh mảng động. Một mặt, chúng tôi không có ý định trình bày chi tiết hàng trăm công thức trước 365 – đó là việc của một loại sách khác – nhưng một lần nữa chúng tôi muốn chỉ ra rằng những công thức này cũng đã được trang bị chức năng mảng động (để có danh mục tất cả các hàm của Excel, trừ những hàm mới nhất vừa được công bố, hãy xem ở đây).
Vậy thì cuốn sách này không chỉ nói về những công cụ mới mở rộng kho hàm của Excel; nó thực sự nói về Excel, về cách nó đã thay đổi, và cách nó sẽ thay đổi cách bạn làm việc.
Một vài điểm cần ghi nhớ
Trước khi bắt đầu mô tả cách hoạt động của công thức mảng động, hãy đưa ra thêm vài điều sơ bộ. Thứ nhất, cuốn sách này không thể hy vọng hay cho rằng sẽ kể cho bạn mọi thứ cần biết về mảng động. Suy cho cùng, với tiềm năng to lớn của chúng, tôi không chắc mục tiêu đó thậm chí có khả thi, và ngay cả nếu có thì nó sẽ đòi hỏi một cuốn sách lớn đến mức bạn không muốn đọc, và tôi cũng không muốn viết. Như mọi người dùng Excel có chút kinh nghiệm đều biết, cùng một tác vụ bảng tính thường có thể có nhiều cách tiếp cận, nên những kỹ thuật được dùng ở đây có thể không phải là cách duy nhất.
Thứ hai, bạn sẽ để ý rằng hầu hết các ảnh chụp màn hình đều hiển thị các công thức đã tạo ra kết quả được ghi lại trong ảnh. Chúng xuất hiện nhờ hàm FORMULATEXT hữu ích nhất, nhưng tất nhiên những công thức này sẽ không tự động xuất hiện trên trang tính của bạn nếu bạn vừa bấm vừa làm theo tôi.
Và cuối cùng, cần thừa nhận rằng những ví dụ đặt trước bạn ở đây không nhất thiết mang tính "thực tế", những ví dụ sẽ giải quyết vấn đề bảng tính dai dẳng ở chỗ làm khiến vị chuyên gia của bạn phải bó tay. Thay vào đó, kế hoạch là trình bày chi tiết cách các hàm, và các công thức dựa trên những hàm đó, được viết ra, và chúng thực sự làm gì – mà không nhất thiết phải quan tâm đến các tác vụ thực tế cần làm.
2. Kiến thức cơ bản về công thức mảng
Cái cũ và cái mới
Công thức mảng mang một tiếng tăm – và đó không phải là tiếng tăm tốt đẹp gì. Với nhiều người dùng bảng tính, chúng giống như con hẻm tối lúc 3 giờ sáng trong Excel vậy; tốt nhất là đừng dại mà bén mảng tới.
Vì sao chứ? Có thể là bởi công thức mảng đòi hỏi người dùng phải suy nghĩ và làm việc với các vùng (range) theo một cách khiến họ bước ra khỏi vùng an toàn của mình. Tất nhiên, mọi công thức bảng tính đều làm việc với các vùng, nhưng công thức mảng – cả loại cũ lẫn loại mảng động (dynamic array) mới hơn – đều xử lý các giá trị theo một kiểu tập thể khác biệt.
• =SUM(LEN(A1:A3))

Hình 2-1Đi tìm độ dài: cộng độ dài của từng từ một cách riêng lẻ
• =SUM(A1:A1000)
Vậy thì nhiệm vụ đó sẽ cần tới 1001 công thức.
Tất nhiên những kết quả này sẽ đúng, nhưng giải pháp mảng có thể tạo ra cùng kết quả đó chỉ với đúng một công thức. Nếu bạn cần tính tổng độ dài của 100.000 từ tràn ngập trong cột A, bạn sẽ phải dùng tới 100.001 công thức để xử lý chúng. Còn số lượng công thức mảng thì sao? Một lần nữa, chỉ một.
• =LEN(A1:A3)
Và sau đó bạn sẽ bao quanh, hay bọc, công thức đó bằng hàm SUM.
Công thức mảng này thực hiện hai thao tác – tính độ dài cho từng ô cũng như tính tổng của chúng – và một lần nữa, chỉ trong không gian của một công thức. Chính cách tư duy này, khi công thức được yêu cầu làm nhiều việc cùng lúc với nhiều giá trị, có thể là điều mới mẻ với bạn, nhưng chỉ cần ngẫm nghĩ một chút về quá trình mảng cùng với vài bài luyện tập có định hướng thì bạn sẽ nắm vững thôi.
• =LEN(A1:A3)
khi được giải phóng khỏi SUM, sẽ trả kết quả của nó vào nhiều ô. Cứ như thể hàm SUM khóa dữ liệu của nó bên trong công thức, buộc một kết quả tổng hợp duy nhất vào một ô duy nhất.
Một lời nhắc quan trọng
• =SUM(LEN(A1:A3))
• =LEN(A1:A3)
chỉ có thể được viết thành công trong Excel 365 trở lên, vì nó sẽ đặt kết quả của mình vào nhiều ô.
Hồi tưởng về những lần gõ phím năm xưa
Và những lời nhắc nhở đó gợi lại một lý do khác khiến bao nhiêu người dùng Excel phải né tránh mỗi khi thấy một công thức mảng (array formula) xuất hiện. Nếu một người dùng nào đó đủ can đảm để thực sự viết một công thức như vậy trong những ngày xa xưa trước phiên bản 365, thì công thức mảng ấy không được thiết lập trong ô của nó bằng một cú nhấn đơn giản vào phím Enter, mà thay vào đó phải gõ ra một bộ ba phím đáng sợ: Ctrl-Shift-Enter.
• =LEN(A1)
• =LEN(A1:A3)
Nhưng Ctrl-Shift-Enter đã buộc, hay như dân mọt công nghệ thường nói, đã "cưỡng chế" các công thức phải kìm nén bản năng chỉ-trả-về-một-kết-quả của mình và nhường chỗ cho nhiều kết quả thay vì thế – kể cả khi với các công thức mảng thế hệ đầu tiên, những kết quả đó chỉ giới hạn trong chính bản thân công thức. Quá trình đó được gọi là lifting (nâng cấp), và là một phần không thể tách rời của công thức mảng; nhưng quan trọng hơn, lifting giờ đây đóng vai trò là khả năng công thức mặc định của Excel. Dù sao đi nữa, chúng ta sẽ nói thêm về lifting ở phần sau.
• {=SUM(LEN(A1:A3))}
Những dấu ngoặc nhọn, thứ hình thù ngoằn ngoèo mà chúng ta đã thấy gắn liền với các mảng trong những ngóc ngách bên trong công thức, ở đây lại xuất hiện trong chính các công thức ngay tại ô của chúng, chắc hẳn đã khơi lên cùng một câu hỏi trong đầu vô số người dùng Excel: rốt cuộc mấy thứ đó là cái gì vậy?
Đó cũng từng là một câu hỏi hay, vào một thời nào đó. Nhưng đừng lo, với sự ra đời của mảng động (dynamic array), cả Ctrl-Shift-Enter lẫn những dấu ngoặc nhọn bao quanh công thức mảng đều đã bị bãi bỏ, và nếu bạn chưa từng biết về chúng ngay từ đầu thì bạn thật may mắn – chẳng có gì để bạn phải "gỡ" khỏi đầu cả. Chúng đã biến mất. Ngày nay, mọi công thức Excel, dù là mảng hay không, đều khởi động chỉ bằng phím Enter và không cần gì hơn. Còn về những dấu ngoặc nhọn, cần nói thêm đôi chút, nhưng cứ yên tâm: bạn sẽ không thấy chúng kẹp quanh các công thức trong ô của chúng nữa.
Lưu ý
Một số ít công thức trước phiên bản 365, đáng chú ý nhất là SUMPRODUCT, đã được trao cho địa vị công thức mảng gốc và do đó người dùng chỉ cần nhấn phím Enter. Nhưng ngay cả SUMPRODUCT cũng chỉ có thể trả kết quả về một ô duy nhất.
Quay lại những điều cơ bản
• =FORMULATEXT(C1:C4)
Nhấn Enter, và xong việc. Một công thức, nhiều phiên bản của FORMULATEXT (lại nói về "spilling" – tràn ra), và không có dấu ngoặc nhọn nào. Chỉ cần nhớ rằng bạn không thể viết công thức này trong các phiên bản Excel cũ hơn.
Và vùng tràn (spilled range) đó đáng để nhìn kỹ hơn. Chúng ta đã viết công thức trong C1, và tất nhiên một cú nhấp vào ô đó sẽ tiết lộ những gì ta đã viết ở đó. Nhưng hãy nhấp vào C2, công thức y hệt sẽ hiện ra, nhưng mờ nhạt – như một dạng bóng phản chiếu của bản gốc. Bạn sẽ không thể xóa C2, hay bất kỳ ô nào đã bị tràn ra từ công thức nguồn. Mặt khác, xóa C1 – ô chứa công thức thực sự – thì toàn bộ vùng tràn sẽ biến mất.

Hình 2-2Một bộ bốn giá trị
• =Beatles
bất kỳ đâu trong worksheet (hoặc bất kỳ sheet nào khác trong workbook, theo mặc định), và ngay lập tức tràn các tên đó xuống cột của nó.
Đó là mảng động thuần túy đang hoạt động, và kiểu vùng như vậy có thể mang lại cho người dùng chu đáo nhiều hơn là trò mẹo vặt. Một giáo viên có thể liệt kê tất cả tên học sinh của mình trong một vùng và gọi nó là Class, rồi bằng cách gõ =Class ở bất kỳ đâu khác trong workbook, có thể ngay lập tức triệu tập tất cả các tên để chấm điểm, điểm danh, hoặc bất kỳ mục đích hành chính nào khác. Một người giám sát công việc cũng có thể làm điều tương tự với danh sách nhân viên; gõ tên vùng, và danh sách xuất hiện.
Và để ôn lại phần thảo luận của chúng ta ở Chương 1, xin nhắc rằng việc viết =Beatles trong Excel trước phiên bản 365 và nhấn Enter sẽ cho kết quả là "John" – và chỉ John mà thôi.
Giờ thì nói cho rõ, một cách xử lý vòng vo nhiều ô đúng là có sẵn cho thế hệ trước 365. Nếu tôi chọn bốn ô trước, rồi nhấp vào thanh công thức và nhập =Beatles, và sau đó nhấn Ctrl-Shift-Enter, thì tên của từng thành viên trong nhóm Fab Four thực sự sẽ có chỗ đứng của mình, mỗi ô một tên. Nhưng đó là một yêu cầu rắc rối – và kém hiệu quả.
Công cụ chấm điểm một công thức

Hình 2-3Bài thi trắc nghiệm nhiều ô
Đáp án nằm ở B4:B13, bên cạnh câu trả lời của học sinh ở C4:C13. Mục tiêu rõ ràng: xác định điểm tổng thể của học sinh.
• =IF(C4=B4,1,0)

Hình 2-4Đánh giá bài đánh giá: tính điểm của học sinh
(Chúng ta có thể đi xa hơn và chia tổng số câu trả lời đúng cho số câu hỏi của bài thi, cho ra điểm 60%; nhưng bước đó không cần thiết cho mục đích minh họa của chúng ta.)
• =SUM(IF(B4:B13=C4:C13,1,0))

Hình 2-5Đúng và sai: các câu trả lời của bài kiểm tra được tập hợp trong một mảng
Chúng ta vừa gặp một trường hợp khác của việc nâng cấp – lần này là một trường hợp đặc biệt gọi là nâng cấp theo cặp (pairwise lifting), trong đó từng cặp giá trị trải dài trên các hàng của chúng được so sánh, khi công thức tràn kết quả xuống cột D. Công thức IF đơn lẻ của chúng ta đã bị buộc phải xé bỏ bản mô tả công việc của nó và đánh giá dữ liệu trong một vùng ô; và những số 1 và 0 đó – tất cả đều nằm trong thâm cung của công thức – tổng cộng là 6, điểm của học sinh.
• =IF(B4:B13=C4:C13,1,0)

Hình 2-6Ra riêng một mình; một câu lệnh IF duy nhất tính từng điểm.
Hao hao LEN(A1:A3). Ở đây cũng vậy, câu lệnh IF – không có SUM – gán các số 1 và 0 của nó bên cạnh từng câu trả lời của học sinh. Lại nữa: một công thức duy nhất tuôn ra nhiều kết quả tràn vào các ô của chúng – một kết quả chỉ có thể xảy ra trong Excel 365 trở lên.
Sự trở lại của các dấu ngoặc

Hình 2-7Sáu đối tượng đi tìm một công thức
Một lần nữa, chúng ta lại yêu cầu một công thức thoát khỏi vai trò quen thuộc của nó – VLOOKUP đáng kính đã được chỉnh sửa "gen" để tra cứu các giá trị trong một cột duy nhất, và giờ đây chúng ta muốn nó truy tìm các giá trị trong hai cột cùng một lúc – và tính luôn giá trị trung bình của chúng. Vậy VLOOKUP đó sẽ trông như thế nào?
• =AVERAGE(VLOOKUP(I9,All,{2,5}))
Và chúng ta biết được rằng Jane đạt điểm trung bình 69 cho bài thi môn xã hội học và nghệ thuật.
Nhưng lại là những dấu ngoặc đó – những dấu ngoặc mà bạn tưởng đã bị trục xuất vĩnh viễn khỏi các công thức mảng, và bị cất giấu không thể lấy ra trong kho lưu trữ. Nhưng những dấu ngoặc đó thuộc loại tự động, loại nhảy vào ô bất cứ khi nào bạn hoàn tất một công thức mảng kiểu cũ bằng tổ hợp Ctrl-Shift-Enter giờ đã lỗi thời. Những dấu ngoặc này do người dùng chọn và người dùng gõ, và chúng ném một mảng thực sự, được tạo ngay lập tức vào thẳng trong công thức. Các giá trị nằm giữa các dấu ngoặc được gọi là hằng số mảng, được đặt tên như vậy vì chúng được mã hóa cứng, hay đơn giản là được gõ vào. Nhưng đừng hiểu sai – các hằng số này không phải là văn bản bất động: ở đây chúng dùng để định lượng các số cột mà bạn chọn, và trong trường hợp của chúng ta, chúng bảo VLOOKUP tìm dữ liệu ở cột 2 và 5. Nếu chúng ta nhập {2,5,7}, VLOOKUP sẽ tiếp tục tính điểm trung bình của Jane cho môn xã hội học, nghệ thuật và hóa học: 64.67. Điểm mấu chốt là thế này: các hằng số mảng buộc VLOOKUP phải thực hiện việc tìm kiếm giá trị trên nhiều cột. Và một lần nữa, vì tất cả màn tung hoành này chỉ tạo ra một kết quả trong một ô – điểm trung bình bài thi – nên công thức của chúng ta có thể được viết trong các phiên bản Excel trước đây, nhưng hãy nhớ rằng nếu bạn đang ở trong tình huống đó, bạn sẽ cần phê chuẩn công thức bằng Ctrl-Shift-Enter.
• =VLOOKUP(I9,All,{2,5,7})

Hình 2-8Toàn là chuyện học hành: điểm của Jane ở môn xã hội học, nghệ thuật và hóa học
Và một lần nữa, kết quả đó khẳng định khả năng xử lý nhiều ô của các công thức mảng động. Chắc hẳn bạn đã nắm được ý tưởng rồi.
Định hướng lại
Nhưng công thức cuối cùng đó làm nảy sinh một câu hỏi mới. Bạn sẽ để ý thấy sự căn chỉnh theo chiều ngang của ba điểm số của Jane; nhưng tại sao chúng lại trải dài theo một hàng, mà không phải theo một cột?
• {2,5,7}
• =VLOOKUP(I9,All,{2;5;7})

Hình 2-9Xu hướng đi xuống: điểm của Jane theo chiều dọc
Vẫn là chuyện cũ
• =LARGE(A1:A100,3)
• =LARGE(A1:A100,{1,2,3})
Tương tự, công thức này sẽ cho ra ba kết quả, mỗi ô một kết quả; và vì mảng được phân tách bằng dấu phẩy, chúng sẽ tràn ra theo hàng ngang.
Nhưng Vẫn Có Cách Khắc Phục
Nhưng nếu bạn chỉ đơn giản là không thích mấy cái dấu ngoặc nhọn phiền phức đó, thì đây là một cách khắc phục khá ít người biết nhưng lại dễ dàng, giúp công thức mảng của bạn không cần dấu ngoặc:
• =VLOOKUP(I9,All,I10:K10)
Cách làm mới này cho kết quả tương tự, mà không cần dấu ngoặc; và nếu bạn muốn thay đổi số cột cần tra cứu mà không phải sửa trực tiếp công thức, chỉ cần nhập một số khác vào đâu đó trong I10:K10.
Tổng Kết
Chúng ta đã dành chương này để điểm lại một số tính năng thiết yếu của công thức mảng thế hệ đầu tiên, bộ công thức mảng động mới, và điều gì phân biệt cái này với cái kia. Lưu ý rằng – và một lần nữa điều này rất quan trọng – phần điểm lại của chúng ta đã chạy hết các bước mà không cần dùng đến bất kỳ hàm mảng động mới nào. Việc cố ý bỏ qua đó là lời nhắc rằng đội ngũ kỹ thuật của Microsoft đã cài đặt động cơ mảng động vào hầu hết các hàm của Excel, chứ không chỉ những hàm mới. Trong chương tiếp theo, chúng ta sẽ đi sâu hơn một chút vào bên trong và khám phá thêm một số cơ chế của động cơ này. Tuy nhiên, không cần mặc đồ bảo hộ đâu.
3. Mảng Động: Đến Lúc Làm Việc Nặng
Hết Tràn Lan
Đúng vậy, thuật ngữ "spill" (tràn) – cái tên mà Excel đặt cho khả năng công thức đa ô mới của mình – gợi lên một màn lộn xộn, kiểu như những tai nạn tôi thường xuyên gây ra cho áo mình trong bữa tối. Nhưng như chúng ta đã thấy trong thế giới bảng tính, tràn lại là một điều tốt lành. Việc cho phép một công thức duy nhất phân phối hàng nghìn kết quả đến bấy nhiêu ô là một tính năng cực kỳ hiệu quả và đáng ca ngợi. Nhưng có hai tình huống chính mà Excel sẽ không cho phép tràn xảy ra.

Hình 3-1Sự xâm nhập không mong muốn: văn bản nằm cạnh kết quả 5
• =IF(B4:B13=C4:C13,1,0)

Hình 3-2Bị chặn hết: công thức không thể tràn
Có lẽ bạn đã đoán ra chuyện gì đã xảy ra, và tại sao. Các giá trị trong vùng tràn không thể chiếm đúng vị trí của chúng vì mục "text" ở ô D8 cản trở quá trình tràn. Việc tràn là một đề xuất được ăn cả ngã về không; nếu chỉ một giá trị bị tràn bị từ chối quyền vào ô của nó, thì tất cả đều bị từ chối.

Hình 3-3Để dữ liệu chảy với tùy chọn Select Obstructing Cells
Đầu tiên, vùng được chỉ định cho spill – trong trường hợp của chúng ta là D4:D13 – được bao quanh bởi một đường viền chấm chấm, khi floatie mở ra tùy chọn Select Obstructing Cells. Nhấp vào đó, và con trỏ ô sẽ phóng thẳng đến ô D8. Giờ thì ô gây lỗi đã được xác định, chỉ cần xóa nó đi, và vùng spill sẽ hoạt động như bình thường.
Tất nhiên, bạn hoàn toàn có thể tự mình tìm ra ô gây cản trở; nhưng hãy nhớ rằng một công thức mảng động (dynamic array formula) duy nhất có thể trải dữ liệu của nó ra nhiều hàng và nhiều cột cùng một lúc, nên việc truy tìm (các) ô cản đường không phải lúc nào cũng đơn giản và rõ ràng như vậy.
Bạn Không Thể Spill Trên Bảng Này
• =IF(B4:B13=C4:C13,1,0)

Hình 3-4Một đống spill đang diễn ra
Lưu ý
Tùy vào cách bạn viết công thức ở đây, bảng có thể hiển thị nó dưới dạng =IF([Answer Key]=[@Student],1,0), nhưng sự khác biệt đó không quan trọng với mục đích của chúng ta.
Spill chắc chắn không hoạt động ở đây – nhưng tại sao?
Câu trả lời cho câu hỏi đó đã làm tôi trăn trở một thời gian, và phỏng đoán ban đầu của tôi là gạt phăng việc bảng không hỗ trợ mảng động sang một bên như thể đó là một lỗi thiết kế gặm nhấm mã nguồn của Excel. Nhưng rồi tôi trải qua một khoảnh khắc eureka nho nhỏ và tự thuyết phục mình rằng thực tế, với một ngoại lệ gần như chỉ mang tính lý thuyết, bảng không thể hoạt động với công thức mảng động.

Hình 3-5Các đĩa nhạc tiếp theo của The Beatles
Nhưng một khi chúng ta tái cấu trúc dữ liệu thành một bảng, tất cả các hàng của nó trở thành các bản ghi (record) được định nghĩa chặt chẽ, và nếu bạn viết một công thức thông thường vào bảng, nó sẽ ngay lập tức được sao chép đến tất cả các bản ghi. Nhưng hãy nhớ rằng công thức vùng Beatles của chúng ta spill ra bốn ô, vậy nên nếu bảng có 100 bản ghi, và công thức Beatles cùng vùng spill của nó bị sao chép xuống một cột của bảng, chúng ta sẽ phải xử lý 400 kết quả – và 400 ô gắn với 100 bản ghi thì đúng là không tính toán nổi. Bởi vì công thức mảng động spill, đầu ra nhiều ô của chúng không thể được kỳ vọng là nhồi nhét vừa vặn vào các bản ghi của bảng.
Lưu ý
Có một vài tình huống khác, ít phổ biến hơn nhiều, mà spill cũng không hoạt động, nhưng không cần bận tâm ở đây.
Nhưng đồng thời hãy nhớ rằng một công thức mảng động có thể tham chiếu đến một bảng; nó chỉ không thể được nhập vào một bảng – ngoại trừ cái ngoại lệ hiếm gặp đó.
Và ngoại lệ đối với lệnh cấm mảng động không dùng bảng đó, như đã nói ở trên, gần như chỉ mang tính lý thuyết. Nếu bạn viết một công thức mảng động cho ra đúng một bản ghi, bảng sẽ chấp nhận nó một cách thoải mái – vì công thức không có gì để spill. Nhưng vì điểm nổi bật của mảng động chính là sức mạnh nhiều ô của nó, bạn khó có thể viết, hoặc muốn viết, một công thức như vậy (cảm ơn Mark của Excel Off the Grid vì gợi ý này).
Dấu #: Cân Nhắc Về Những Ưu Điểm Của Nó
• =D4#
Dấu thăng (hay còn gọi là dấu hash, tùy vào việc bạn sống ở bờ nào của Đại Tây Dương) biểu thị ô mà công thức mảng động thực sự được viết, và việc viết tham chiếu như vậy sẽ nhân bản công thức đã viết vào ô đó, cùng với tất cả các kết quả tràn ra của nó.
• =SUM(D4#)
đương nhiên sẽ cho ra 6.
Tất nhiên, =SUM(D4:D13) cũng có thể tạo ra kết quả tương tự, nhưng D4# có vài ưu điểm: nó dễ hơn và ngắn hơn, và quan trọng hơn, tham chiếu dấu thăng sẽ tự động ghi nhận mọi thay đổi đối với phạm vi tràn do công thức gây ra.
• =SEQUENCE(10)
• =SEQUENCE(30)
• =COUNT(A3#)
sẽ xuất ra 30. Nhưng ở đây, dù công thức COUNT thuộc loại một kết quả, nó không thể được viết trong các phiên bản Excel trước đó – vì những phiên bản đó không có hàm SEQUENCE lẫn tùy chọn dấu thăng.
Nêu Thêm Vài Điểm Về Việc "Nâng"
Ôn lại chút, thuật ngữ "nâng" (lifting) chỉ khả năng đa kết quả hiện tại của các công thức Excel, nay đã được nâng lên thành mặc định thực sự cho hầu hết các hàm của nó. Nhưng còn vài sự thật nữa về việc nâng mà bạn cần biết.

Hình 3-6Lần này đến lần khác – các giá trị cần nhân
• =C3:C6*D3:D6

Hình 3-7Thành quả của công sức chúng ta
Chúng ta lại gặp một trường hợp nâng theo cặp (pairwise lifting), kiểu nâng mà trong đó các cặp giá trị được nhân xuống theo cột của chúng. Hãy nhớ rằng lần đầu tiên chúng ta gặp việc nâng theo cặp là khi so sánh câu trả lời bài kiểm tra của học sinh với đáp án, dưới sức mạnh của câu lệnh IF. Ở đây, chúng ta đã thực hiện một loạt phép nhân với các cặp giá trị.

Hình 3-8Ba lần vẫn thích: nhân các bộ ba giá trị

Hình 3-9Một công thức bị lệch
Bạn thấy lý do rồi đấy. Hai vùng dữ liệu không khớp đúng với nhau – vì một vùng có bốn ô, còn vùng kia chỉ có ba. Chẳng hạn, ô C6 nhân chính nó với một "đối tác ma", cụ thể là ô D6 bị thiếu, và công thức của nó không còn cách nào khác ngoài việc đầu hàng trước lỗi #NA.
Giờ đến một góc nhìn mới

Hình 3-10Định hướng lại công thức

Hình 3-11… cái này thì chạy được
Bất ngờ chưa. Vùng thứ hai – nhớ nhé, vùng này chứa ít giá trị hơn vùng thứ nhất – giờ đây đứng ở vị trí vuông góc với vùng thứ nhất, và kèm theo cú xoay 90 độ đó là một sự thay đổi toàn diện trong "mệnh lệnh hành quân" của công thức. Giờ thì mỗi giá trị trong vùng thứ nhất được nhân với từng giá trị trong vùng thứ hai. Ví dụ, giá trị đầu tiên (ô trên cùng bên trái) trong mảng tràn hoàn toàn mới này – 1242 – chẳng qua chỉ là tích của các ô đầu tiên thuộc hai vùng tương ứng, 23 và 54. Đi tiếp theo hàng ngang, con số 736 là tích của 23 x 32, và chắc bạn tự suy ra được phần còn lại.
• =D7#

Hình 3-12Lan truyền (broadcasting): phiên bản phép cộng
cũng chạy được luôn.

Hình 3-13Tự thân một mình: lan truyền từ một ô

Hình 3-14E unum pluribus: từ một (ô), sinh ra nhiều
Nhưng nó hoạt động thế nào? Giả thuyết của tôi là Excel coi giá trị đơn lẻ đó như một hàng hẹp nhất có thể, rồi lan truyền nó qua bốn giá trị xếp dọc theo cột.
Nhưng gạt chuyện thuật ngữ sang một bên, bạn sẽ muốn hiểu cách lan truyền hoạt động, vì như chúng ta sẽ thấy, nó có thể có lợi cho bạn.
Các hoán vị của PMT
• =PMT(interest rate divided by number of annual payments,number of payments,loan amount)
• =PMT(A2/12,A3,A1)
Để giải thích điều này: lãi suất của A2 phải được chia cho 12, nhằm phản ánh số kỳ thanh toán mỗi năm được phát hành theo mức lãi suất 3%. A3 chỉ đơn giản ghi lại tổng số kỳ thanh toán khoản vay (12 kỳ trong mỗi năm của 2 năm, tức 24 kỳ), và A1 gợi nhớ lại khoản vay 10.000 đô-la. Đáp án: -429,81 đô-la, được biểu diễn dưới dạng số âm đơn giản vì khoản vay ghi nợ vào tài khoản của người đi vay. Do đó, A1 thường được nhập là -A1 để khôi phục dấu dương cho kết quả; nhưng quyết định đó chỉ mang tính trình bày mà thôi.

Hình 3-15Người sắp xếp khoản vay
• =PMT(G7:K7/12,F8:F13,G4)

Hình 3-16Điều bạn quan tâm: một ma trận thanh toán khoản vay, nhờ một công thức mảng động duy nhất
Công thức PMT của chúng ta đồng thời kiểm tra mọi mức lãi suất với đối số G7:K7/12, và từng tần suất thanh toán qua F8:F13. Như vậy nó khác biệt với PMT thông thường ở chỗ trích dẫn các vùng thay vì tham chiếu ô đơn lẻ – nói cách khác, đây là một công thức mảng động. Kết quả mang tính thông tin, khi đó, mọi khả năng thanh toán mở ra trước mắt người đi vay, nhờ vào một công thức mảng động duy nhất đó.
Và dù bạn có nhận ra hay không, bài tập của chúng ta mô phỏng công cụ Data Table cổ xưa của Excel, một tính năng dựa trên mảng thời kỳ đầu với đủ thứ bộ phận chuyển động (một số khá kỳ quặc) mà, nói riêng giữa chúng ta với nhau, tôi chưa bao giờ thực sự hiểu hết (để xem hướng dẫn của Microsoft về Data Table, xem tại đây (https://support.microsoft.com/en-us/office/calculate-multiple-results-by-using-a-data-table-e95e2487-6ca6-4413-ad12-77542a5ea50b)). Nhưng đừng bận tâm; PMT của chúng ta làm điều tương tự chỉ với một công thức.
Nâng cao hơn nữa – nhưng lần này, ngay bên trong một ô
Giờ chúng ta cần xem xét thêm một đặc tính nữa của việc nâng cao, và đây là một đặc tính quan trọng. Đây là ví dụ minh họa, một ví dụ ta có thể thực hiện trên một bảng tính trống. Mỗi ký tự Excel đều có một số mã được hàm CODE ghi nhận. Ví dụ, =CODE(“b”) cho ra 98, trong khi biến thể chữ hoa =CODE(“B”) cho kết quả 66. Giờ giả sử rằng, vì bất kỳ lý do gì, chúng ta cần biết mã của từng ký tự trong từ Thursday, mà ta sẽ nhập vào ô A6. Thách thức của chúng ta là viết một công thức làm được việc đó, và để đạt được mục tiêu ấy chúng ta sẽ cần bằng cách nào đó tách, hay trích xuất, từng ký tự từ Thursday, để có thể gán đúng mã cho đúng ký tự.
• =MID(A6,4,2)
sẽ cho ra kết quả rs cho từ Thursday.
Ba thành phần của MID (hay “đối số”, như cách gọi trong sách quy tắc) (1) nêu tên ô mà MID tác động lên, (2) xác định số vị trí của ký tự mà MID bắt đầu làm việc, và (3) khai báo số ký tự cần tách ra từ ô. Vì chữ r nằm ở vị trí thứ tư trong chuỗi văn bản Thursday của chúng ta, MID bắt đầu từ đó và nhổ lên cả r lẫn s – 2 ký tự được nêu trong đối số cuối cùng của hàm.
• =MID(A6,{1,2,3,4,5,6,7,8},1)

Hình 3-17Bị giam trong ô của chúng; MID trích xuất từng ký tự.
Công thức mảng dựa trên MID của chúng ta tràn tám kết quả ra một vùng nằm ngang. MID thực chất đã tự áp dụng tám lần, thực hiện tám lần trích xuất ký tự liên tiếp trên từ mục tiêu, một kỳ công nhanh nhẹn đáng kinh ngạc. Và không giống những trường hợp nâng cao trước đây chúng ta đã khảo sát đến nay, đầu ra nhiều ô được sắp đặt ở đây bắt nguồn từ một ô đơn lẻ, và đó là một khả năng bạn rất cần ghi nhớ, và là điều chúng ta cần xem xét lại.

Hình 3-18Thursday, phong cách Excel
Khi MID tách các chữ cái ra, mỗi ô một chữ, hàm CODE sẽ kiểm tra từng chữ và áp dụng mã riêng của nó. Và toàn bộ công việc được vận hành chỉ bằng một công thức. Đó chính là sức mạnh mảng động thực sự. Và hãy nhớ: cả MID lẫn CODE đều không phải là hàm mảng động “mới” – nhưng chúng vẫn hoạt động một cách động, y như vậy.
Ghi chú thực hành: Tên trường và tên tập dữ liệu
Giờ thì chúng ta đã nắm chắc hiểu biết về spill, dấu #, và những điều cốt lõi cần biết về lifting, chúng ta có thể bắt đầu dành một lời chào riêng cho những thành viên mới nhất gia nhập đại gia đình hàm Excel – những hàm mang dòng dõi mảng động (dynamic array).
Nhưng trước khi bắt đầu phần đánh giá, đôi lời về tên trường và tên tập dữ liệu được dùng ở đây sẽ giúp làm rõ các thảo luận. Để đơn giản hóa và tập trung vào mảng động, các trường sẽ được đặt tên theo các mục trong hàng tiêu đề của chúng, trừ khi có chỉ định khác. Nếu một bài tập yêu cầu tham chiếu đến toàn bộ tập dữ liệu, tập hợp đó sẽ được gọi là All, nếu nó là tĩnh – nghĩa là nếu dữ liệu sẽ giữ nguyên như bạn thấy, và không nhận thêm bản ghi mới. Tất cả tên trường trong tập dữ liệu tĩnh – kể cả All toàn cục – sẽ hoạt động với các vùng (range) có tọa độ bắt đầu từ hàng ngay bên dưới các tiêu đề.
Những tập dữ liệu được chuẩn bị để nhận bản ghi mới sẽ được cấu hình thành bảng (table) thông qua tổ hợp phím Ctrl-T tiêu chuẩn, và chúng sẽ được đặt tên là Table1, Table2, v.v. – nhưng các trường của chúng vẫn sẽ đơn giản mang tên các tiêu đề của chúng. Điều kiện sau là cần thiết, vì bảng tạo ra tên trường mặc định thể hiện cái mà Excel gọi là tham chiếu có cấu trúc (structured references).

Hình 3-19Bảng đã sẵn sàng
• =COUNTA(Table1[Salesperson])
• =COUNTA(Salesperson)
Như vậy, kiểu tên trường ở trên sẽ xuất hiện trong cả hai loại tập dữ liệu – biến thể tĩnh và biến thể bảng.
• Nhấp vào bất kỳ đâu trong dữ liệu.
• Nhấn Ctrl-A, từ đó chọn tất cả các ô của tập dữ liệu.
• Sau đó nhấp vào tab Formulas > lệnh Create from Selection trong nhóm nút Defined Names. Bạn sẽ thấy như trong Hình 3-20.

Hình 3-20Cũ mà vẫn hay: hộp thoại Create from Selection
• Sau đó nhấn Ctrl-T để chuyển tập dữ liệu thành bảng.
Giờ thì bạn đã tự ban cho mình điều tuyệt vời nhất của cả hai thế giới – bạn đã tạo ra một bảng mà các trường của nó sẽ tự động ghi nhận mọi bản ghi mới trong công thức, và bạn cũng cho phép mình làm việc với các tên trường dựa trên tiêu đề theo cách thông thường.
Một điểm cuối. Từ đây trở đi, ngoài việc mô tả công thức qua hàm FORMULATEXT, ảnh chụp màn hình sẽ tô vàng các ô chứa công thức, giúp tăng độ rõ ràng.
Tiếp theo
Giờ chúng ta đã giải quyết xong những phần chuẩn bị cần thiết đó, đã đến lúc đào sâu vào các hàm mảng động (dynamic array) thú vị này. Đầu tiên: một hàm mà chúng ta đã thoáng gặp qua – SEQUENCE.
4. Hàm SEQUENCE: Đặt hàng theo yêu cầu
Điểm mới của Sequence
Tất nhiên, Excel từ lâu đã cho chúng ta cách trải một dãy giá trị ngang hoặc dọc trên bảng tính. Nếu bạn cần nhập một chuỗi số từ 1 đến 100, chúng ta chỉ cần nhập số 1 và số 2 – từ đó thiết lập khoảng cách, hay bước nhảy (step), mong muốn là 1 – nắm lấy nút AutoFill, rồi kéo xuống thêm 98 hàng nữa, hoặc kéo ngang với số cột tùy ý. Hơn nữa, nếu bạn đã nhập sẵn một danh sách 100 cái tên, bạn có thể đặt số 1 và số 2 vào cột bên trái liền kề, chọn cặp giá trị đó, rồi nhấp đúp vào nút AutoFill. Thế là xong – từ 3 đến 100 sẽ hiện ra.
• =SEQUENCE(no. of rows,no. of columns,first value,step)
• =SEQUENCE(30,1,1,1)
sẽ tạo ra một dãy cao 30 hàng, rộng một cột, bắt đầu dãy bằng giá trị 1, và tăng, hay cộng thêm, mỗi giá trị kế tiếp thêm 1. Nói cách khác, viết công thức trên và bạn sẽ thu được các số từ 1 đến 30 chạy dọc xuống một cột.
• =SEQUENCE(30)
• =SEQUENCE(,30)
sẽ tạo dãy giá trị 1–30 ngang qua một hàng. Nhưng ở đây bạn thực sự cần nhập dấu phẩy đầu tiên đó, để báo cho công thức biết rằng số 30 đã nhảy qua đối số hàng và lọt vào phần tham chiếu cột.
• =SEQUENCE(30,,6,2)
sẽ cho ra 30 hàng (và một cột) giá trị bắt đầu từ 6 và tăng dần theo bước nhảy 2, ví dụ kết quả sẽ là 6,8,10,12, v.v.
• =SEQUENCE(10,3,,4)

Hình 4-1Tăng dần theo cột: ba cột, mười hàng giá trị của dãy
Nhân đây cũng lưu ý rằng ở đây dãy trải ngang qua các hàng của nó, chứ không phải dọc xuống.
• =SEQUENCE(12,,,0)

Hình 4-2Có nguy cơ lặp lại chính mình
Bước 0 nghĩa đúng như vậy; không có gì được thêm vào giá trị được đánh số tiếp theo. Bắt đầu với 1 và kết thúc với 1 – 12 lần.
Và hãy nhắc mình rằng tất cả các chuỗi này đều tỏa ra từ một công thức duy nhất. Nhớ nhé – chúng ta đang ở trong lãnh địa mảng động (dynamic array).
Các khả năng sinh sôi nảy nở
Giờ khi bạn đã quen với SEQUENCE, bạn có thể bắt đầu nghĩ đến đủ mọi cách mà hàm này có thể phục vụ ý bạn, đôi khi kết hợp với các hàm khác, và với một chút định dạng khéo léo.

Hình 4-3Sẵn sàng đếm: danh sách tên cần được đánh số
• =SEQUENCE(COUNTA(B2:B1000))
• =SEQUENCE(4)

Hình 4-4Danh sách A, được đánh số trong cột A
Đơn giản nhưng thật sự hữu ích, tuy nhiên cần lưu ý vài điều. Thứ nhất, đừng cố gán ID cho các tên bằng kỹ thuật này, vì nếu bạn sắp xếp các tên, các con số sẽ không đi kèm theo chúng. Công thức SEQUENCE chỉ đếm các tên, chứ không quan tâm tên nào hiện đang nằm cạnh giá trị tràn (spilled value) nào. Và thứ hai, nhớ nhé – bạn không thể ghi công thức trên vào một bảng (table).
Lưu ý
Dù trước đó chúng ta đã nhận xét rằng bình thường bạn không thể xóa một giá trị tràn (khác với công thức thật sự), thì ở đây bạn có thể xóa một hàng chứa một trong các giá trị, và SEQUENCE sẽ tự điều chỉnh lại cho phù hợp. Do đó, nếu bạn xóa hàng chứa giá trị được đánh số 3, hàng bên dưới sẽ nhận lấy số 3, v.v.
Một tràng ngày tháng
• =SEQUENCE(5,7,TODAY(),1)

Hình 4-535 ngày, một công thức
• =SEQUENCE(5,7,44664,1)
Và chuyển phần tràn sang định dạng ngày thích hợp.
• =SEQUENCE(365,,44562)
44562 biểu thị ngày 1 tháng 1 năm 2022, và vì vậy công thức của chúng ta sẽ tạo chuỗi tất cả các ngày trong năm 2022 xuống một cột – và cho phép bạn nhập ghi chú liên quan đến từng ngày vào cột ngay bên phải nó. Hãy nhớ rằng các đối số bị bỏ qua ở đây – số cột và bước nhảy – mặc định là 1.
• =SEQUENCE(13,,6/24,1/24)
Để phân tích công thức: số 13 thể hiện số hàng mà chuỗi yêu cầu – 13, vì hàng đầu tiên trả về 6:00 sáng, và chúng ta cần thêm 12 hàng nữa để đánh dấu các khoảng thời gian cho cả 12 giờ.

Hình 4-6Từ bình minh đến hoàng hôn; 12 giờ qua SEQUENCE
PMT, Một Lần Nữa: Phần Tiếp Theo, với Sequence

Hình 4-7Lần thứ hai: công thức PMT, sắp được kết hợp với SEQUENCE
• =SEQUENCE(,5,0.02,0.01)
Năm cột, số bắt đầu là .02 (tất nhiên là 2%, theo định dạng mong muốn), và khoảng cách là .01.
• =SEQUENCE(6,,12,12)
• =PMT(G7#/12,F8#,G4)

Hình 4-8Ba công thức, 30 mức lãi suất
(Và hãy chú ý các tham chiếu dấu thăng trong công thức.)

Hình 4-9Gộp lãi của chúng ta: 48 kế hoạch thanh toán
• =SEQUENCE(,G1,0.02,0.01)
điều này sẽ cho phép bạn nhập bất kỳ giá trị nào vào G1 mà không cần phải chỉnh sửa công thức. Mục nhập G1 sẽ ghi lại bao nhiêu khoảng lãi suất tùy theo nhu cầu của bạn.
Và tất nhiên, bạn cũng có thể làm điều tương tự với tần suất thanh toán, bằng cách thay thế một giá trị mới cho số 6 trong SEQUENCE của nó. Như vậy chúng ta thấy rằng khi làm việc một cách linh động, các kịch bản mới có thể tự nảy ra trong tích tắc.
Bảng Cửu Chương Một-Công-Thức
Giờ hãy chuyển từ thời gian sang số lần. Giả sử chúng ta muốn xây dựng một bảng cửu chương – không phải kiểu truyền thống (theo đúng nghĩa đen), mà là một bảng linh động, một bảng có thể nắm bắt bất kỳ hai dải giá trị nào và hiển thị ngay lập tức tất cả tích số của chúng. SEQUENCE có thể làm được việc đó – và chỉ với tổng cộng một công thức duy nhất.
Bắt đầu với một trang tính trống và nhập số 5 vào B6 và 10 vào C6. Những mục nhập đó sẽ truyền, trong lần chạy đầu tiên của chúng ta, các giá trị từ 1 đến 5 xuống một cột và từ 1 đến 10 ngang qua một tập hợp các cột, giúp tạo thành đường viền của một ma trận sẽ nhân mỗi giá trị với mọi giá trị khác.
• =SEQUENCE(B6)*SEQUENCE(,C6)

Hình 4-10Thời thế đổi thay: một bảng cửu chương linh động chỉ với một công thức
Tuyệt vời, phải nói là vậy. Giờ hãy nhập các giá trị khác nhau vào B6 và C6, và bảng sẽ thay đổi để phản ánh các đầu vào mới, với số cột và số hàng mở rộng và thu hẹp tương ứng. Nó thật linh động.
Thực ra, công thức này đưa chúng ta trở lại một bài học mà chúng ta đã học rồi, đó là phần thảo luận của chúng ta trong Chương 3 về cách các dải vuông góc với nhau tương tác với nhau. Ở đó chúng ta đã lưu ý rằng nếu chúng ta nhân hai dải như vậy, mỗi giá trị trong dải thứ nhất được nhân với mọi giá trị trong dải thứ hai – và đó chính xác là điều đang diễn ra ở đây. Công thức SEQUENCE thứ nhất phân phát các giá trị của nó xuống một cột, và công thức thứ hai đẩy các giá trị của nó ngang qua, vuông góc với công thức thứ nhất. Điểm khác biệt ở đây là hai công thức SEQUENCE không lấy các giá trị của chúng từ các dải trong trang tính, như chúng đã làm trong Chương 3; các chuỗi 1-5 và 1-10 được lắp ráp bên trong công thức của chúng, sau đó tất cả kết quả tràn ra ma trận.
Viết lại CODE

Hình 4-11Mảng bên trong MID, bên trong CODE
• =CODE(MID(C6,SEQUENCE(LEN(C6)),1))
• =SEQUENCE(8)

Hình 4-12Mười ký tự để đếm? Không vấn đề gì
Và đó rõ ràng là cách tiếp cận hiệu quả và mạnh mẽ hơn.
• =CODE(MID(C6,SEQUENCE(,LEN(C6)),1))
Dấu phẩy nhỏ ngay trước LEN đó đẩy LEN(C6) vào đối số thứ hai của SEQUENCE, nơi nó chuyển sang vùng lãnh thổ của cột.
Nhìn về phía trước
Nhưng tôi lại lan man rồi. Chắc hẳn bạn đã nắm được ý nghĩa của SEQUENCE đến giờ, và chỉ cần vài lần thực hành qua lại là bạn sẽ thành thạo SEQUENCE ngay. Giờ chúng ta có thể ghé thăm một thành viên khác của nhóm mảng động (dynamic array) – UNIQUE.
5. UNIQUE: Một hàm độc nhất
Điều gì khiến nó độc đáo?
[image: ]
Hình 5-1Điểm bán hàng: Dữ liệu nhân viên bán hàng sẽ chịu tác động của hàm UNIQUE
Vấn đề tất nhiên nằm ở việc tên của mỗi nhân viên bán hàng xuất hiện lặp đi lặp lại trong trường dữ liệu – vì chúng ta muốn xem mỗi tên đúng một lần.
• =UNIQUE(Salesperson)

Hình 5-2Chỉ một lần: mỗi nhân viên bán hàng được liệt kê duy nhất
Tuyệt vời – người dùng Excel đã tìm kiếm kiểu hiệu suất đó từ lâu rồi.
Và nếu bạn định nghĩa lại tập dữ liệu thành một bảng và thêm tên mới vào trường Salesperson, UNIQUE sẽ đảm bảo rằng tên của họ tự động xuất hiện trong kết quả của nó.
• =COUNTA(UNIQUE(Salesperson))
• =SORT(UNIQUE(Salesperson))
sẽ lại trả về tên các nhân viên bán hàng một cách duy nhất, nhưng lần này theo thứ tự bảng chữ cái (SORT và SORTBY sẽ chính thức xuất hiện trong chương tiếp theo).
Cách nó hoạt động
• =UNIQUE(range/array,by column,exactly once)
Lưu ý
Thuật ngữ “range/array” (dải/mảng) đơn giản chỉ để xác định dữ liệu sẽ bị ảnh hưởng bởi hàm, thừa nhận rằng, xét về mặt thuật ngữ, dải của người này có thể là mảng của người khác. Ở đây, range và array thực chất là tương đương nhau.

Hình 5-3Định hướng lại; tìm những tên duy nhất trong một dải nằm ngang
• =UNIQUE(B7:F7,1)

Hình 5-4Thiếu mất thứ gì đó: chỉ trả về những tên duy nhất
Lưu ý rằng, không giống như SEQUENCE, cả dải dọc lẫn dải ngang đều được UNIQUE tham chiếu trong đối số đầu tiên. Chính số 1 tùy chọn ra lệnh cho công thức nhận diện dải đó là dải nằm ngang (bạn cũng có thể nhập từ TRUE thay cho giá trị 1).
• =UNIQUE(B7:F7,1,1)
sẽ cho ra Jane, Mark, Alice (một lần nữa, số 1 gắn với đối số thứ ba cũng có thể được thay bằng từ TRUE).
Dù bạn có thể khó mà nghĩ ra một ứng dụng thực tế nào cho lựa chọn “đúng một lần”, thì đây là vài khả năng. Nếu bạn cần tìm lỗi đánh máy trong một danh sách tên, lựa chọn “đúng một lần” có thể – có thể thôi – hữu ích phần nào. Nếu bạn đã lỡ gõ nhầm Peacock một lần trong trường Salesperson, đối số thứ ba của UNIQUE sẽ tìm ra nó – nhưng tất nhiên nếu tôi đã mắc cùng lỗi đó nhiều lần, thì nó sẽ không làm được.
Bạn cũng có thể áp dụng đối số “đúng một lần” cho, chẳng hạn, một danh sách tên sinh viên mà mỗi tên chỉ được nhập một lần duy nhất. Khi đó, chạy UNIQUE với đối số “đúng một lần” sẽ chỉ đơn giản là nhân bản toàn bộ danh sách – nhưng sẽ loại trừ bất kỳ tên nào vô tình bị nhập hai lần.
UNIQUE trải rộng khắp nhiều trường
• =UNIQUE(Country:Salesperson)
[image: ]
Hình 5.5Duy nhất trên bình diện quốc tế: mỗi nhân viên bán hàng được ghép với mọi quốc gia mà anh/cô ấy làm việc
(Một lần nữa, những dữ liệu này có thể được sắp xếp, và có lẽ bạn sẽ muốn làm đúng như vậy; nhưng cách sắp xếp cụ thể sẽ được dành cho chương tiếp theo.)
Công thức hoạt động bằng cách triển khai dấu chấm phẩy để liên kết các trường Country và Salespersons liền kề, tạo nên một kiểu siêu trường (meta-field) mà, hiểu theo thuật ngữ tham chiếu ô, đọc là A2:B799. Và UNIQUE sau đó tiến hành phân phát mọi tổ hợp duy nhất của Country và Salesperson vào dải tràn (spill range).
• =UNIQUE(first field:third field)
Biểu thức đó sẽ trải dài trên cả ba trường.
Những trường xa cách
[image: ]
Hình 5-6Các quốc gia xa xôi: trường Country và Salespersons bị ngăn cách bởi một trường thứ ba
Với tình huống đó, các bước để thu thập các giá trị UNIQUE cho Country và Salesperson sẽ phức tạp hơn một chút. Chúng ta cần gắn thêm hàm INDEX, một công cụ bảng tính kinh điển mà, giống như bao hàm cốt lõi khác, đã trải qua một cuộc cải tổ lớn về mảng động (dynamic array).
[image: ]
Hình 5-7Lại là những điểm số đó
• =INDEX(A1:G11,3,4)
sẽ nhắm trúng 87, điểm số nằm ở hàng thứ ba và cột thứ tư của vùng dữ liệu. Nhưng giờ đây INDEX đã được trang bị một khả năng mới, một khả năng quan trọng – đó là đánh dấu và tách ra toàn bộ các vùng. Và ở đây, trong trường hợp của chúng ta với các trường Country và Salesperson bị ngăn cách bởi một trường thứ ba ở giữa, chúng ta muốn INDEX tách Country và Salesperson ra khỏi các cột hiện tại của chúng và đặt chúng vào một tập dữ liệu tạm thời mới chỉ gồm hai cột/trường đó; và một khi chúng đã được tái hợp, chúng ta có thể chạy UNIQUE với cặp Country:Salesperson mà chúng ta đã thấy.
• =INDEX(A1:C800,SEQUENCE(ROWS(A1:C800)),{1,3})
Và sau đó chúng ta bọc UNIQUE quanh toàn bộ biểu thức đó.
Rõ ràng công thức đó cần được giải thích đôi chút, dù nó có nhắc lại một số thành phần quen thuộc (hãy nhớ rằng giờ chúng ta đang làm việc với tập dữ liệu nằm trong trang Non-adjacent UNIQUE thứ hai).
Đầu tiên, A1:C800 thể hiện nhu cầu của chúng ta chỉ cần cột thứ nhất và cột thứ ba trong vùng dữ liệu, nằm ở cột A và C – những cột lưu dữ liệu Country và Salesperson. Chúng ta không quan tâm đến dữ liệu ở cột D và E, và vì thế có thể loại chúng ra khỏi tham chiếu vùng ban đầu. Nhưng chúng ta cũng cần loại trừ cột B, trường ghi lại Order Dates – bởi vì nếu không loại bỏ dữ liệu ở cột B, kết quả UNIQUE sẽ trả về các tổ hợp duy nhất của cả ba cột – A, B và C.
• =INDEX(A1:C800,800,{1,3}))
thì chỉ có hàng 800 được trả về.
Còn về tham chiếu mảng đặt trong dấu ngoặc nhọn ở đối số cột của INDEX, mục đó cũng quen thuộc; ở đây nó chọn cột thứ nhất và cột thứ ba trong vùng dữ liệu – những cột chứa dữ liệu mà chúng ta muốn.
• =UNIQUE(INDEX(A1:C800,SEQUENCE(ROWS(A1:C800)),{1,3}))
Và biểu thức đó sẽ mang lại chính xác những kết quả mà chúng ta thấy trong Hình 5.5.
Ghi chú
Một bài tập thay thế cho bài tập trên sẽ được đưa ra trong chương về hàm CHOOSECOLS hoàn toàn mới.
Bắt đầu cộng dồn lại
Sở thích của UNIQUE trong việc lấy các giá trị hoặc văn bản đơn lẻ trong một vùng có thể được tận dụng cực kỳ hiệu quả để tổng hợp dữ liệu theo một biến, hoặc nhiều biến. Để minh họa cho tuyên bố trừu tượng đó bằng một trường hợp thực tế, giả sử chúng ta chỉ muốn xác định mỗi nhân viên bán hàng đã kiếm được bao nhiêu tiền (chúng ta quay lại trang tính đầu tiên trong tệp UNIQUE). Đó có phải là việc mà bảng pivot (pivot table) có thể làm không? Đúng vậy, nhưng cặp đôi năng động gồm UNIQUE và SUMIF (hoặc SUMIFS) kiểu cũ có thể tạo ra kết quả tự động tính toán lại ngay lập tức với dữ liệu mới, cũng như tích hợp các bản ghi mới được thêm vào dữ liệu nguồn.
• =SUMIF(Salesperson,G4#,Order_Amount)
[image: ]
Hình 5-8Điểm bán hàng: UNIQUE cung cấp tiêu chí cho SUMIF
Lưu ý G4# biểu thị ô mà UNIQUE được đặt vào, và đóng vai trò là tiêu chí của SUMIF.
• =TRANSPOSE(UNIQUE(Country))
[image: ]
Hình 5-9Ma trận đang hình thành: Salesperson và Country trong một ấn tượng bảng pivot
• =SUMIFS(Order_Amount,Salesperson,G4#,Country,H3#)
[image: ]
Hình 5-10Thỏa sức tung hoành: Tổng doanh số theo các trường Salesperson và Country
Và một lần nữa, bất kỳ tên Salesperson và/hoặc Country mới nào chúng ta thêm vào tập dữ liệu sẽ tìm được vị trí của chúng trong các kết quả trên, một khi chúng ta chuyển tập dữ liệu thành một bảng (table). Nhưng vì công thức của chúng ta tham chiếu đến Salesperson và Country theo dạng mảng động (dynamic array), nên không cần phải viết lại công thức.
Và đúng vậy, ảnh chụp trên có nét tương đồng đáng kinh ngạc với một bảng pivot; và thực sự, mảng động có thể tái tạo sức mạnh tính toán của các bảng đó, ít nhất là một phần (dù không hoàn toàn), và với ưu điểm là tự động tính toán lại ngay lập tức mọi bản ghi mới được ghi vào dữ liệu nguồn. Và điều đó để lại cho bạn thêm một quyết định thiết kế bảng tính nữa: mảng động hay bảng pivot? Một điều mới mẻ để suy ngẫm.
Tiếp theo
Giờ đây khi đã kết thúc phần giới thiệu về hàm UNIQUE, chúng ta có thể chuyển sang một cặp hàm mảng động liên quan mà bạn chắc chắn sẽ muốn học và thành thạo – SORT và SORTBY.
6. SORT và SORTBY: Bảng chữ cái (và cả những thứ ngược lại)
Sắp xếp là một trong những nguyên liệu quen thuộc của bảng tính, luôn được ném vào các hỗn hợp dữ liệu. Và việc ném ấy cũng ngày càng dễ dàng qua các thế hệ. Có thể bạn không nhớ những kiểu sắp xếp thời đồ đá có trong các thế hệ đầu của Lotus 1-2-3, khi người dùng phải chọn toàn bộ tập dữ liệu cần sắp xếp trước khi tiến hành; nhưng dù sao thì bạn cũng không cần phải nhớ.
Nhưng chắc chắn bạn sẽ muốn học, và ghi nhớ, cách mảng động (dynamic array) mới xử lý việc sắp xếp, được thúc đẩy bởi cặp hàm SORT và SORTBY. Điểm mới của chúng, trước hết, là khác với cách sắp xếp truyền thống mà chúng ta đã biết và sử dụng (nếu không muốn nói là yêu thích), SORT và SORTBY không sắp xếp trực tiếp một cơ sở dữ liệu. Tất nhiên, cho đến nay, nếu bạn muốn thực hiện việc sắp xếp một tập dữ liệu thông thường theo một trường, bạn sẽ nhấp vào bất kỳ ô nào trong trường đó rồi gọi một trong các nút Sort nằm trên ribbon Home hoặc Data, hoặc một nút được gắn vào menu ngữ cảnh khi nhấp chuột phải. Điểm mấu chốt một lần nữa là theo những kỹ thuật này, chính tập dữ liệu thực tế là thứ được sắp xếp.
Nhưng SORT và SORTBY tạo ra một bản sao của tập dữ liệu và sắp xếp bản sao đó thay vào đó, nhờ vậy giữ nguyên dữ liệu gốc. Việc bạn thấy hành động nhân bản này có hơi lộn xộn hay không – vì thực chất bạn đã tạo một bản sao của tập dữ liệu gốc – là tùy bạn, và gắn với bất kỳ mục đích nào bạn mang đến cho công việc của mình. Nhưng có lẽ bạn sẽ kết luận rằng, với hầu hết các ý định bảng tính của mình, sắp xếp bằng SORT và SORTBY thực sự là một nước đi hiệu quả.
Cách SORT hoạt động
• =SORT(range/array,sort_index,sort_order,by_col)

Hình 6-1Các nhân viên bán hàng đang bị xáo trộn, tạm thời
• =SORT(All,2)
[image: ]
Hình 6-2Buchanan đứng đầu trong số các nhân viên bán hàng
Hẳn bạn đã nhận thấy một số điểm khác biệt giữa kết quả tràn ra và tập dữ liệu nguồn gốc. Thứ nhất, dữ liệu đã trở về định dạng mặc định của chúng, ví dụ, các Order Date đã được trả về định dạng số nguyên bản, và Order Amount hiển thị số chữ số thập phân thay đổi. Vì vậy, bạn sẽ cần khôi phục các định dạng mong muốn.
Thứ hai, việc sắp xếp đã bỏ qua các tiêu đề trường của tập dữ liệu, trong trường hợp của chúng ta là vì dải tập dữ liệu All bắt đầu từ hàng 2 (một điểm chúng ta đã đề cập vài chương trước). Do đó, nếu bạn cần những tiêu đề đó – và tất nhiên là bạn có thể cần – bạn có thể sao chép và dán bản gốc lên trên kết quả tràn ra.
Lưu ý
Ngay cả khi định nghĩa dải của bạn cho All bao gồm hàng 1 – hàng tiêu đề – SORT vẫn sẽ tiếp tục bỏ qua nó.
• =SORT(All)
tập dữ liệu sẽ tự động sắp xếp theo cột đầu tiên của nó. Nó buộc phải chọn một cột để sắp xếp, và theo mặc định nó chọn cột/trường một.
Đối số thứ ba của SORT, thứ tự sắp xếp, muốn biết bạn muốn sắp xếp cột được chỉ định theo thứ tự tăng dần (bằng cách nhập 1) hay giảm dần (qua -1). Nhưng chúng ta đã thấy rằng khi bỏ qua đối số này, công thức sẽ thực hiện sắp xếp tăng dần mặc định.
Đối số cuối cùng của hàm – theo cột – có lẽ là đối số khó nhằn nhất, vì chúng ta không quen nghĩ đến những kiểu sắp xếp sắp thứ tự tập dữ liệu theo chiều ngang. Nhưng SORT vẫn có thể làm đúng điều đó.

Hình 6-3Tư duy ngang: sắp xếp theo cột
(Lưu ý rằng tên các trường ở đây – Test, Jane và Ted – bao hàm dữ liệu của chúng theo chiều ngang.)
• =SORT(scores,3,,1)
[image: ]
Hình 6-4Quỹ đạo đi lên: điểm của Ted, sắp xếp từ thấp đến cao
Ở đây số 3 trong SORT hướng dẫn công thức sắp xếp tập dữ liệu theo hàng thứ 3 của nó, hàng chứa điểm của Ted. Một lần nữa, các tiêu đề trường đã được miễn khỏi việc sắp xếp.
• =SORT(UNIQUE(Salesperson))
Sắp xếp theo nhiều trường
Bạn sẽ nhớ rằng SORT mặc định chỉ giới hạn việc sắp xếp một tập dữ liệu theo một cột duy nhất. Tuy nhiên, thực tế bạn có thể tinh chỉnh hàm này để khiến nó sắp xếp theo nhiều trường, thông qua một người bạn cũ, hay cũng có thể là kẻ thù – hằng mảng đặt trong dấu ngoặc nhọn quen thuộc (cảm ơn trang Ablebits vì gợi ý này).
• =SORT(All,{2,1})

Hình 6-5Sắp xếp hai cột: nhân viên bán hàng trước, rồi đến quốc gia
Một lần nữa, Buchanan đứng đầu trường Salesperson, với tập hợp các quốc gia của anh/cô ấy được dẫn đầu bởi Canada, tiếp theo trong thứ tự sắp xếp là Pháp (hãy nhớ lại rằng có thể cần định dạng lại các trường).
• =SORT(All,{2,5},{1,-1})

Hình 6-6Lên xuống: Salesperson sắp xếp từ A đến Z, Order Amount từ cao nhất đến thấp nhất
[image: ]
Hình 6-7Tương tự như vậy: Callahan đứng kế tiếp theo thứ tự bảng chữ cái với doanh số lại hướng xuống dưới, theo kiểu sắp xếp giảm dần
Sắp xếp các chữ số: Tất cả trong cùng một ô
• 1587078421
• 0112457788
Và chúng ta muốn những chữ số đó được tái kết hợp thành chuỗi đó bằng một công thức duy nhất.
• =MID(B4,SEQUENCE(LEN(B4)),1)
• =MID(B4,{1;2;3;4;5;6;7;8;9;10},1)

Hình 6-8Giữa chừng quá trình: MID trích xuất từng chữ số
(Lưu ý rằng các chữ số được căn lề trái, ám chỉ rằng những kết quả này thực ra là văn bản, không phải số.)
• =SORT(MID(B4,SEQUENCE(LEN(B4)),1))
[image: ]
Hình 6-9Gọn gàng và ngăn nắp: các chữ số, giờ đã được sắp xếp
(Một lần nữa, các chữ số đã thừa hưởng định dạng văn bản, nhưng Excel đọc chúng như gần giống số và có thể sắp xếp chúng.)
• =CONCAT(SORT(MID(B4,SEQUENCE(LEN(B4)),1)))
[image: ]
Hình 6-10Đúng vị trí – các chữ số đã được sắp xếp
Và tất nhiên, bất kỳ tập hợp chữ số nào khác bạn nhập vào B4 cũng sẽ được sắp xếp ngay lập tức.
SORTBY: Người bạn đồng hành của SORT
Chúng ta đã thấy rằng SORT là một phương tiện rất hiệu quả và nhanh nhẹn để sắp xếp dữ liệu một cách linh động; vậy thì SORTBY có thể làm được gì mà người bạn đồng hành của nó không thể?
• =SORTBY(range/array,by_range/array,sort_order,by_range/array2,sort_order…)
• =SORTBY(All)
Và SORT thì làm được. Vậy thì SORTBY mang đến điều gì cho bữa tiệc này?
Đây là điều đó. SORTBY cho phép người dùng sắp xếp một trường, hoặc nhiều trường, theo một trường khác không nhất thiết phải xuất hiện trong kết quả sắp xếp, và cũng không nhất thiết phải nằm trong cùng tập dữ liệu.
• =SORTBY(Name,Art,-1)

Hình 6-11Bức tranh đẹp: Clothilde đứng đầu điểm thi môn Art
Ở đây, SORTBY dựa vào một trường sắp-xếp-theo đã bị loại khỏi kết quả. (Nhớ rằng đối số -1 kích hoạt kiểu sắp xếp giảm dần, từ cao xuống thấp.)

Hình 6-12Quan hệ trường, đã tách rời: trường eng bị tách khỏi tập dữ liệu
• =SORTBY(name,eng,-1)

Hình 6-13Trường vừa có, vừa không: tên học sinh được sắp xếp theo trường eng
Bạn sẽ để ý rằng điểm eng 98 được khắc vào hàng thứ ba của trường, tương ứng với vị trí của Maureen trong trường name – hàng thứ ba. Như vậy hai trường được xếp thẳng hàng với nhau, dù chúng bị ngăn cách bởi các cột và hàng. Và điều đó lại dạy chúng ta rằng để sự xếp thẳng hàng và kiểu sắp xếp tiếp theo đó diễn ra, hai trường phải có cùng số hàng.
Lưu ý
Chúng ta sẽ thấy sau này rằng hàm HSTACK mạnh mẽ có thể dễ dàng tái định vị các trường name và eng nằm cạnh nhau, tạo nên một tập dữ liệu mới.
• =SORT(All,2)
đề cập đến cột thứ hai trong tập dữ liệu; nhưng vì SORTBY cho người dùng quyền tự do sắp xếp theo một cột độc lập với bất kỳ tập dữ liệu nào, nên chỉ mục sắp xếp không thể hoạt động ở đó vì nó sẽ không biết số "2" đang ám chỉ cột nào.
Lưu ý Khi bạn gọi đến trường thứ hai (hoặc thêm nữa) trong SORTBY, đối số "thứ tự sắp xếp" của trường đó bắt buộc phải được nhập. Vì vậy, ví dụ, cú pháp này sẽ là bắt buộc, =SORTBY(Salesperson,,Country,-1). Ở đây, số 1 không thể bị lược bỏ khỏi đối số của trường thứ hai.
Tiếp theo
Sắp xếp dữ liệu là một trong những kỹ năng thiết yếu của bảng tính, và hai hàm SORT thuộc mảng động đã đưa công việc sắp xếp lên một tầm cao mới, xin lỗi vì chơi chữ. Giờ chúng ta sẽ chuyển sang xem xét một mục nhập tối quan trọng khác trong bản mô tả công việc của Excel, một mục cũng vừa được khoác áo mới hoành tráng và năng động – dưới dạng hàm FILTER.
7. Hàm FILTER: Cắt dữ liệu cho vừa vặn
Tập dữ liệu của bạn có thể nhiều đến mức "ngộp thở", nhưng đôi khi nhiều lại chưa chắc đã hơn. Ai dùng bảng tính cũng biết rằng dữ liệu của họ thường chứa nhiều thông tin hơn mức cần thiết ở thời điểm hiện tại, và sẽ tốt hơn nếu được cắt gọt một chút — dù chỉ tạm thời — nhưng phải thật sắc bén.
Và hàm mảng động FILTER mới của Excel hoàn toàn đủ sức đảm nhận việc đó. Cũng giống như SORT và SORTBY, FILTER mang đến một bộ giải pháp dựa trên công thức cho một công việc bảng tính kinh điển mà trước đây vốn được xử lý bằng đủ thứ công cụ, ví dụ như bộ lọc và slicer trong bảng pivot, tùy chọn Advanced Filter, và cả bộ lọc Filter tiêu chuẩn mà bạn thấy trên đầu các bảng biểu.
Tất nhiên, mỗi công cụ đều có chỗ đứng riêng, nhưng vì FILTER làm việc bằng công thức, nên bạn có cả một danh mục tiêu chí khổng lồ để triệu hồi dữ liệu, biến FILTER thành phương tiện cực kỳ mạnh mẽ và vô cùng linh hoạt để lấy ra đúng thứ bạn muốn từ dữ liệu. FILTER chính là con dao đa năng Thụy Sĩ của mảng động — nó có thể cắt, thái, xào nấu dữ liệu theo vô số cách.
Công thức
• =FILTER(range/array,include,if_empty)
Đối số đầu tiên, theo cách gọi chính thức của Excel là "array", yêu cầu tập dữ liệu bạn muốn lọc, và tất nhiên chấp nhận tên vùng (range) hoặc tên bảng (table) thay cho tọa độ ô.
Chính đối số thứ hai — "include" — là nơi tỏa ra sức mạnh của FILTER. Hãy bắt đầu với một bộ lọc đơn giản (tệp: FILTER, phỏng theo tuyển tập tải miễn phí Contexture của tác giả cùng nhà xuất bản Apress là Debra Dalgliesh. Một lần nữa, toàn bộ tập dữ liệu được đặt tên là All).
• =FILTER(All,City=L1)
<<<|||>
Hình 7-1Đếm hạt đậu: doanh số thực phẩm ở Beantown

(Một lần nữa, giống như với SORT, vùng tràn (spill range) kết quả thể hiện định dạng cơ bản, mặc định mà chắc chắn bạn sẽ muốn chỉnh sửa; và một lần nữa, kết quả không có dòng tiêu đề. Dòng đó có thể được sao chép và dán lên trên vùng tràn.)
City=L1
• =FILTER(All,Category=L1)
• vì Cookies là một mục nằm trong trường đó.
=IF(Category=L1…
• Giờ nói về đối số [If Empty] đó

• =FILTER(All,Category=L1,”Not found”)
Dòng chú thích đó sẽ thay thế thông báo lỗi.
Nhiều tiêu chí lọc: Khai thác dữ liệu nhiều hơn (hoặc ít hơn)
• =FILTER(All,(Category=L1)*(City=M1),“Not found”)
• (tiêu chí 1)*(tiêu chí 2)*(tiêu chí 3)
(Thực ra, dấu hoa thị – toán tử nhân của Excel – cũng đang thực hiện phép nhân bên trong công thức, nhưng ở đây ta có thể lướt qua chi tiết của thao tác đó.)

Hình 7-2Ăn vặt ở San Diego: bộ lọc hai tiêu chí
HOẶC Cân nhắc phương án thay thế này
• =FILTER(All,(City=L1)+(City=M1),“Not found”)

Hình 7-3Thực phẩm California: doanh số bán thực phẩm ở Los Angeles và San Diego
Điều phân biệt rõ ràng bộ lọc nhiều tiêu chí kiểu “hoặc” với kiểu “và” chính là việc thay dấu hoa thị bằng dấu cộng – không gì hơn.
Kết hợp linh hoạt: AND và OR cùng nhau
Câu hỏi tiếp theo: nếu bạn muốn lọc tất cả doanh số bán Cookies ở cả Los Angeles lẫn San Diego thì sao? Đúng là một bài toán hấp dẫn, vì nó đòi hỏi cả tiêu chí “và” lẫn “hoặc”. Ở đây, tôi muốn bộ lọc phát hiện các doanh số được tổng hợp ở Los Angeles hoặc San Diego – nhưng chỉ của Cookies. Vậy công thức này viết thế nào?
• =FILTER(All,((City=L1)+(City=M1))*(Category=N1),“Not found”)
• (City=M1))*(Category=N1)
bởi vì những cặp đó luôn gọi đến tiêu chí 2 và 3, vì chúng liền kề. Nhưng các bản ghi Los Angeles không phải lúc nào cũng khớp với Cookies, bởi vì thành phố đó nằm ở tiêu chí 1, và không liên kết trực tiếp với tiêu chí 3, tham chiếu Category.)

Hình 7-4Cal. Đếm: Doanh số bán bánh quy ở Los Angeles và San Diego
Giờ hãy quay lại công thức FILTER đầu tiên của chúng ta, công thức mà chúng ta đã dùng để trả về dữ liệu doanh số cho Boston. Theo định nghĩa, thì tất cả kết quả ở đó đều phải hiển thị tên thành phố đó trong trường City – và chính vì trường đó sẽ chỉ chứa toàn Boston, nên thật ra chúng ta không cần tất cả thông tin dư thừa đó. Kết quả là, vì những lý do trình bày hợp lý, chúng ta có thể muốn loại bỏ trường City khỏi bộ lọc này – và để thực hiện ý định đó, chúng ta có thể tái sử dụng công thức INDEX mà chúng ta đã nhắc đến ở Chương 5, trong quá trình tìm hiểu hàm UNIQUE.
Ở đây, công thức của chúng ta là
=FILTER(INDEX(All,SEQUENCE(ROWS(All)),{1,2,4,5,6,7,8}),City=M1,”Not found”)
Đừng để bị lừa hay bối rối; dù trông có vẻ dày đặc, nhưng bộ lọc ở đây vẫn gồm đúng ba đối số mà chúng ta đã làm việc từ đầu đến giờ. Công thức INDEX đang lắp ghép một tập dữ liệu tạm, lấy từ All trừ đi trường City – cột thứ ba trong All, do đó giải thích vì sao số 3 bị thiếu trong mảng trong ngoặc nhọn. Ngoài ra, hãy chú ý hàm SEQUENCE ở đây đang thực hiện đúng công việc mà nó đã làm trong công thức UNIQUE – nó đang đếm, và do đó bao gồm, tất cả các hàng trong tập dữ liệu All.

Hình 7-5Có gì đó bị thiếu – là cố ý. Trường City không còn ở đó.
Tất cả những Boston đó đã biến mất; và để chắc ăn, chúng ta cũng có thể đã loại bỏ trường Region – trường thứ hai của tập dữ liệu – khỏi công thức, bằng cách cắt bỏ số 2 khỏi mảng trong ngoặc nhọn – vì suy cho cùng, Boston luôn nằm ở vùng East.
Lưu ý
Phần thảo luận của chúng ta về hàm mảng động mới DROP trong một chương sau sẽ mô tả một cách thanh lịch hơn đáng kể để đạt được kết quả này
Còn việc lọc một phần của ô thì sao?
Đến đây, chúng ta đã học về việc lọc các trường mà dữ liệu chỉ gồm một từ, ví dụ như Cookies, hay Boston. Nhưng còn những ô chứa cái thường được gọi là văn bản phi cấu trúc (unstructured text) – tức là nội dung nhiều từ nằm gọn trong một địa chỉ ô duy nhất thì sao? Liệu FILTER có thể giúp chúng ta tìm ra một từ khóa, hay những từ được chọn từ đoạn văn bản dài hơn nằm trong một ô không?
Vâng, câu trả lời là một tiếng "có" dứt khoát. FILTER có thể trích xuất một cách điêu luyện những đoạn văn bản một phần từ một dải ô, và để lấy ví dụ, hãy mở file FILTER – text search, một bản phỏng theo bảng tính liệt kê các thành viên đương nhiệm của Hạ viện Hoa Kỳ (nguồn: Everypolitican (https://everypolitician.org/united-states-of-america/house/download.html)).
Giả sử ban đầu chúng ta muốn lọc trường tên để tìm tất cả các Nghị sĩ tên John. Vấn đề, tất nhiên, là tất cả các tên đều bị gộp chung vào từng ô riêng lẻ – tên, họ, và tên đệm – và chúng ta cần bằng cách nào đó tách "John" ra khỏi những mục dài hơn mà tên đó đã bị gom vào.
• =SEARCH(find_text,within_text,start_number)
Đối số start number là tùy chọn.
• =SEARCH(A2,A6)
sẽ tạo ra 10. Nếu văn bản được tìm kiếm không có ở đó, một thông báo lỗi #VALUE! sẽ thay thế vào ô đó. Tất nhiên, hãy nhớ rằng chúng ta sắp áp dụng SEARCH cho toàn bộ một dải tên, nhưng chúng ta đang ở chế độ mảng động (dynamic array), và đó là điều chúng ta có thể làm.
• =FILTER(name,ISNUMBER(SEARCH(B2,name)),“Not found”)
Hàm ISNUMBER bao quanh SEARCH sẽ kiểm tra một giá trị hoặc công thức xem nó có phải là số hay không; do đó, nếu việc tìm kiếm từng ô trong dải tên trả về một con số – nghĩa là cụm từ tìm kiếm đã được tìm thấy – thì ô đó sẽ tự đưa mình vào kết quả đã lọc.

Hình 7-6Nhập hạn chế: Các nghị sĩ có tên John – ở đâu đó trong tên của họ
Cách này có hiệu quả – kiểu như vậy. Nhưng chúng ta thấy rằng bộ lọc của mình đã gom được ba người Johnson – những người cũng chứa văn bản John – mà có lẽ chúng ta không hề nhắm tới. Một cách khắc phục: thay vào đó hãy nhập vào B2
John[dấu cách]

Hình 7-7Đúng ý hơn rồi: không gì ngoài John
Như vậy chúng ta thấy rằng FILTER làm rất xuất sắc việc tìm kiếm văn bản/từ khóa trên văn bản tự do, hay phi cấu trúc – một khả năng vô cùng linh hoạt và năng động.
Lưu ý
Một số cách tiếp cận để tách họ và tên riêng thành các ô riêng biệt sẽ được khám phá khi chúng ta xem xét các hàm mảng động mới nhất của Excel là TEXTBEFORE và TEXTAFTER.
Còn nhiều điều khác
• =FILTER(name,LEFT(name,1)=B2)

Hình 7-8Thành công bước đầu
• =COUNTA(B4#)
để đưa ra tổng số thành viên Quốc hội có tên bắt đầu bằng chữ cái được chỉ định.
Phép thuật con số của FILTER thêm giá trị vào các giá trị của bạn
Và tất nhiên, FILTER luôn sẵn sàng phục vụ bạn nếu bạn cần đếm các con số. Qua một ví dụ đơn giản, hãy gọi ra một tập dữ liệu trông quen thuộc, ở đây được lưu trong tệp FILTER: Values.
• =FILTER(All,Order_Amount>=H3)

Hình 7-9Tạo ra con số: doanh số bằng hoặc tốt hơn $2000
(Hãy nhớ rằng các toán tử lớn hơn và nhỏ hơn luôn đứng trước dấu = trong các công thức Excel.)
Giờ đến một tác vụ dựa trên giá trị khác, nếu bạn cần nghiên cứu tất cả doanh số được thực hiện, chẳng hạn, từ ngày 1 tháng 1 năm 2020 đến ngày 30 tháng 6 cùng năm đó – tức là một bản tóm tắt 6 tháng thì sao?
• =FILTER(all,(Order_Date>=H3)*(Order_Date<=I3))

Hình 7-10Doanh số của nửa năm
Lưu ý
Bạn cũng có thể nhập tiêu chí ngày tháng thông qua phương pháp hơi rườm rà hơn này, ví dụ: =FILTER(All,Order_Date=VALUE(“6/10/2013”))
Không còn những cái nhìn ngơ ngác về các hàng trống
Nếu bạn đang tìm kiếm một câu đố về chất lượng dữ liệu có thể khiến ngày làm việc của bất kỳ nhà phân tích bảng tính nào trở nên cực kỳ khó khăn, hãy bắt đầu với các hàng trống. Những khoảng trống rỗng này là nỗi ám ảnh của việc sắp xếp thông thường, bảng pivot và các bộ lọc truyền thống, nhưng một khi bạn làm quen với chương trình FILTER, bạn thực sự có thể làm được việc thật – ngay cả khi bạn để nguyên những khoảng trống đó.
Ví dụ, đây là một phiên bản chỉnh sửa của một bảng tính (Tệp: Filter – working with blank rows) được phát hành bởi một cơ quan ở Thành phố New York (để có tệp gốc, truy cập vào đây https://media.githubusercontent.com/media/thecityny/housing-lottery-data/master/housing-lotteries.csv)), trong đó liệt kê chi tiết các căn hộ nhà ở công cộng được cung cấp qua hình thức xổ số. Tuy nhiên, các hàng trống như bạn thấy đã có sẵn như vậy trong bảng gốc. Vậy chúng ta có thể làm gì? (Như thường lệ, tập dữ liệu được đặt tên là All, và tên các trường bắt nguồn từ hàng tiêu đề.)
• =FILTER(All,Rent<=B3)

Hình 7-11Có lẽ không phải điều bạn nghĩ đến: Những bất động sản miễn phí tiền thuê?
Và chúng ta nhận được kết quả sau, trích đoạn, trong Hình 7-11.
• =FILTER(All,(Rent<=B3)*(Rent<>0))
[image: ]
Hình 7-12Đúng kiểu rồi đấy
Tiếp theo là gì
Ừ thì, việc lọc một tập dữ liệu mà một nửa số hàng chẳng có gì trong đó nghe hơi kiểu mẹo vặt, nhưng bạn hiểu ý rồi đấy – với lại, nãy giờ mình đang làm việc với một bảng tính thật sự. Hàm FILTER có thể xử lý một tập con dữ liệu của bạn thỏa mãn gần như bất kỳ tiêu chí nào, và bạn càng nghĩ ra nhiều tiêu chí bao nhiêu, hàm này càng mạnh bấy nhiêu. Tiếp theo là một hàm mảng động rất khác, thực hiện một nhóm tác vụ cũng rất khác – RANDARRAY.
8. RANDARRAY: Hữu ích một cách khó lường
Có ai để ý rằng RANDARRAY là hàm mảng động duy nhất thật sự lén đưa chữ "array" vào tên của nó không? Lời giải thích của tôi cho điều thú vị này chắc chắn không làm bạn choáng ngợp vì độ sâu sắc của nó đâu. Theo tôi thì Excel phải phân biệt RANDARRAY với các tiền bối tạo số ngẫu nhiên là RAND và RANDBETWEEN, và ARRAY có vẻ là một thuật ngữ hoàn toàn ổn và mang tính mô tả để ghép với RAND lần này.
Đúng vậy, RANDARRAY thật sự tạo ra các mảng động, một cách nhanh chóng và dễ dàng, dù tính thân thiện với người dùng của nó không giải quyết được câu hỏi hiển nhiên trước đó: khi nào tôi sẽ dùng nó?
Cách viết
• =RANDARRY(rows,column,min,max,integer)
• =RANDARRAY(10)

Hình 8-1Đâu đó giữa 0 và 1: một mảng ngẫu nhiên mười hàng
• =RANDARRAY(,10)
• =RANDARRAY(10,10)

Hình 8-2Một trăm giá trị ngẫu nhiên
Giờ thì vì vùng tràn (spill range) được công thức điều khiển, tất cả các giá trị của nó sẽ thay đổi mỗi lần bảng tính làm mới (và điều đó bao gồm cả bất kỳ lần nhập dữ liệu nào thêm, ít nhất là theo mặc định). Nếu bạn cần cố định những giá trị đó – và rất có thể bạn sẽ cần – bạn có thể chọn toàn bộ vùng tràn của RANDARRAY và thực hiện Copy > Paste Values.
• =RANDARRAY(10,10,1,10,1)

Hình 8-3Một đống số nguyên
Lưu ý
Các chuyên gia thống kê vẫn khẳng định rằng các hàm ngẫu nhiên của Excel không thực sự ngẫu nhiên, nhưng với hầu hết mục đích thực tế thì chúng vẫn đáp ứng được yêu cầu tạo ngẫu nhiên. Để tìm hiểu kỹ thuật về một số vấn đề này, xem tại đây.)
Vài cách dùng, làm ơn
Tuy nhiên, câu hỏi trước đó của chúng ta vẫn cần được đặt lại: khi nào bạn sẽ dùng RANDARRAY?
• =RANDARRAY(50,,1,4,1)
Công thức đó sẽ trải ra 50 dòng giá trị ngẫu nhiên nằm trong khoảng từ 1 đến 4. Nếu kết quả khiến bạn lo lắng – ví dụ, nếu một đoạn kết quả nào đó chứa quá nhiều số 2 liên tiếp – chỉ cần làm mới bảng tính và kiểm tra lại. Khi bạn đã hài lòng với phân bố đó, hãy cố định các câu trả lời bằng Copy > Paste Values.
Nhưng nếu bài kiểm tra của bạn không đưa ra bốn lựa chọn được đánh số cho mỗi câu hỏi, mà thay vào đó là một sơ đồ trả lời theo bảng chữ cái – từ A đến D thì sao?

Hình 8-4Trao đổi chữ-số
• =VLOOKUP(A5#,score,2)

Hình 8-5Chuẩn từng chữ cái
“Đại loại như” ảnh chụp màn hình ở trên, bởi vì nếu bạn đã bấm theo từng bước, tập giá trị ngẫu nhiên của bạn sẽ không giống với tập ở trên. Và nếu bạn hài lòng với phân bố câu trả lời đó, bạn có thể tiến hành Copy > Paste Values và chốt các câu trả lời.
• =SORTBY(class,RANDARRAY(COUNTA(class)))
Biểu thức đó cần được xem lại một chút, vì nó đưa chúng ta trở lại với hàm SORTBY. Chúng ta đang sắp xếp tên học sinh nằm trong vùng class theo một tập giá trị ngẫu nhiên mà sẽ không xuất hiện trong bảng tính. Hãy nhớ rằng SORTBY có thể sắp xếp một vùng/mảng theo một vùng khác hoàn toàn độc lập với dữ liệu cần sắp xếp – vùng đó không cần phải nằm cạnh dữ liệu được sắp xếp, thậm chí không cần phải được ghi vào các ô của bảng tính. Ở đây, trường sắp xếp theo bao gồm mười giá trị ngẫu nhiên chỉ tồn tại trong “bộ não” của công thức, và điều đó không sao cả; SORTBY vẫn sẽ hoạt động. (Chúng ta cũng không bận tâm về việc RANDARRAY xuất ra những giá trị thập phân mặc định đó – chúng ta chỉ cần mười số ngẫu nhiên, mà dù sao chúng ta cũng không thực sự nhìn thấy chúng.)

Hình 8-6Chỗ ngồi không thể gian lận: ngẫu nhiên hóa vị trí học sinh trong lớp học
Tất nhiên, một lần nữa, trình tự chỗ ngồi của bạn gần như chắc chắn sẽ khác với ảnh chụp ở trên, vì chúng ta đang làm việc với RANDARRAY. Và một lần nữa, nếu bạn thấy kết quả của mình khiến bạn phải dừng lại – nghĩa là, đôi bạn thân Zelda và Emily lại ngồi cạnh nhau – chỉ cần làm mới bảng tính cho đến khi kết quả của bạn đạt được phân bố chỗ ngồi thỏa mãn nhu cầu của bạn (chúng ta sẽ tìm hiểu thêm về sắp xếp chỗ ngồi trong chương về WRAPCOLS).
Kiểu ứng dụng RANDARRAY này cũng có thể được áp dụng cho xổ số, trong đó số vé có thể được sắp xếp theo bài tập ở trên.
Tung xúc xắc, theo cách ảo
Với bài tập cuối cùng, chúng ta có thể đi qua một cách để tạo ra 1000 kết quả tung xúc xắc giả định và đếm phân bố các kết quả đó (tức là số lần xuất hiện của mặt 2, mặt 3, v.v.) – nói ngắn gọn, đây là một kiểu phân tích tần suất.
• =RANDARRAY(1000,2,1,6,1)

Hình 8-7Mô phỏng Las Vegas – kết quả tung xúc xắc, kiểu mảng động
• =SUM(B4#)
vì biểu thức đó sẽ chỉ đơn giản gom tất cả 2000 giá trị vào một tổng lớn duy nhất. Chúng ta cần tính tổng từng hàng riêng lẻ, để chuẩn bị cho việc tính tần suất kết quả. Ở đây có vài lựa chọn cho chúng ta, nhưng cách ngắn nhất trông như thế này, tại ô D4:
(Một lần nữa, vẫn có các lựa chọn thay thế khác, nhưng chúng dài dòng hơn. Một khả năng như vậy là hàm BYROW, một hàm đặc thù của giao thức phát triển công thức LAMBDA mới của Excel, sẽ đưa chúng ta vượt ra ngoài phạm vi của cuốn sách này. Nhưng ngay cả giải pháp BYROW cũng tốn nhiều thao tác bàn phím hơn cách của chúng ta.)

Hình 8-8Cắt và chia nhỏ các kết quả
Bây giờ, một lần nữa, nếu kết quả trông ổn, hãy Copy > Paste Values toàn bộ kết quả. Chúng ta sẽ đặt tên vùng cho D4:D1003 là dice.
• =SORT(UNIQUE(dice))

Hình 8-9Hai con xúc xắc, mười một kết quả
(Chúng ta cũng có thể viết =SEQUENCE(11,,2,1) trong ô H9, qua đó đảm bảo rằng tất cả 11 kết quả xúc xắc đều sẵn sàng để đếm. Về lý thuyết, công thức UNIQUE của chúng ta có thể bỏ sót một hoặc hai kết quả, nếu chẳng may với xác suất cực kỳ nhỏ là không có mặt 2 nào hoặc mặt 12 nào được công thức trong B4# “tung” ra, chẳng hạn.)
• =COUNTIF(dice,H9#)/1000

Hình 8-10Chơi với tỷ lệ phần trăm: các kết quả tung xúc xắc
Lưu ý rằng nếu bạn không cố định tất cả các kết quả trong cột B và C bằng quy trình Copy > Paste Values, thì kết quả sẽ vẫn “động”, thay đổi mỗi khi bảng tính làm mới và do đó liên tục thay thế các tỷ lệ phần trăm trong ảnh chụp màn hình ở trên bằng những tỷ lệ mới.
Tiếp theo
Chúng ta sẽ còn nói thêm về RANDARRAY, và một vài cách nó có thể kết hợp với các hàm động thế hệ tiếp theo của Excel. Nhưng trước tiên, hãy nói đôi lời – chỉ đôi lời thôi – về một hàm khá kỳ lạ mà có thể bạn sẽ chẳng bao giờ dùng đến – toán tử giao nhau ngầm (implicit intersection operator).
9. Toán tử giao nhau ngầm: Hàm mà có lẽ bạn sẽ chẳng bao giờ dùng
Chúng ta vừa nói điều đó rồi, và sẽ nhắc lại lần nữa: có lẽ bạn sẽ chẳng bao giờ dùng đến toán tử giao nhau, vì những lý do mà chúng ta sắp trình bày chi tiết. Nhưng dù sao thì toán tử này vẫn tồn tại; và công dụng của toán tử – được ký hiệu bằng dấu @ – là thu gọn một vùng tràn mảng động (dynamic array spilled range) thành kết quả một ô duy nhất, qua đó mô phỏng hành vi của các công thức trong các phiên bản Excel trước 365.
Một ví dụ: bạn còn nhớ vùng Beatles của chúng ta cách đây vài trăm trang, liệt kê tên của bốn thành viên Fab Four thuở nào. Trong Excel 365, nhập =Beatles tất nhiên sẽ tràn các tên xuống theo cột mà tên vùng được nhập vào. Nhưng ở Chương 2, chúng ta đã chỉ ra rằng việc mô phỏng hành động đó trong một phiên bản trước 365, theo mặc định, sẽ chỉ trả về mục đầu tiên trong vùng, hoạt động dưới sự chi phối của cái gọi là giao nhau ngầm. Như đã mô tả trong chương đó, cách duy nhất – và có phần hạn chế – để trả về cả bốn tên đòi hỏi người dùng phải chọn trước bốn ô đích tương ứng với kết quả dự kiến gồm bốn tên, nhấp vào Thanh công thức (Formula Bar), viết =Beatles ở đó, và hoàn tất quá trình bằng cách gõ tổ hợp Ctrl-Shift-Enter huyền thoại, kiểu như một hợp âm của bảng tính vậy. Nhưng vì bạn cần chọn bốn ô đó trước khi tiến hành, nên kỹ thuật này không hẳn thuộc kiểu mảng động.
[image: ]
Hình 9-1Thiếu hụt đầu ra: phép nhân nhiều ô thời trước mảng động
[image: ]
Hình 9-2Cùng công thức, kết quả khác
Giờ nếu bạn thấy kết quả đó có chút kỳ lạ, thì việc viết cùng công thức đó vào ô C2, xuống một ô, sẽ cho ra
Hơn nữa, kể cả khi bạn hoàn tất các công thức này bằng chính tổ hợp Ctrl-Shift-Enter mang tính biểu tượng, chúng vẫn cho ra kết quả một ô duy nhất.
Và cho trọn vẹn, nếu bạn viết đúng công thức đó vào ví dụ như ô D12, bạn sẽ nhận ngay một thông báo lỗi #VALUE! trong ô đó.
Tất cả những kết quả kỳ quặc này đều hé lộ cách hoạt động của giao nhau ngầm, và bạn sẽ vui mừng khi biết rằng nó đã thuộc về thì quá khứ. Bởi vì các công thức trước 365 không có khả năng trực tiếp xuất nhiều kết quả ra các ô, kể cả khi chúng cố gắng làm vậy, nên chúng buộc phải quyết định xem một kết quả duy nhất nào mà chúng có thể trả về. Và trong những công thức như các ví dụ trên, kết quả đó được căn thẳng – theo đúng nghĩa đen – với hàng mà công thức nằm trên đó, từ đó giải thích vì sao một công thức nhập vào D12 lại gây ra thông báo lỗi – bởi vì hàng 12 trong bảng tính không khớp với bất kỳ hàng nào từ 1 đến 3, nơi dữ liệu được đặt. Đó chính là giao nhau ngầm – khi công thức buộc phải giao với chỉ giá trị cùng hàng với nó (hoặc cùng cột, nếu công thức được viết trên cùng cột với giá trị đó).
Nhưng một lần nữa, tất nhiên, gần như chẳng điều nào trong số này còn quan trọng nữa. Các công thức mảng động thường xuyên tung ra vùng tràn giá trị của chúng xuống dưới hoặc ngang qua, hoặc vừa xuống vừa ngang qua, với bao nhiêu ô tùy thích, và các công thức còn có thể được viết ở bất cứ đâu trong bảng tính.
• =(@A1:A3*@B1:B3)

Hình 9-3Kìm hãm lại; công thức mảng động này chỉ cho ra một kết quả

Hình 9-4Một bước thụt lùi: một lần nữa, công thức chỉ tham chiếu đến giá trị trên hàng của nó

Hình 9-5Kéo dài lê thê: giao nhau ngầm lại buộc chỉ cho ra một kết quả
Và những kết quả đó mô phỏng đúng những gì bạn sẽ thấy trong một phiên bản Excel trước 365.
Tất cả những điều đó khơi gợi một câu hỏi hiển nhiên: khi nào tôi mới cần dùng thứ này? Câu trả lời ngắn gọn: có lẽ chẳng bao giờ.
Suy cho cùng, khả năng bạn thực sự quay lại dùng một tính năng mà Excel đã quyết định phủ quyết là hơi quá xa vời so với nỗi hoài niệm ngược dòng. Một số cuộc thảo luận trên web về toán tử này mà tôi từng thấy gợi ý những cách dùng cho hàm này nghe có vẻ gượng ép và khiên cưỡng, cứ như thể tác giả của chúng cũng bối rối y như vậy trước toàn bộ ý tưởng này.
Nhưng để công bằng mà nói, cho Microsoft được hưởng lợi thế của sự nghi ngờ, hãy để tôi dệt nên một câu chuyện nửa vời có vẻ hợp lý, trong đó toán tử giao nhau ngầm có thể hữu ích.
Nơi Bạn Có Thể Dùng Toán Tử Giao Nhau – Có Lẽ Vậy
• =SUM(LEN(A1:A3))
có thể được viết bởi tất cả học sinh, bất kể phiên bản Excel nào – tất nhiên với điều kiện là người dùng trước phiên bản 365 phải gõ Ctrl-Shift-Enter để hoàn tất công thức.
Nhưng một tình huống khác lại loom ló: nếu một người dùng trước phiên bản 365 viết một công thức mảng và quên nhấn Ctrl-Shift-Enter, mà lại nhấn Enter – một lỗi dễ mắc phải nhất?
Tất nhiên điều xảy ra là giao nhau ngầm. Viết =SUM(LEN(A1:A3)) trong phiên bản trước 365, chỉ nhấn Enter, và bạn nhận được một giá trị – không phải tổng độ dài của ba từ được giới thiệu trong A1:A3, mà một lần nữa, là độ dài của từ trên hàng mà bạn đã soạn công thức.
Nhưng hãy nhớ rằng bạn, người giáo viên, lại có Excel 365 trong máy, và vì vậy bạn không thể tái tạo lại điều đang xảy ra – bởi vì Excel 365 đã loại bỏ giao nhau ngầm.
• =SUM(LEN(@A1:A3))
Nhập biểu thức đó và công thức của bạn cũng sẽ chỉ trả về một giá trị. Và kết quả là, bạn sẽ có thể xác nhận – và cho thấy – cho người dùng trước phiên bản 365 biết cô ấy sẽ thấy kết quả gì.
Vì vậy, việc dùng đến toán tử giao nhau ngầm trong Excel 365 có thể phục vụ một mục đích giảng dạy có ý nghĩa. Nhưng nếu việc giảng dạy không phải là sở thích của bạn, thì dấu @ không phải là thứ dành cho bạn.
Chúng Đã Có Mặt, Có Lẽ Vậy: Những Hàm Mảng Động Mới Nhất
Nhưng giờ chúng ta sẽ bắt đầu xem xét một cách nghiêm túc một số hàm khác mà bạn có lẽ sẽ dùng – một khi bạn xác định được rằng chúng đã có ở đó.
Đó là lô hàm mảng động mới nhất – tổng cộng 14 hàm – mà phần lớn mang đến cho người dùng Excel một số cải tiến cho cách làm việc thường ngày của họ. Thay vì đưa ra một loạt phương tiện mới để tính toán số liệu, các hàm mới này nhìn chung cung cấp một bộ công cụ mới lạ và quan trọng để tổ chức, và tái tổ chức, các tập dữ liệu của bạn theo những cách tạo điều kiện thuận lợi cho việc tính toán; và nếu mô tả đó dài dòng về mặt trừu tượng mà thiếu ví dụ, thì các ví dụ sẽ xuất hiện trong những chương tiếp theo.
Và đúng vậy, bạn nên có các hàm mới này ngay bây giờ, theo thông báo của Microsoft vào ngày 29 tháng 9 năm 2022 rằng “Những hàm này hiện đã được triển khai đầy đủ cho Excel for the Web và người dùng Office 365 trên Kênh Hiện tại”.

Hình 9-6CHÚNG đến từ đâu vậy?: CHOOSECOLS và CHOOSEROWS, hai trong số các hàm mảng động mới
• TEXT SPLIT
• TEXT BEFORE
• TEXTAFTER
• TOCOL
• TOROW
• WRAPSOL
• WRAPROWS
• VSTACK
• HSTACK
• CHOOSECOLS
• CHOOSEROWS
• TAKE
• DROP
• EXPAND
thực ra có thể được hiểu như một tập hợp nhóm nhỏ hơn, bởi vì một số hàm giải quyết việc tổ chức các hàng trong một tập dữ liệu, trong khi những hàm khác thực hiện công việc tương tự trên các cột, và đại loại như vậy. Và điều đó có nghĩa là việc làm quen với bộ hàm mới này sẽ không mất nhiều thời gian như bạn có thể tưởng tượng lúc đầu – hoặc lo sợ.
Chương 10 sẽ khởi động phần điểm lại các hàm mới của chúng ta bằng việc khảo sát ba hàm được thiết kế để giải quyết – và xử lý triệt để – một loạt vấn đề bảng tính kinh điển thường cản trở việc xử lý văn bản – TEXT SPLIT, TEXT BEFORE và TEXT AFTER.
10. TEXTSPLIT, TEXTBEFORE và TEXTAFTER: Đặt từ ngữ vào đúng chỗ của chúng
Sắp có mặt trên ổ cứng của bạn
Ba hàm văn bản mảng động mới này cùng nhắm vào một nhóm vấn đề bảng tính lâu đời và có liên quan với nhau – cụ thể là làm sao tách, hay phân tích, một ô chứa chuỗi văn bản thành các từ cấu thành của nó.

Hình 10-1Cách làm của Microsoft – gán từng từ vào một ô thông qua Text to Columns
Text to Columns hoạt động chủ yếu bằng cách cho phép người dùng định nghĩa một dấu phân cách (delimiter), hoặc nhiều dấu phân cách, để phân tách văn bản thành kiểu mỗi cột một từ. Trong ảnh trên, người dùng sẽ tick vào ô “space” – ký tự sẽ phân tách văn bản thành các từ tương ứng mỗi khi nó gặp một dấu cách trong đoạn văn bản nhập vào.

Hình 10-2Sự chia tách lớn: một hàng tiêu đề ở định dạng CSV trước khi các tên trường của nó được tách ra
Hãy nhớ rằng tất cả những tiêu đề đang hình thành đó (nhiều hơn hẳn những gì bạn thực sự thấy ở trên) đều bị dồn vào một ô duy nhất, và Text to Columns sẽ chộp lấy những dấu phẩy phân cách rồi tách ra một tên trường riêng biệt cho từng thuật ngữ được bao quanh bởi những dấu phẩy đó, sau đó tiếp tục làm điều tương tự cho tất cả các hàng đầy dấu phẩy bên dưới phần tiêu đề, biến tất cả chúng thành dữ liệu trường.
Text to Columns đã phục vụ một cách đáng kính trong nhiều năm, nhưng vì nó hoạt động dựa trên việc nhấp chuột, nên tính linh hoạt của nó bị hạn chế. Ví dụ, nếu tôi muốn tách và sắp xếp dữ liệu – chẳng hạn điểm kiểm tra được phân tách bằng dấu phẩy – thì Text to Columns chỉ thực hiện việc tách, chứ không sắp xếp. Hoặc nếu tôi cần gỡ rối các giá trị được phân tách bằng dấu phẩy rồi sau đó xếp chúng theo chiều dọc, thì một lần nữa, bạn sẽ phải tìm cách khác – theo hướng các công thức.
Và đúng là như vậy – từ lâu đã có nhiều cách dùng công thức để phân tích, hay trích xuất, các từ hoặc đoạn văn bản, và chúng ta đã xem qua một số cách, ví dụ MID, LEFT và SEARCH. Nhưng như bài viết này (https://www.linkedin.com/posts/andrewcharlesmoss_extracting-and-splitting-text-activity-6928128981799997440-NGpl/?utm_source=linkedin_share&utm_medium=member_desktop_web) nhận xét, những chiến lược đó có thể trở nên khá rối rắm, và có thể làm khó người dùng khi họ đụng phải rào cản văn bản điển hình – tách tên đầu, tên đệm và tên cuối vốn chen chúc trong cùng một ô.
Nhưng cứu viện đã đến – dưới dạng ba công thức mới, tinh gọn hơn, giúp làm phẳng đáng kể những gồ ghề rải rác trên con đường dẫn tới việc tách văn bản thành công – TEXTSPLIT, TEXTBEFORE và TEXTAFTER.
TEXTSPLIT: Ghép nối mọi thứ lại
• =TEXTSPLIT(text,column delimiter,row delimiter,ignore empty,match mode,pad width)
Như chúng ta sẽ thấy, hai đối số đầu tiên – đối số yêu cầu bạn xác định văn bản muốn tách và đối số nêu tên (các) dấu phân cách – là thiết yếu, còn bốn đối số còn lại chỉ mang tính tùy chọn.
• =TEXTSPLIT(B3," ")

Hình 10-3Tách theo dấu cách: mỗi từ được gán vào một ô riêng
Ở đây TEXTSPLIT tìm kiếm cụm từ của chúng ta theo từng dấu cách, ký tự mà ta đã chọn làm dấu phân cách cột. Mỗi đoạn văn bản đứng trước một dấu cách sẽ được cấp cho một ô riêng, và kết quả là mọi từ đều được tách ra đúng cách, hay nói cách khác là được chia nhỏ.
• =TEXTSPLIT(B3,," ")

Hình 10-4Văn bản của London đang rơi xuống: TEXTSPLIT tạo ra một cách tách từ theo chiều dọc
Chúng ta đã từng thấy điều gì đó tương tự trước đây, chẳng hạn trong phần khảo sát về hàm SEQUENCE. Dấu phẩy thừa trong công thức bỏ qua đối số dấu phân cách cột và thay vào đó kích hoạt một dấu phân cách hàng – cũng là dấu cách, nhưng lúc này đóng vai trò như một kiểu ngắt dòng thực tế, khiến các mục đã tách rớt xuống theo một cột.
• Ted 76,Jan 82,Mildred 91,Frank 64
• =TEXTSPLIT(I5," ",",")

Hình 10-5Đủ mọi hướng; văn bản được tách cả theo chiều ngang lẫn chiều dọc
Dấu phân cách khoảng trắng làm mỗi tên/điểm của học sinh tràn xuống dưới, đồng thời dấu phẩy ghép gọn từng tên với điểm tương ứng theo chiều ngang. Chỉ cần nhớ căn chỉnh cho đúng tất cả những dấu ngoặc kép đó.
Lưu ý
Tuy nhiên, các điểm kiểm tra do TEXTSPLIT trả về ở trên vẫn mang trạng thái là văn bản (hãy để ý chúng được căn lề trái). Dù vậy, vẫn có những cách để xử lý chúng như các giá trị số, chẳng hạn thông qua hàm VALUE.
• =SORT(TEXTSPLIT(I5," ",","),2,-1)
[image: ]
Hình 10-6Sắp xếp điểm số trong một ô duy nhất
(Lưu ý một lần nữa rằng Excel vẫn cho phép việc sắp xếp diễn ra, dù các điểm số về mặt chính thức được định dạng là văn bản.)
Sẽ còn nhiều điều để nói về việc TEXTSPLIT kết hợp dấu phân cách cột và hàng sau đây một chút.
Chọn dấu phân cách của bạn
Nhưng ai bảo rằng ký tự dấu cách là dấu phân cách duy nhất của TEXTSPLIT? Thực ra thì không ai cả. Thực tế là bạn có thể gán trạng thái dấu phân cách cho bất kỳ ký tự nào – hoặc những ký tự nào.
Ví dụ, hãy quan sát cụm từ này:
Chúng tôi muốn ra ngoài, nhưng trời đang mưa. Phương án B là gì?

Hình 10-7Ngữ pháp bảng tính – dấu câu không mong muốn
Nhưng chúng ta muốn cho phép tất cả các ký tự trên – dấu chấm, dấu phẩy, dấu hỏi và dấu cách – để phân tách từ, thay vì để chúng lảng vảng vô ích giữa các từ, như chúng làm trong ảnh chụp màn hình. Làm sao để làm điều đó?
• =TEXTSPLIT(E8,{" ",",",".","?"},,1)
Hiểu chưa? Vẫn còn nheo mắt, hay đã bỏ cuộc rồi? Nếu vậy, hãy ngồi lại và xem xét lời giải thích này: đầu tiên, tất cả các dấu phân cách được chỉ định đều được bao quanh bởi một cặp dấu ngoặc công thức mảng quen thuộc do người dùng nhập. Và bên trong, mỗi dấu phân cách lần lượt được bao bọc bởi dấu ngoặc kép và tách khỏi dấu phân cách tiếp theo bằng một dấu phẩy – đồng thời nhớ rằng một trong các dấu phân cách chính nó là một dấu phẩy, và do đó được kẹp giữa hai dấu ngoặc kép.
Tất cả cú pháp đó có khó đọc và thân thiện với người dùng không? Có và không. Tất nhiên, nó hoạt động, một khi bạn phối hợp tất cả các dấu ngoặc kép và dấu phẩy đó; nhưng có một cách tương đương rõ ràng hơn mà bạn muốn biết.
[image: ]
Hình 10-8Dấu phân cách, không cần ngoặc kép. Dấu phân cách dấu cách vô hình chiếm ô đầu tiên của bảng.
• =TEXTSPLIT(E8,Table1,,1)
Tham chiếu Table1 đóng vai trò thay thế cho các dấu phân cách được bao trong ngoặc và dày đặc ngoặc kép, và hoạt động chính xác theo cùng một cách. Hơn nữa, nếu hóa ra bạn cần thêm dấu phân cách hoặc nhớ ra những dấu bạn đã bỏ sót, chỉ cần nhập chúng xuống cột của bảng, và chúng cũng sẽ tự động phân tách bất kỳ từ nào. Đây là một sự thay thế khá thú vị, gọn gàng hơn nhiều so với đối số dấu phân cách chính thức, theo đúng sách vở, được bao trong ngoặc.
Không phải lúc nào bạn cũng bỏ qua "Bỏ qua ô trống"
Nhưng nếu bạn đi theo con đường bảng được vạch ra ở trên, bạn sẽ cần đảm bảo rằng đối số thứ tư, tùy chọn "bỏ qua ô trống" của TEXTSPLIT có một vị trí trong công thức, như chúng ta thấy nó được biểu diễn ở trên bằng số 1. "Bỏ qua ô trống" hướng dẫn hàm bỏ qua một dấu phân cách không đi kèm với bất kỳ văn bản nào cần phân tách – và nếu bạn bỏ qua nó, công thức mà chúng ta đã trình bày chi tiết sẽ gây ra những khoảng trống không cần thiết cho kết quả. Ví dụ, nếu không có "bỏ qua ô trống", dấu cách theo sau từ "out" sẽ chiếm một ô riêng – bởi vì dấu phẩy bên cạnh "out" sẽ đã phân tách từ đó, và dấu cách sau đó sẽ được coi là một dấu phân cách trống.

Hình 10-9.Khoảng trống bên ngoài – Ted bị tách khỏi điểm kiểm tra của mình bởi hai dấu cách
Chúng ta thấy rằng theo mặc định, các dấu phân cách thừa không bị bỏ qua, và do đó kết quả ở trên dành chỗ cho cả hai dấu cách của Ted – dấu thứ nhất không phân tách gì cả, dấu thứ hai phân tách số 76. Và bởi vì dấu cách thừa đó – suy cho cùng, là một dấu phân cách cột – đẩy điểm của Ted vào một cột thứ ba mới, thêm; cột đó giờ đây cũng bị áp đặt lên các tên khác, buộc chúng phát ra thông báo lỗi #N/A. Rốt cuộc, bạn không thể dành riêng một cột mới chỉ cho một hàng; đó là một đề xuất được ăn cả ngã về không. Hàng của Ted không thể nhận ba cột trong khi các tên khác giữ nguyên hai cột ban đầu.
• =TEXTSPLIT(I5," ",",",1)
trong đó số "1" đưa ra lệnh "bỏ qua ô trống", kết quả trở về kết quả hai cột, không có lỗi.
Ghi chú
Bọc hàm TRIM quanh các công thức sẽ loại bỏ những khoảng trắng dư thừa trong một chuỗi văn bản.

Hình 10-10ID của bạn đâu rồi, Bill?

Hình 10-11Các trường này được căn thẳng hàng

Hình 10-12Còn các trường này thì không
Ta thấy rằng nếu bạn thực sự bỏ qua dấu phân cách rỗng thông qua đối số 1, TEXTSPLIT sẽ ném phần dữ liệu kế tiếp có sẵn của Bill – 67, một điểm kiểm tra – vào cột kế tiếp có sẵn, id; và như bạn thấy, quyết định đó khiến dữ liệu lệch khỏi các cột thích hợp của chúng. Vậy nên, ta thấy rằng dấu phẩy đầu tiên trong hai dấu phẩy liên tiếp của Bill cung cấp một chỗ giữ chỗ cho một trường – id – mà thông tin của nó đang bị thiếu. (Chúng ta cũng sẽ có thêm vài điều để nói về ví dụ này.)
• TodayXisXThursday
• =TEXTSPLIT(G12,"x")

Hình 10-13Trường hợp kỳ lạ: không có gì thay đổi
• =TEXTSPLIT(G12,"x",,,1)

Hình 10-14x đánh dấu điểm tách: văn bản được tách bởi TEXTSPLIT
Ra mắt "Pad With": Một kiểu đối số mới

Hình 10-15Miếng cọ rửa: tùy chọn "pad with" dọn dẹp các thông báo lỗi.
Người ta có thể hỏi tại sao Excel lại thấy cần phải đặt ra thuật ngữ "pad width" (độ rộng đệm), một thuật ngữ không hề xuất hiện trong bất kỳ hàm mảng động nào trước đó. Suy cho cùng, những hàm khác, ví dụ như XLOOKUP và FILTER, cũng cung cấp các đối số "if not found" (nếu không tìm thấy) hoặc "if empty" (nếu rỗng) mà cũng cho phép người dùng đăng một chú thích thay thế cho những công thức mà nếu không sẽ phải chịu các thông báo lỗi. Nhưng đó chẳng phải cũng là điều mà "pad with" làm hay sao? Và nếu đúng như vậy, tại sao nhóm phụ trách khả năng sử dụng của Microsoft lại cần phải đặt ra một thuật ngữ mới cho tính năng này, vốn dường như làm gần giống những gì các phiên bản tiền nhiệm của nó đã làm?
Câu trả lời là Excel có thể đã quay về dùng một thuật ngữ sẵn có như "if not found" ở đây, nhưng "pad with" lại đưa ra một tuyên bố về kiểu công việc khác biệt mà một số hàm mảng động mới thực hiện. Chẳng hạn, khi người dùng thực hiện một truy vấn với FILTER, số lượng kết quả mà công thức tạo ra sẽ thay đổi, tùy thuộc vào tiêu chí lọc mà người dùng áp dụng; nhưng những hàm như TEXTSPLIT và, như chúng ta sẽ thấy, WRAPCOLS và EXPAND, lại yêu cầu người dùng định hình một vùng tràn có kích thước cố định ngay từ đầu, ví dụ ba hàng nhân bốn cột; và vì một số ô trong đó có thể, vì bất kỳ lý do gì, bị để trống, nên người dùng được trao tùy chọn điền đầy – hay đệm – những ô trống đó bằng một chú thích.
TEXTSPLIT và bộ dữ liệu một ô

Hình 10-16Trông quen không? Bài kiểm tra TEXTSPLIT phân tách
Nhưng giờ hãy lật ngược vấn đề. Chúng ta đã thấy TEXTSPLIT có thể giải nén một tập hợp dữ liệu tập trung trong một ô, rồi phân phối, hay tách, chúng ra thành nhiều ô có thể sử dụng được. Với kỹ năng đó trong tay, tại sao chúng ta không thể lấy dữ liệu hiện có, đóng gói lại vào một ô duy nhất thông qua hàm TEXTJOIN, rồi sau đó gọi chúng trở lại thành các mục nhập dựa trên ô thông thường khi chúng ta muốn? Nói cách khác, tại sao không nén và lưu trữ các bản ghi vào một ô – thậm chí vài nghìn bản ghi – rồi xả ô đó ra thành các bản ghi riêng biệt trở lại bất cứ khi nào chúng ta cần chúng bằng TEXTSPLIT?
• =TEXTJOIN("*",,Student&","&Score)
TEXTJOIN là một hàm tiện dụng và mạnh mẽ đến bất ngờ, có thể kết hợp, hay nối, văn bản của nhiều ô thông qua một dấu phân cách. Ở đây, TEXTJOIN gộp mọi tên học sinh và điểm kiểm tra theo từng cặp song hành, được ngăn cách bởi dấu phẩy chèn giữa mỗi cặp tên-điểm. Nghĩa là, mỗi tên được nối với điểm của nó, ví dụ, Smith, 78. Nhưng chính dấu hoa thị mới đóng vai trò dấu phân cách, vì những lý do sẽ trở nên rõ ràng hơn nhiều trong giây lát. (Hai dấu phẩy liên tiếp trong công thức chỉ đến tùy chọn "bỏ qua ô trống" của TEXTJOIN, không liên quan ở đây; dữ liệu của chúng ta không có ô trống nào.)

Hình 10-17Lớp lớn: 100 học sinh và điểm của họ, tất cả được nối trong D4
(Giờ bạn có thể chạy Copy > Paste Values lên trên D4.)
Hãy để ý dữ liệu hiện trông như thế nào. Mỗi tên học sinh được theo sau bởi điểm kiểm tra ở bên kia dấu phẩy. Nhưng mỗi tên/điểm lại được ngăn cách với tên/điểm tiếp theo bởi dấu hoa thị đó – dấu phân cách mà chúng ta đã chọn cho TEXTJOIN. Và giờ thì sao?
• =TEXTSPLIT(D4,",","*")

Hình 10-18Tập dữ liệu, được trả về đầy đủ: tên và điểm kiểm tra được mở khóa từ D4 và gán lại vào các ô riêng biệt
Một lần nữa, TEXTSPLIT tách dữ liệu theo hai hướng: nó nắm lấy dấu phân cách cột là dấu phẩy – lấy từ dấu phẩy nối của TEXTJOIN – để tách tên học sinh khỏi điểm của họ, và cũng áp dụng dấu phân cách chính thức của chính TEXTJOIN, dấu hoa thị, để đưa mỗi bản ghi xuống hàng tiếp theo bằng cách viện dẫn dấu hoa thị trong đối số "dấu phân cách hàng" của nó.
Điểm mấu chốt lớn hơn: TEXTSPLIT có thể khéo léo chia các giá trị phân tách bằng dấu phẩy thành dữ liệu hữu dụng, nhưng bạn có thể hướng quá trình đó theo chiều ngược lại – định nghĩa hồi tố dữ liệu chuẩn, đã được phân tách thành một nhóm các giá trị phân tách bằng dấu phẩy được lưu vào một ô, và sau đó tái tạo tập dữ liệu theo nhu cầu thông qua TEXTSPLIT. Nghĩa là, hãy để TEXTJOIN gom hàng trăm hoặc thậm chí hàng nghìn bản ghi vào một ô (hãy nhớ một ô Excel có thể chứa 32,767 ký tự) và truy xuất chúng bằng TEXTSPLIT khi bạn muốn.
TEXTSPLIT Không Thể Làm Mọi Thứ – nhưng Có Lý Do Chính Đáng

Hình 10-19Ba ô cần được tách
• =TEXTSPLIT(C7:C9, “ “)

Hình 10-20Bạn không thể đến đó từ đây: TEXTSPLIT không thể tách toàn bộ văn bản từ ba ô được tham chiếu bởi một công thức.

Hình 10-21Tách văn bản, mỗi lần một dòng và một công thức

Hình 10-22Không có học trò cưng: mọi học sinh đều nhận được một công thức TEXTSPLIT
Tách văn bản bằng ba công thức TEXTSPLIT, mỗi hàng một công thức.

Hình 10-23Thông điệp từ đối thủ: hàm SPLIT của Google Sheets có thể tách văn bản ra nhiều ô chỉ với một công thức
Vậy thì tại sao TEXTSPLIT lại không thể làm điều tương tự?
• =TEXTSPLIT(C7:C9, " ")
Giờ chúng ta thấy rằng nếu văn bản trong C7 bị áp một dấu phân cách hàng và do đó tràn các từ của nó xuống cột C, thì kết quả của nó sẽ đụng phải và bị chặn bởi văn bản trong C8, hàng kế tiếp bên dưới, và TEXTSPLIT không thể giải quyết được tình trạng tắc nghẽn đó. Mặt khác, hàm SPLIT của Google Sheets sẽ không bận tâm đến sự phức tạp đó – bởi vì nó vốn không có dấu phân cách hàng nào cả.
Vẫn có Phương án B
• =TEXTSPLIT(TEXTJOIN("*",,C7:C9)," ","*",,,"")

Hình 10-24Chia tay đâu có khó đến thế: ba chuỗi văn bản được TEXTJOIN nối lại với nhau trong một ô, rồi được TEXTSPLIT tách thành các từ
Mấu chốt của công thức nằm ở khả năng của TEXTJOIN trong việc khâu ba chuỗi lại thành một ô duy nhất, từ đó tạo ra hiệu quả một chuỗi văn bản lớn. Và đó chính xác là loại đối tượng mà TEXTSPLIT được thiết kế để xử lý – một chuỗi văn bản trong một ô. Vì vậy, nếu ta tách riêng phần TEXTJOIN của công thức, ta sẽ thấy
Today is Thursday*My favorite flavor is Rocky Road*Annapolis is the capital of Maryland
Và cũng như ví dụ về tập dữ liệu một ô trước đó, TEXTJOIN ghi nhận dấu hoa thị là dấu phân cách của nó, rồi TEXTSPLIT lại mượn dấu này làm dấu phân cách hàng cho chính nó, từ đó tách chuỗi trở về ba hàng văn bản ban đầu. Dấu phân cách cột của TEXTSPLIT – ở đây là dấu cách – sau đó chia mỗi chuỗi thành các từ riêng lẻ.
Cặp dấu ngoặc kép cuối cùng của công thức, cặp bị đẩy về tận cùng bên phải của công thức, thể hiện đối số "pad with" (đệm bằng). Chúng cần thiết ở đây vì chuỗi văn bản đầu tiên – Today is Thursday – chỉ gồm ba từ trải dài qua ba cột, trong khi hai chuỗi còn lại với sáu từ của chúng đương nhiên trải dài qua sáu cột. Và như đã giải thích ở phần trước của chương, vì "Today is Thursday" cũng phải được cấp sáu cột – bởi vì mọi hàng trong vùng tràn đều phải thể hiện cùng số cột – nên ba ô trống của nó mặc định hiển thị thông báo #N/A, có thể được ghi đè bằng một chú thích "pad with".
TEXTBEFORE và TEXTAFTER: Giới hạn Dấu phân cách một cách Hữu ích
Là anh em họ với TEXTSPLIT rộng hơn, tổng quát hơn, hai hàm mảng động mới TEXTBEFORE và TEXTAFTER mang đến một cách tiếp cận hẹp hơn đôi chút cho công việc tách văn bản cụ thể ra khỏi các ô, nhưng có lẽ với một nhiệm vụ nổi tiếng – hay tai tiếng – được nghĩ đến cụ thể, một nhiệm vụ mà chúng ta đã nhắc đến rồi.
Nhiệm vụ đó: Lấy họ tên đầy đủ chen chúc trong một ô và tách chúng thành tên, tên đệm, và họ – và TEXTBEFORE cùng TEXTAFTER sẵn sàng giúp đỡ hết mình. TEXTBEFORE trả về văn bản xuất hiện trước một vị trí dấu phân cách được chỉ định, trong khi TEXTAFTER đi theo hướng ngược lại – nó mang đi văn bản theo sau một vị trí dấu phân cách được chỉ định.
Cách chúng được viết – và cách chúng hoạt động
• =TEXTBEFORE(text,delimiter(s),instance number,match mode,match end,if not found)
• {" ","*"}
Và một lần nữa, bạn có thể tham chiếu các dấu phân cách (delimiter) tới một bảng thay vì nhập trực tiếp, rồi cung cấp tên bảng đó làm tên dấu phân cách toàn cục (global delimiter name) trong công thức.
Đối số thứ ba, instance number (số thứ tự lần xuất hiện), là trọng tâm của toàn bộ quá trình. Con số này chỉ vị trí theo thứ tự của một dấu phân cách cụ thể trong số tất cả các dấu phân cách có trong ô. Ví dụ đơn giản: dấu cách đứng trước Sartre trong tên John Paul Sartre là dấu cách thứ hai trong ô tính từ trái sang phải, và do đó sẽ được chỉ định là 2 trong TEXTBEFORE.
Tuy nhiên, bạn cũng có thể ghi số thứ tự lần xuất hiện bằng giá trị âm, một tùy chọn khởi động việc đếm dấu phân cách từ phải sang trái, đòi hỏi bạn phải suy nghĩ kỹ một chút. Với cách làm này, dấu cách thứ hai trước Sartre sẽ được mã hóa là -1 – nghĩa là trong trường hợp này, dấu cách đó là dấu phân cách đầu tiên trong ô theo hướng từ phải sang trái. Vậy -2 trong cùng công thức sẽ biểu thị dấu phân cách thứ hai theo hướng phải sang trái – và ở đây, đó là dấu cách ngăn cách giữa Jean và Paul. Nghe có vẻ hơi khó hiểu, nhưng như chúng ta sẽ thấy, cách đánh số ngược này có thể giúp ích cho bạn rất nhiều.
Và nếu bạn bỏ qua hoàn toàn instance number, TEXTBEFORE sẽ mặc định làm việc với lần xuất hiện đầu tiên của dấu phân cách.
• TodayXisXThursday
• =TEXTBEFORE(L14,"x")
(Các đối số bị bỏ qua còn lại là tùy chọn.)
• =TEXTBEFORE(L14,"x",,1)
Giờ thì, ngoài việc nghe như phần kết luận của một sự kiện thể thao, đối số thứ năm, "match end," phức tạp hơn một chút nhưng có thể được tận dụng hiệu quả một khi bạn hiểu chính xác nó làm gì – điều mà tôi cũng mất một lúc mới nắm được. Mặc định không hoạt động và được biểu thị bằng giá trị 1 khi được dùng, Microsoft nói rằng "match end" "coi phần cuối của văn bản như một dấu phân cách," một mô tả mà đối với tôi, ít nhất, chẳng giúp tôi hiểu thêm được bao nhiêu.
• Today is Thursday[space]
Và giờ khi Excel đã trang bị dấu phân cách cho chuỗi, TEXTBEFORE và TEXTAFTER có thể tìm thấy nó và hành động dựa trên nó.
• =TEXTBEFORE(A3," ")
• =TEXTBEFORE(A4," ",,,1)
sẽ đặt dấu phân cách ảo của nó sau chữ “a” thứ hai trong Madonna. Thực tế, lúc này, công thức sẽ đọc Madonna thành Madonna[dấu cách], và trả về toàn bộ văn bản đứng trước dấu cách nổi loạn đó – tức là, Madonna.

Hình 10-25Báo cáo điểm danh: X bị đánh dấu vắng mặt
TEXTAFTER: Mặt trái của TEXTBEFORE
TEXTAFTER, thực chất là hình ảnh phản chiếu của TEXTBEFORE, có cú pháp tương tự – với điểm khác biệt thiết yếu là đối số dấu phân cách ở đây tìm kiếm văn bản theo sau sự xuất hiện của dấu phân cách. Vì vậy, với tên John Doe được phân tách bằng dấu cách, TEXTBEFORE sẽ trích xuất John – tên đứng trước dấu cách, trong khi TEXTAFTER sẽ lấy ra Doe, phần văn bản nằm sau dấu cách.
[image: ]
Hình 10-26Danh sách hạng A
Nhiệm vụ của chúng ta ở đây, một nhiệm vụ phổ biến: tách tên ra khỏi họ, đồng thời quyết định xem nên đặt những tên đệm khó nhằn ở đâu – thứ vốn nổi tiếng là hay làm khổ các danh sách và thiệp mời.
Thực ra, các chiến lược dựa trên công thức để tách tên ra khỏi những mục có nhiều tên đã lưu hành từ lâu, gắn liền với các hàm LEFT và FIND. Nhưng TEXTBEFORE và TEXTAFTER có vài chiêu rõ ràng và thanh thoát hơn, như chúng ta sẽ thấy.
• =TEXT BEFORE(A1:A10," ")
Nhưng khoan. Chẳng phải mới vài trang trước chúng ta vừa biết rằng công thức TEXTSPLIT không thể tách văn bản từ dữ liệu của nhiều ô sao? Đúng vậy. Nhưng TEXTBEFORE và TEXTAFTER không bị giới hạn đó. Việc không có dấu phân cách hàng trong TEXTBEFORE và TEXTAFTER nghĩa là chúng sẽ không bao giờ tràn xuống dưới và lấn vào văn bản trong ô bên dưới – khác với TEXTSPLIT.

Hình 10-27Người nổi tiếng, gọi nhau bằng tên
• =TEXTAFTER(A1:A10," ")

Hình 10-28Big Sur: họ qua TEXTAFTER
Ở đây theo mặc định TEXTAFTER nhắm vào dấu cách đầu tiên trong mỗi tên, và điền vào mỗi ô toàn bộ văn bản nằm bên phải dấu cách.

Hình 10-29Cân nhắc lại về tên đệm? Tách tên bằng TEXTSPLIT
Có lẽ không phải điều bạn nghĩ trong đầu – bởi vì dù TEXTSPLIT tách được từng cái tên một, hai tên đệm lại chia sẻ cột B với phần lớn các họ.
Trước và Giữa: Trích xuất tên đệm

Hình 10-30Bị kẹt ở giữa: tên đệm cũng bị bắt luôn
Tham vọng đó có phần lớn lao hơn một chút, bởi vì các hàm TEXT BEFORE/AFTER sẽ cuốn phăng toàn bộ văn bản ở hai bên của dấu phân cách. Nhưng ở đây chúng ta muốn nhặt ra đoạn văn bản bị kẹt giữa hai dấu phân cách, bị bao quanh bởi văn bản không mong muốn ở cả hai phía.
• =TEXTAFTER(TEXT BEFORE(A1:A10," ",-1)," ",,,1)

Hình 10-31Đúng thứ cần tìm: văn bản được trả về từ bên trái của dấu cách ngoài cùng bên phải trong mỗi tên
Tất nhiên đây là những kết quả trung gian, tạo thành một tập dữ liệu ảo tạm thời cung cấp các tên – mỗi tên giờ đây chỉ còn, hoặc sẽ chỉ còn, một dấu cách – mà nửa TEXT AFTER của công thức sắp tác động lên đó.
Và khi chúng ta bọc TEXT AFTER quanh TEXTBEFORE, công thức giờ đây sẽ xem xét những cái tên trong hình trên và đơn giản là giật lấy đoạn văn bản theo sau dấu cách duy nhất còn lại trong mỗi tên. Trong trường hợp của John Paul, thì tên Paul được trả về; còn với những ô chỉ chứa một tên, một lần nữa dấu phân cách "match end" lại gắn dấu cách giả của nó vào cuối tên – và TEXTAFTER không tìm thấy gì phía sau nó, để lại ô trống.
Sắp xếp theo Họ: Hơi Khó Nhằn
• =SORTBY(A1:A10,TEXTAFTER(A1:A10," ",-1))

Hình 10-32Thứ tự chữ cái nội bộ: sắp xếp theo họ

Hình 10-33Hậu trường: phần này của công thức chỉ sắp xếp họ mà thôi
Sau đó nó thực chất tiến hành sắp xếp hai cột – tức là dữ liệu thật trong cột A và cột ảo chứa các họ được trả về bên trong công thức – theo cột sau, và điều này kéo theo cả những cái tên ở cột đầu tiên, tức những cái tên mà chúng ta thực sự nhìn thấy trong bảng tính.
Đôi Lời Kết Luận
Xử lý số có thể là nghề chính của Excel, nhưng như chúng ta đã thấy, nó cũng làm được rất nhiều việc với chữ nghĩa; và các hàm văn bản mới cố gắng giúp công việc đó trở nên đơn giản và hiệu quả hơn.
Cặp hàm mảng động mới tiếp theo, TOCOL và TOROW, sẽ làm phẳng các vùng nhiều cột hoặc nhiều hàng thành một cột hoặc một hàng duy nhất. Và bạn sẽ thấy vì sao bạn muốn thêm những thuật ngữ mới này vào vốn từ bảng tính của mình.
11. TOCOL và TOROW: Sắp Xếp Lại Dữ Liệu Cho Ngay Ngắn
Để nhắc lại một điểm đã nêu ở phần giới thiệu cách đây ít lâu: các hàm mảng động thế hệ thứ hai mới của Excel không mở ra nhiều cánh cửa mới cho việc xử lý số; thay vào đó, chúng chủ yếu nhằm cải tổ và tinh gọn cách dữ liệu được tổ chức. Và đó là một điểm chắc chắn cần được giải thích đôi chút, bắt đầu bằng việc mô tả các hàm TOROW và TOCOL.
Cách chúng được viết – và chúng nói về điều gì
TOCOL và TOROW được tạo ra để cho phép người dùng có cách đơn giản hơn để phân tích dữ liệu hiện đang được sắp xếp theo dạng hình chữ nhật. Vậy điều đó có nghĩa là gì?

Hình 11-1Ma trận: phần tiếp theo
Chúng ta muốn đếm tần suất xuất hiện của từng giá trị trong vùng, nhưng sự phân tán của các giá trị đó qua năm cột khiến bài tập này trở thành một thứ khiến ta phải dừng lại suy nghĩ – bởi vì trước khi có thể đếm từng giá trị bằng hàm COUNTIF tiêu chuẩn, ta cần liệt kê từng giá trị duy nhất làm tiêu chí, để COUNTIF biết nó đang đếm cái gì; và việc tập hợp một danh sách các giá trị duy nhất qua nhiều cột không phải là chuyện đơn giản.
Và đây là lúc TOCOL xuất hiện, nó sẵn sàng lao vào dữ liệu nhiều cột và chắt lọc tất cả thành một cột duy nhất, sau đó mọi loại tác vụ phân tích dữ liệu trở nên dễ dàng hơn nhiều. Suy cho cùng, một khi bạn đã bằng cách nào đó ép tất cả các giá trị trên vào một cột – dù chỉ tạm thời – thì hàm UNIQUE có thể không chút sợ hãi mà tung hoành.
• =TOCOL(range/array,ignore,scan by column)
Đối số đầu tiên, range, hay cái mà Excel lại gọi là "array," chỉ đơn giản yêu cầu tọa độ của dữ liệu mà TOCOL sẽ làm việc – tức là dữ liệu nào sẽ được định hình lại thành một cột duy nhất.

Hình 11-2Các tùy chọn bỏ qua của TOCOL; đừng bỏ qua chúng
Tùy chọn đầu tiên được thể hiện bằng số 0, Keep all values (Giữ tất cả giá trị), đóng vai trò là tùy chọn mặc định và có thể được bỏ qua; nó chỉ đơn giản giữ nguyên tất cả các giá trị hiện có trong range/array và sẽ trả về tất cả chúng vào cột duy nhất mà TOCOL sẽ tạo ra. Ignore blanks (Bỏ qua ô trống) làm đúng như tên gọi, tức là nó bỏ qua mọi ô trống trong range/array nguồn và loại chúng khỏi kết quả TOCOL, còn ignore errors (Bỏ qua lỗi) làm điều tương tự với các ô chứa thông báo lỗi. Tùy chọn thứ tư, ignore blanks and errors (Bỏ qua ô trống và lỗi), kết hợp các thao tác của tùy chọn 2 và 3.
• =TOCOL(G6:J27)

Hình 11-3Bốn thành một – ma trận được thu hẹp thành một cột duy nhất
• =TOCOL(G6:J17,,1)

Hình 11-4Đi theo hướng khác: kết quả lặn xuống theo các cột để lấy kết quả
Ở đây, bốn kết quả TOCOL đầu tiên nắm bắt các giá trị 1, 2, 3 và 9 từ cột đầu tiên của ma trận, bởi vì các giá trị được tìm kiếm theo hướng xuống dưới.

Hình 11-5Mỗi giá trị ma trận – xuất hiện một lần, theo thứ tự số
• =COUNTIF(G6:J17,L6#)

Hình 11-6Giá trị ma trận, đã được tính đến
Nhiệm vụ hoàn thành. Chúng ta đã đưa hàm TOCOL vào xử lý dữ liệu nhiều cột, nhờ đó có thể dễ dàng thu thập các trường hợp duy nhất của từng giá trị.
Giờ thì sao nếu chúng ta muốn sắp xếp các giá trị ma trận – ngay trong ma trận nhiều cột? Đó cũng là việc chúng ta có thể làm, nhưng nhiệm vụ đó để dành cho chương sau, khi chúng ta ra mắt các hàm WRAPCOLS và WRAPROWS và kết hợp chúng với TOCOL
Nhắm thẳng vào các ô trống

Hình 11-7Phân loại dữ liệu điểm danh hằng ngày
• =SORT(UNIQUE(TOCOL(A2:E11)))

Hình 11-8Mười học sinh, mười một kết quả

Hình 11-9Tất cả đều có mặt và được tính đến – trừ các ô trống
loại bỏ mọi ô trống khỏi vùng tràn, một kết quả vui vẻ nhờ số 1 mà chúng ta đã thêm vào công thức (đối số "bỏ qua ô trống"), và trông đẹp hơn hẳn.

Hình 11-10Sao vàng cho Conor, Danny và Nancy

Hình 11-11Zelda là người mới, đã được báo cáo và sắp xếp
TOROW thì hơi khác một chút
Và như bạn có thể đã suy ra, TOROW sắp xếp lại dữ liệu nhiều cột thành đầu ra vừa đủ một hàng, dựa trên các đối số giống như TOCOL nhưng đôi khi vẫn cần người dùng quyết định thêm vài điều.

Hình 11-12Sắp xếp học sinh theo chiều ngang
Điều khác biệt ở đây là hàm UNIQUE phải được yêu cầu tràn các tên duy nhất theo cột, thể hiện qua số 1 trong đối số cuối cùng của nó (số đứng trước ba dấu phẩy); và SORT cũng phải được yêu cầu sắp xếp dữ liệu theo chiều ngang – quy định bởi số 1 cuối cùng trong toàn bộ công thức.
Lưu ý
Theo mặc định, cả TOCOL lẫn TOROW đều quét các vùng dữ liệu mà chúng xử lý theo cột; nghĩa là chúng quét dữ liệu theo chiều ngang, rồi sắp xếp lại thành một cột hoặc một hàng duy nhất, mỗi lần một cột.
Ghép Nối Các Kết Luận

Hình 11-13Đừng thử cái này ở nhà: nhồi hai trường vào một cột
[image: ]
Hình 11-14Táo và cam: Chữ cái và số không hòa hợp với nhau
Thử làm vậy là bạn sẽ phải với tay bấm lệnh hoàn tác (undo) ngay lập tức.
Những Điều Sắp Tới
Chương tiếp theo sẽ giới thiệu một cặp hàm mới có thể được kết hợp hữu ích với TOCOL và TOROW, đó là WRAPCOLS và WRAPROWS, cả hai đều đưa phân tích theo hướng ngược lại – bằng cách trải dữ liệu của một cột hoặc một hàng ra thành nhiều cột hoặc nhiều hàng.
12. WRAPCOLS và WRAPROWS: Định Hướng Cho Dữ Liệu
Các danh sách trong bảng tính có thể trở nên rất dài. Hãy nhớ rằng một trang tính Excel cho bạn hơn một triệu hàng bản ghi tiềm năng; và dù nhu cầu quản lý dữ liệu của bạn có lẽ sẽ không bao giờ chạm tới giới hạn đó, thì màn hình laptop nhỏ xíu của bạn có thể không hiển thị được toàn bộ danh sách – ngay cả khi nó chỉ có 50 bản ghi. Và nếu bạn hết chỗ trên màn hình cho danh sách nhưng vẫn muốn xem càng nhiều càng tốt, thì vì mục đích trình bày, bạn có thể muốn phân phối lại dữ liệu thành nhiều cột. Bạn không thể xem 300 hàng dữ liệu cùng một lúc, nhưng nếu bạn đóng gói lại tất cả thành 15 cột, mỗi cột 20 bản ghi, thì có lẽ bạn xem được.

Hình 12-1Đó là một màn "wrap", kiểu Slicer
WRAPCOLS và WRAPROWS làm điều gì đó tương tự, đóng vai trò như những hàm nghịch đảo (reciprocal) của TOCOL và TOROW – vốn lấy các cột và hàng rồi nhồi chúng vào một cột và một hàng duy nhất. Và như chúng ta sẽ thấy, hai bộ hàm này cũng có thể phối hợp với nhau.
Cách Viết Chúng
• =WRAPCOLS(vector[range],wrap_count,pad_with)
Tôi không chắc tại sao WRAPCOLS – hay Microsoft – đột nhiên chọn gọi vùng dữ liệu mà WRAPCOLS xử lý là một vector, nhưng họ đã làm vậy và bạn không cần bận tâm về điều đó. Tuy nhiên, cái được gọi là wrap count (số lượng gói) thì có phần đáng suy nghĩ hơn một chút. Trong trường hợp của WRAPCOLS, đối số đó – vốn cần một giá trị – không yêu cầu người dùng chỉ định số cột mà họ muốn đổ dữ liệu vào. Thay vào đó, wrap count xác định số hàng dữ liệu mà mỗi cột sẽ chứa.
(Và điều đó có nghĩa là đối số wrap count trong WRAPROWS lại muốn biết số cột mà bạn dành riêng cho mỗi hàng.)

Hình 12-2Một dãy dữ liệu đơn lẻ
• =WRAPCOLS(Student,20)

Hình 12-320 x 5
Nói cách khác, WRAPCOLS không yêu cầu người dùng nhập số cột mong muốn, nghe có vẻ phản trực giác như vậy. Ở đây kết quả năm cột xuất hiện một cách gián tiếp từ chỉ dẫn điền mỗi cột với 20 bản ghi.
Và nếu bạn viết cùng biểu thức đó với WRAPROWS thay vào đó, kết quả sẽ hiển thị các hàng, mỗi hàng gồm 20 cột.
Hơn nữa, hãy lưu ý rằng cách sắp xếp theo cột này đặt các tên xuống một cột cụ thể, trước khi chuyển sang cột tiếp theo. Các tên đổ xuống cột đầu tiên theo đúng thứ tự chúng xuất hiện trong dữ liệu nguồn. Khi cột đó hết chỗ, có thể nói như vậy, dữ liệu tiếp tục ở cột hai.
• =WRAPCOLS(Student,17)

Hình 12-4Thiếu hụt dữ liệu: không đủ bản ghi cho mỗi cột
• =WRAPCOLS(Student,17,"")
Hoặc tất nhiên bạn có thể điền đối số "pad with" bằng bất kỳ thông báo văn bản nào khác mà bạn muốn, ví dụ: "No Record."
• =A1:A37&" "&B1:B37

Hình 12-5Biết vị trí của mình; các học sinh đang chờ được xếp chỗ ngồi (từ File: WRAPCOLS - demo seating plan)
• =WRAPCOLS(C1#,8,"")

Hình 12-6Bây giờ bạn có thể mở tập câu hỏi
Vài màn phối hợp công thức: TOCOL và WRAPCOLS

Hình 12-7The Matrix, phần 2
Giả sử bây giờ chúng ta muốn sắp xếp các giá trị trên, rồi đưa chúng trở lại cách sắp xếp theo cột 12 x 4 – ở trạng thái đã sắp xếp.

Hình 12-8Một cột, ở dạng số ít
• =SORT(TOCOL(G6:J17))
• =WRAPCOLS(SORT(TOCOL(G6:J17)),12)

Hình 12-9Đa chức năng: kết quả sắp xếp nhiều cột chỉ với một công thức
Chúng ta thấy rằng bằng cách phối hợp các hàm WRAPCOLS, SORT và TOCOL, chúng ta có thể vừa sắp xếp các giá trị vừa khôi phục lại cách bố trí theo cột ban đầu trước khi sắp xếp.
Chuyển sang Sắp xếp lại

Hình 12-10Hướng đúng: việc sắp xếp diễn ra theo chiều ngang
Cái này có thể cần nhìn lại lần thứ hai. Ở đây chúng ta đã chuyển sang dùng WRAPROWS, với số 4 biểu thị số lượng giá trị được đặt để lấp đầy mỗi hàng. Đoạn SORT(TOCOL(G6:J17)) giống hệt nhau trong cả hai công thức, nhưng lần này WRAPROWS lấy các kết quả đã sắp xếp và hướng chúng sang phải, thay vì xuống dưới (hãy nhớ rằng có thể có những cách tiếp cận khác cho công thức này).
Đa nhiệm: Sắp xếp hai cột theo Họ

Hình 12-11Sắp xếp theo họ lần nữa

Hình 12-12Khá thú vị: sắp xếp theo họ, trải rộng trên hai cột
Đó chính là kiểu sắp xếp lại tên mà bạn thấy trong các chương trình của trường học vào ngày lễ tốt nghiệp.
Tiếp theo là gì
Trong khi WRAPCOLS và WRAPROWS mang đến những cơ hội xem dữ liệu mới và cải tiến, thì cặp hàm tiếp theo – VSTACK và HSTACK – cũng đóng góp quan trọng cho việc phân tích dữ liệu. Hẹn gặp bạn ở chương sau.
13. VSTACK và HSTACK: Chúng nói về điều gì
Các hàm mảng động mới VSTACK và HSTACK thực hiện một kiểu hành động giải cứu cho người dùng; chúng đơn giản hóa cực kỳ một tác vụ quản lý dữ liệu lâu đời mà phần lớn thời gian thực ra có thể tránh được ngay từ đầu.
Đó là công việc gộp hoặc hợp nhất dữ liệu đã được thu thập vào nhiều tập dữ liệu (dataset). Một ví dụ điển hình: một người làm nghề tự do ghi lại thu nhập của mình trong một loạt tập dữ liệu, mỗi tập lưu trữ hoạt động của một năm. Trong tình huống rập khuôn nhưng hoàn toàn hợp lý này, nhà kinh tế học làm nghề tự do của chúng ta giao phó tập dữ liệu mỗi năm cho một tab bảng tính mới, đặt ra câu hỏi phân tích hiển nhiên: anh ta phải làm gì nếu muốn gom tất cả dữ liệu lại với nhau, chẳng hạn để lập bảng tổng thu nhập theo khách hàng? Hoặc ngược lại, nếu anh ta đã phân bổ một tập dữ liệu riêng cho mỗi khách hàng, thì anh ta cũng sẽ gặp thách thức tương tự khi muốn tính thu nhập theo năm, theo tháng, v.v.

Hình 13-1Consolidate – các lựa chọn kiểu cũ để gộp tập dữ liệu
Tôi chưa bao giờ ưa Consolidate cùng giao diện vụng về của nó, nhưng câu hỏi thiết kế lớn hơn là tại sao ngày nay người dùng lại muốn chia tách nhiều tập dữ liệu ngay từ đầu. Thay vào đó, bằng cách dồn tất cả dữ liệu vào một tập dữ liệu duy nhất và đưa tất cả vào một bảng pivot (pivot table), mọi kiểu tổng hợp và phân tách theo trường đều trở nên khả thi, mà công sức lại giảm đi đáng kể. Bảng pivot sẵn sàng cho phép tách dữ liệu theo từng năm hoặc từng khách hàng, và bằng cách đó chúng đảo ngược hoàn toàn mô hình hợp nhất. Suy cho cùng – gom tất cả dữ liệu về một chỗ rồi tách số liệu ra từ đó thì dễ hơn là rải dữ liệu khắp nhiều tập dữ liệu rồi sau đó cố gắng lắp ghép số liệu lại một cách có ý nghĩa, kiểu Humpty-Dumpty.
Nhưng đó chỉ là ý kiến khiêm tốn và chắc chắn là không được ai yêu cầu của một người, và bất chấp lời khuyên của tôi, chắc chắn vẫn còn rất nhiều người dùng tiếp tục thực hành chính sách đa tập dữ liệu. Và VSTACK cùng HSTACK chính là dành cho bạn.
Thực chất, VSTACK và HSTACK chính là Consolidate phiên bản mới. Nó cho phép người dùng, thông qua một giải pháp công thức cực kỳ đơn giản, giữ nguyên nhiều tập dữ liệu tại chỗ mà đồng thời vẫn được phép thực hiện một loạt phân tích trên chúng. VSTACK và HSTACK cho bạn có cả đôi đường.
Cách viết VSTACK
• =VSTACK(range1, range2…)
Một lần nữa, Excel thay thế "array" cho "range", nhưng thuật ngữ nào cũng truyền đạt cùng ý tưởng. Tất cả những gì bạn cần làm là cung cấp tọa độ của các vùng bạn muốn xếp chồng, và VSTACK lo phần còn lại. Nhưng dù dễ thực hiện đến đâu, chúng ta sẽ thấy rằng bạn thực sự cần có một chiến lược khi triển khai VSTACK và quyết định chính xác bạn muốn hàm này làm gì.

Hình 13-2Hai tập dữ liệu nhỏ ở chế độ trước khi xếp chồng
• =VSTACK(D8:F11,J4:L8)

Hình 13-3Các tiêu đề bị xếp chồng chống lại chúng ta
Cách đó có hiệu quả, kiểu như vậy, nhưng có gì đó mách bảo tôi rằng bạn sẽ không hoàn toàn hài lòng với những gì mình thấy.
Nhưng sự thật là VSTACK đã làm đúng chính xác những gì chúng ta bảo nó làm. Nó đã xếp chồng cả hai vùng mà chúng ta chỉ định, nhưng vì các vùng này tình cờ chứa cùng một hàng tiêu đề – thì đành vậy thôi.
• =VSTACK(D8:F11,J5:L8)
[image: ]
Hình 13-4Loại bỏ một hàng, gộp hai vùng

Hình 13-5Tránh trùng lặp: một cách khác để loại bỏ một hàng tiêu đề
Ở đây, vì UNIQUE tác động lên các bản ghi mà mỗi bản ghi có ba ô, nó sẽ loại bỏ một trong các tiêu đề giống hệt nhau. (Lưu ý rằng mặc dù cách khắc phục bằng UNIQUE hiệu quả cho tình huống trên, nhưng nếu một số bản ghi bị trùng lặp hoàn toàn, thì tất cả trừ một bản ghi sẽ bị UNIQUE loại bỏ luôn. Vì vậy, vẫn có thể áp dụng một giải pháp thay thế khác cho vấn đề này: =VSTACK(D8:F11,DROP(J4:L8,1)). Hàm DROP phân tích một số hàng được chỉ định từ một tập dữ liệu – trong trường hợp của J4:J8, hàng 1 chứa tiêu đề của nó – và sẽ được thảo luận trong Chương 15.)

Hình 13-6Đừng để mất tiêu đề của bạn
“tiêu đề” sẽ đơn giản là tự đầu hàng trước thao tác sắp xếp, không giống như các tiêu đề tập dữ liệu đích thực sẽ được giữ nguyên tại chỗ.
Và điều này có nghĩa là, ít nhất một phần, nếu bạn muốn xử lý dữ liệu mới được xếp chồng của mình như một tập dữ liệu thông thường, bạn chỉ cần chạy Copy > Paste Values lên kết quả, và bạn đã sẵn sàng. Khi đó các tiêu đề của bạn sẽ được giữ nguyên tại chỗ.
Nhưng nếu bạn muốn VSTACK các vùng dữ liệu trong khi đồng thời bảo lưu quyền thêm các bản ghi mới vào bất kỳ vùng đóng góp nào – và đảm bảo rằng VSTACK sẽ tự động đưa các bản ghi mới đó vào ngay lập tức thì sao?

Hình 13-7Lật ngược tình thế với các vùng dữ liệu
• =VSTACK(Table1, Table2)

Hình 13-8VSTACK hoạt động trực tiếp – bất kỳ bản ghi mới nào được nhập vào một trong hai bảng sẽ xuất hiện trong kết quả xếp chồng
Công thức VSTACK giờ đây tham chiếu đến hai bảng; và vì vậy, việc nhập thêm dữ liệu vào một trong hai bảng sẽ ngay lập tức được phản ánh trong kết quả đầu ra của VSTACK.

Hình 13-9Ở giữa nhóm: bản ghi mới Dan từ Table1 vẫn nằm trong dữ liệu của Table1

Hình 13-10Tất cả cùng nhau – dữ liệu từ cả hai bảng được sắp xếp cùng nhau
Khi dữ liệu không có ở đó

Hình 13-11Nhiều hơn bạn mong đợi; một trường thừa trong một bảng được mang sang kết quả của VSTACK
Chúng ta sẽ tìm hiểu một cách khắc phục đơn giản cho tình huống khó xử này trong chương tiếp theo về các hàm CHOOSECOLS và CHOOSEROWS mới, và một thảo luận liên quan khác sẽ xuất hiện trong chương về hàm EXPAND.
Một vấn đề khác, và một cách khắc phục

Hình 13-12Tập trung vào dữ liệu trống
Nhưng một ô trống không hẳn là số không. VSTACK ghi nhận điểm kiểm tra bị thiếu của Jill thành 0 một cách gây hiểu nhầm, trong khi thực tế có thể cô ấy chỉ đơn giản là đã vắng mặt trong bài kiểm tra, và số ID 0 của Mary cũng chẳng giống như một con số mà cô ấy thực sự được gán. Hơn nữa, số 0 sai lệch của Jill còn kéo điểm trung bình của cả lớp xuống một cách giả tạo.
Lưu ý
Thực ra bạn có thể ẩn mọi số 0 rải rác trên một trang tính bằng cách nhấp vào File ➤ Options ➤ Advanced ➤ Display Options for this Worksheet và bỏ chọn Show a zero in cells that have zero value. Nhưng quyết định đó chỉ che khuất số 0 khỏi tầm nhìn, chứ không triệt tiêu giá trị toán học của nó. Ô đó vẫn sẽ cho ra giá trị bằng không.
• =IF(ISBLANK(VSTACK(Table1,Table2)),“”,VSTACK(Table1,Table2))

Hình 13-13Hãy sắp xếp một bài kiểm tra bù cho Jill
HSTACK: Không chỉ là VSTACK nằm ngang
• =HSTACK(Range1, Range2…)
HSTACK căn chỉnh các vùng nằm cạnh nhau, chứ không xếp chồng lên nhau, khác với VSTACK. Và nhờ đó, HSTACK có thể thực hiện một dịch vụ tổ chức dữ liệu rất hữu ích bằng cách trích xuất các trường được chọn từ một tập dữ liệu lớn hơn, qua đó loại bỏ những trường mà bạn cho là không liên quan.

Hình 13-14Vẫn là dữ liệu đó: dữ liệu bán hàng sẵn sàng cho việc HSTACK
• =HSTACK(Country,Salesperson,Order_Amount)

Hình 13-15Tập dữ liệu được tạo theo yêu cầu: ba trường được chọn ra từ năm trường ban đầu
(Một lần nữa, bạn sẽ cần định dạng lại dữ liệu Order_Amount cho phù hợp. Đồng thời, hãy nhớ rằng các tiêu đề trường ban đầu không được trả về ở trên phần kết quả, và tên vùng của các trường gốc cũng không tự động chuyển sang tập dữ liệu thu gọn mới này.) Nếu bạn hài lòng với cách dữ liệu hiển thị, tiếp theo bạn có thể thực hiện Copy > Paste Values lên dữ liệu, thêm một trường tiêu đề, rồi xử lý kết quả mới như một tập dữ liệu chuẩn, gọn gàng hơn. Ngoài ra, như mọi khi, hãy nhớ rằng kết quả của HSTACK là một vùng tràn mảng động (dynamic array spill range), nên nếu bạn viết HSTACK vào ví dụ ô H6, bạn sẽ tham chiếu dữ liệu đó trong một công thức khác bằng H6#.
Vậy là ta thấy có chút trớ trêu ở đây. Trong khi hai hàm xếp chồng này được tạo ra để hợp nhất các vùng độc lập lại thành một tập dữ liệu lớn hơn, chúng cũng có thể thu gọn khối lượng của các tập dữ liệu hiện có bằng cách loại bỏ những trường thừa thãi mà bạn không cần, rồi xếp chồng phần còn lại. Khả năng của HSTACK trong việc cắt gọn các tập dữ liệu lớn xuống chỉ còn những trường mà bạn muốn làm việc cùng là một tính năng cực kỳ đáng giá, xét cho cùng có những tập dữ liệu chứa hàng chục trường, mà nhiều trường trong số đó đơn giản là chẳng liên quan gì đến công việc của bạn với chúng.
Và còn hơn thế nữa. Nếu bạn định nghĩa lại tập dữ liệu nhân viên bán hàng ban đầu thành một bảng (table) và tiếp tục nhập các bản ghi mới vào đó, những mục nhập đó cũng sẽ tự động xuất hiện trong kết quả do HSTACK tạo ra. Thậm chí – bạn còn có thể viết một công thức HSTACK lấy từ tập dữ liệu nhân viên bán hàng sang một workbook khác, và những thay đổi đối với tập dữ liệu nguồn vẫn sẽ được phản ánh trong kết quả HSTACK.
• =HSTACK(Country:Order_Date)
Dùng HSTACK để sắp xếp lại toàn bộ tập dữ liệu
Và với một tùy chọn liên quan, nếu bạn muốn chỉnh sửa thứ tự xuất hiện của tất cả các trường ở trên, bạn có thể viết, ví dụ:
• =HSTACK(Salesperson,Country,Order_ID,Order_Date,Order_Amount)
Ở đây HSTACK gán lại vị trí của tất cả các trường trong tập dữ liệu – nhưng một lần nữa, không tính các tiêu đề trường.

Hình 13-16Ôn tập, lần này với HSTACK

Hình 13-17Một công thức cho ra hai trường độc lập
Hàm INDIRECT lấy đoạn văn bản “art” và biến nó thành tham chiếu đến vùng có cùng tên đó.
• =name&“ ”&INDIRECT(K4)
Và trả về dữ liệu dưới dạng văn bản, do đó buộc phải mất một phen vất vả để tách tên ra khỏi điểm số và đưa hai tập dữ liệu vào các cột riêng biệt.
HSTACK và việc tách tên bằng một công thức duy nhất
• =HSTACK(TEXTBEFORE(A1:A10,“ ”,-1),TEXTAFTER(A1:A10,“ ”,-1))

Hình 13-18Bao nhiêu cái tên, chỉ một công thức
Tất nhiên, chúng ta có thể làm điều tương tự với hàng nghìn cái tên, tất cả đều phục tùng chỉ một công thức đó.
Sắp tới
Trong khi VSTACK và HSTACK có thể xây dựng những khối dữ liệu lớn hơn bằng cách hợp nhất các vùng rời rạc, chương tiếp theo sẽ mô tả một cặp hàm liên quan giúp thay đổi kích thước của các tập dữ liệu hiện có thông qua một kiểu co rút dữ liệu – CHOOSECOLS và CHOOSEROWS. Hẹn gặp lại sớm.
14. CHOOSECOLS và CHOOSEROWS: Ít hơn là nhiều hơn
Phần lớn thời gian, một tập dữ liệu chứa nhiều thông tin hơn mức bạn cần ở thời điểm hiện tại. Đó là lý do dữ liệu thường xuyên được lọc; và quyết định lọc có thể cắt giảm dữ liệu từ một trong hai góc nhìn: bạn có thể cần lọc các trường mình cần và bỏ qua những trường khác, nhưng có lúc bạn có thể giữ nguyên tất cả các trường và áp dụng bộ lọc cho các bản ghi được chọn. Dù bạn chọn hướng nào, các hàm mảng động CHOOSECOLS và CHOOSEROWS mới sẽ giúp chỉ cho bạn đúng hướng.
Chúng ta vừa tìm hiểu về các hàm VSTACK và HSTACK, trong đó HSTACK có thể "nhặt" một tập hợp con các trường từ một bộ dữ liệu rộng hơn và "thu hoạch" thành một bộ dữ liệu mới. CHOOSECOLS cũng làm được điều tương tự, nhưng với vài khác biệt quan trọng mà bạn sẽ muốn biết.
Cách viết hàm CHOOSECOLS
• =CHOOSECOLS(range/array,column_number1, column_number2…)
(Việc chọn nhiều số cột thực chất là lặp lại cùng một đối số khi cần.) CHOOSECOLS yêu cầu điểm khởi đầu là một vùng (range) hoặc mảng (array) đã có sẵn, từ đó bạn quyết định những trường – hay cột – nào mà bạn quan tâm. Và các cột đó được tham chiếu bằng những con số đơn giản, dễ hiểu.
• =CHOOSECOLS(All,1,3,5)

Hình 14-1Ba trên năm cũng không tệ: CHOOSECOLS chọn các trường từ dữ liệu nhân viên bán hàng.
Một lần nữa, cần nhớ lại những lưu ý "chuẩn mực" về các kết quả tràn (spilled results) này: kết quả đầu ra có thể cần được định dạng lại đôi chút, và các tiêu đề trường nguồn sẽ không xuất hiện, đúng như bản chất của một kết quả dạng vùng tràn. Và một lần nữa, nếu bạn tái cấu trúc bộ dữ liệu nhân viên bán hàng gốc thành một bảng (table), thì mọi dữ liệu mới được nhập vào đó sẽ tự động được chuyển đến kết quả CHOOSECOLS ở trên; nghĩa là dữ liệu mới vẫn luôn kết nối với dữ liệu cũ.
Thực ra, ở chương trước chúng ta đã làm một bài tập khá giống bài trên; ở đó, chúng ta cũng giao cho HSTACK nhiệm vụ tách vài trường ra khỏi một bộ dữ liệu và đóng gói chúng thành một bộ mới. Nhưng điểm khác biệt ở đây là CHOOSECOLS xác định các trường bằng số cột hay số trường, trong khi HSTACK yêu cầu tên trường hoặc một tập tọa độ vùng. Và lý do CHOOSECOLS có thể làm việc với các con số – vốn là cách tham chiếu đơn giản hơn – là vì nó chỉ làm việc với các trường thuộc cùng một bộ dữ liệu. Vì đối số đầu tiên của CHOOSECOLS yêu cầu tham chiếu đến một bộ dữ liệu, nên đương nhiên nó biết các đối số số phía sau đang ám chỉ đến (những) trường số nào. Ngược lại, HSTACK có thể gộp các trường rời rạc từ bất kỳ đâu trong workbook (hoặc thậm chí bên ngoài), nên buộc phải dựa vào tên trường cụ thể hoặc tọa độ vùng.
• =CHOOSECOLS(All,5,3,1)
• =CHOOSECOLS(All,-1,-3)
• =CHOOSECOLS(All,-2)
sẽ trích xuất trường áp chót của một bộ dữ liệu gồm 279 trường, giúp bạn khỏi phải vất vả nhớ chính xác để yêu cầu trường số 278.
Tuy nhiên, hãy nhớ rằng kiểu chức năng này không thể so sánh với ý nghĩa của các tham chiếu âm trong hàm TEXTBEFORE và TEXTAFTER; ở đó, giá trị âm xác định các vị trí khác nhau của cùng một dấu phân cách trong một ô mà nó xuất hiện nhiều lần (ví dụ: dấu cách phân tách từng từ), và vì thế có thể trả về số lượng từ khác nhau. Ở đây, các số âm luôn "chạm" vào một trường duy nhất, giống như các giá trị dương vậy.
Kết hợp với các hàm khác
Dù sao đi nữa, một khi bạn đã quen với quy tắc số trường/số cột (tương tự như đối số chỉ mục sắp xếp trong hàm SORT, cũng yêu cầu số của một cột/trường), bạn có thể kết hợp CHOOSECOLS với các hàm hữu ích khác – nhưng phải hết sức cẩn thận. Công thức này
• =SORT(CHOOSECOLS(All,1,3,5),2)
• =SORT(CHOOSECOLS(All,1,5,3),2)
• =SORT(CHOOSECOLS(All,1,3,5),4)
sẽ cho ra thông báo lỗi – vì CHOOSECOLS chỉ xác định được ba cột.
• =FILTER(CHOOSECOLS(All,1,3,5),Salesperson=I2)

Hình 14-2Tùy bạn chọn; chọn cột và chọn nhân viên bán hàng của bạn
Bỏ qua những vấn đề định dạng thường thấy, chúng ta thấy một sự kết hợp pha trộn khá thú vị đang diễn ra: CHOOSECOLS dùng các tham chiếu số cột tiêu chuẩn, trong khi phần FILTER lại yêu cầu chúng ta nhập tên trường – Salesperson – để lọc kết quả đầu ra. Tất nhiên, ở đây chúng ta đang xem xét một bộ lọc kép, có thể nói như vậy – một bộ lọc hoạt động bán hàng của Peacock, lại được lọc tiếp chỉ với ba trường của tập dữ liệu. Và dĩ nhiên, chúng ta đang lọc theo nhân viên bán hàng, dù trường đó không hề xuất hiện trong phần CHOOSECOLS của công thức.

Hình 14-3Vive la formula; lọc cho nước Pháp
CHOOSECOLS và quá nhiều thông tin

Hình 14-4Dư một trường
• =CHOOSECOLS(VSTACK(Table1,Table2),1,2,3)

Hình 14-5Cấu trúc ba cột, tất cả thẳng hàng
Giờ thì chiến lược trên hoạt động cho một VSTACK mà ở đó bạn cần giảm số trường của một trong các tập dữ liệu được xếp chồng. Nếu bạn cần đi theo hướng ngược lại – nghĩa là bạn muốn tăng số trường của một trong các tập dữ liệu để nó xếp chồng đúng cách với một tập dữ liệu khác có nhiều trường hơn – thì nhiệm vụ đó sẽ chờ phần thảo luận về hàm EXPAND.
• =FILTER(INDEX(All,SEQUENCE(ROWS(All)),{1,3,5}),Salesperson=I2)
Không hiểu sao, tôi đoán bạn sẽ thích lựa chọn CHOOSECOLS hơn.
CHOOSEROWS: Phá kỷ lục
Như chúng ta đã chỉ ra ở đầu chương, hai hàm CHOOSE thực hiện các thao tác lọc theo một cách nào đó: CHOOSECOLS cắt bỏ các trường khỏi một tập dữ liệu trong khi giữ lại những trường khác, còn CHOOSEROWS thì "tiễn" những bản ghi được chọn ra đi trong khi giữ lại phần còn lại mong muốn.
CHOOSEROWS đúng là có lọc bản ghi, nhưng theo cách khá thô. Nếu bạn cần lọc tất cả các giao dịch được thực hiện ở Pháp, hoặc biết những giao dịch nào đạt hoặc vượt $2,000, thì bạn sẽ chuyển sang hàm FILTER. CHOOSEROWS không thể áp dụng tiêu chí chi tiết như khả năng bao quát của FILTER; thay vào đó, nó chỉ đơn giản lấy các hàng mà bạn chỉ định, và điều đó có thể phục vụ một mục đích rộng hơn nào đó.
• =CHOOSEROWS(range/array,row_number1, row_number2…)
• =CHOOSEROWS(All,1,2,3,4,5)

Hình 14-6Lấy năm hàng; CHOOSEROWS gọi ra năm hàng đầu tiên trong tập dữ liệu
(Một lần nữa, bạn sẽ phải đối mặt với những nhu cầu định dạng lại thường lệ.)
• =CHOOSEROWS(All,22,23,24,25,26)
• =CHOOSEROWS(All,17,9,24,31,11)
• =CHOOSEROWS(All,1,2,3,4,5,6,7,8,…)
Tức là, tôi có phải nhập từng tham chiếu hàng từ 1 đến 100 không?
• =CHOOSEROWS(All,SEQUENCE(100))
Người bạn cũ SEQUENCE của chúng ta có thể cung cấp tất cả 100 giá trị hàng. Suy cho cùng, nó là một công thức mảng động – với mỗi giá trị do SEQUENCE tạo ra từ 1 đến 100 sẽ chọn hàng của tập dữ liệu mang số đó.
• =CHOOSEROWS(All,-1)
sẽ lôi ra hàng cuối cùng trong tập dữ liệu.
Số Hàng Bắt Đầu Từ Đâu
• =CHOOSEROWS(All,1,2,3,4,5)
chứng tỏ hàng đầu tiên trong tập dữ liệu, bất kể dữ liệu thực sự bắt đầu ở đâu trong bảng tính. 1 luôn biểu thị vị trí hàng của bản ghi đầu tiên trong tập dữ liệu – ở đây, là hàng ngay bên dưới hàng tiêu đề.
Bản ghi duy nhất trong các trường không liền kề: Lần 2
Có thể bạn còn nhớ phần thảo luận của chúng ta trong chương dành cho hàm UNIQUE về việc rút ra các bản ghi duy nhất từ dữ liệu trong hai trường không liền kề, một cách làm dựa trên một ứng dụng khá cầu kỳ của hàm INDEX. Nhưng CHOOSECOLS có thể đảm nhận cùng nhiệm vụ đó với một công thức đơn giản hơn nhiều.

Hình 14-7Nhân viên bán hàng ở các quốc gia xa xôi

Hình 14-8Tạm biệt INDEX – CHOOSECOLS cho một chuyến đi êm ái hơn
Ở đây, công thức chỉ đơn giản tính toán mọi tổ hợp duy nhất của các bản ghi được rút ra từ cột thứ nhất và cột thứ ba của tập dữ liệu – những cột chứa Country và Salesperson. Dễ đến mức bạn sẽ nghĩ rằng mình đã làm sai điều gì đó.
Dùng CHOOSEROWS để điền vào chỗ trống
Giờ có thể bạn còn nhớ một vài bài tập chúng ta đã mô tả trong chương FILTER nhằm lọc một tập dữ liệu đầy rẫy các hàng trống. Giờ hãy hướng CHOOSEROWS vào dữ liệu đó, và chứng minh cách hàm này có thể dễ dàng loại bỏ tất cả những hàng đó và từ đó tạo ra một tập dữ liệu cực kỳ hữu dụng (tệp: CHOOSEROWS – blank rows).
Nhưng trước tiên, chúng ta cần ôn lại cách CHOOSEROWS đánh số các hàng mà nó làm việc cùng. Hãy nhớ rằng tập dữ liệu của chúng ta, mang tên mặc định quen thuộc là All và có 3788 hàng, thực ra bắt đầu từ hàng 2 (xem phần ghi chú giới thiệu trong Chương 3 dưới tiêu đề "Field Notes: Field and Dataset Names"). Và hàng đó – hàng số 1 trong tập dữ liệu, hàng ngay bên dưới hàng tiêu đề – là trống. Điều đó có nghĩa là hàng đầu tiên chứa dữ liệu trong tập dữ liệu, theo ngôn ngữ của CHOOSEROWS, là hàng 2.
• =CHOOSEROWS(All,SEQUENCE(1894,,2,2))

Hình 14-9Chỉ toàn dữ liệu: các hàng trống đã bị xóa
Công thức này hoạt động thế nào? Phần tử SEQUENCE của nó yêu cầu 1894 hàng – một nửa của 3798 hàng tạo nên tập dữ liệu, và do đó là số hàng chứa dữ liệu. Nó khởi đầu chuỗi của mình bằng số 2 – một lần nữa, đại diện cho hàng đầu tiên trong tập dữ liệu có dữ liệu – và tăng mỗi giá trị tiếp theo thêm một bước là 2. Như vậy, CHOOSEROWS được cung cấp các giá trị hàng 2,4,6,8…3798, mỗi giá trị tương ứng với một hàng có dữ liệu – và tiến hành chọn chính xác, và chỉ, những hàng đó.
Nếu kết quả trông ổn và bạn muốn chúng làm tập dữ liệu cho các phân tích tiếp theo, bạn có thể thực hiện quy trình Copy > Paste Values nhắm vào vùng tràn – và hãy nhớ, nó đúng là một vùng tràn. Tiếp theo, bạn có thể sao chép và dán các tiêu đề gốc lên trên tất cả, và bạn đã sẵn sàng – chỉ cần đặt tên vùng cho từng trường thông qua Create from Selection.
Tiếp theo: Đưa các hàng và cột qua một TAKE khác
Bạn sẽ thấy rằng cặp hàm mảng động mới tiếp theo mà chúng ta sẽ xem xét có nét tương đồng họ hàng với CHOOSECOLS và CHOOSEROWS, nhưng chắc chắn chúng không phải là cặp song sinh giống hệt nhau. Chúng được gọi là TAKE và DROP, và bạn sẽ thấy chúng có điểm chung gì với hai hàm CHOOSE – và những điểm không chung.
15. TAKE và DROP: Chọn và Loại bỏ Dữ liệu
Tương tự – nhưng Khác biệt
Giống như CHOOSECOLS và CHOOSEROWS, hai hàm mảng động mới là TAKE và DROP cắt tỉa tập dữ liệu bằng cách tạm thời loại bỏ những bản ghi không mong muốn và giữ lại những bản ghi khác. Nhưng TAKE và DROP thực hiện việc cắt tỉa theo những cách kém linh hoạt hơn so với các tùy chọn mà hai hàm CHOOSE cung cấp – nhưng đồng thời, chúng ta sẽ thấy rằng chúng có thể thực hiện một số tác vụ nhất định hiệu quả hơn.
Cách viết chúng
• =TAKE(range/array,rows,columns)
(Các đối số rows và columns là tùy chọn, mặc dù bạn cần cung cấp ít nhất một trong số chúng.)
• =TAKE(names,6)

Hình 15-1Lấy một chút từ trên xuống: TAKE trả về sáu tên đầu tiên trong vùng
• =CHOOSEROWS(names,3,1,5)
hàm này lấy các hàng 3, 1 và 5 từ tập dữ liệu, bạn không thể đưa ra một tập tham chiếu gồm nhiều hàng bằng TAKE.
• =TAKE(all,8,3)

Hình 15-2Tám hàng dọc, ba cột ngang: cách TAKE lấy dữ liệu theo hàng và cột
• =TAKE(all,,3)
sẽ trưng dụng tất cả các hàng, và ba cột đầu tiên.
Vậy nên theo mặc định, TAKE chỉ có thể lấy dữ liệu từ các hàng và/hoặc cột liên tiếp bắt đầu từ những hàng trên cùng của tập dữ liệu, và từ những cột ngoài cùng bên trái. Bạn không thể dùng TAKE để trả về những hàng hoặc cột không liên tiếp, như bạn có thể làm với CHOOSEROWS hoặc CHOOSECOLUMNS; cũng không thể lấy dữ liệu từ một điểm xuất phát nằm giữa tập dữ liệu.
• =TAKE(names,-3)

Hình 15-3Đảo ngược thế cờ: TAKE gọi ra các tên từ cuối vùng với đối số âm
Tương tự như vậy, tham chiếu đối số column với một giá trị âm sẽ khởi tạo việc lấy cột từ cột ngoài cùng bên phải. Nhưng ở đây cũng vậy, TAKE thu thập dữ liệu từ các cực – từ tận đáy dữ liệu đi ngược lên trên, và từ những cột xa nhất bên phải tiến dần về bên trái.
BỎ QUA: Bỏ lại dữ liệu phía sau
• =DROP(range/array,rows,columns)
Một lần nữa, các đối số rows và columns là tùy chọn, mặc dù tất nhiên bạn cần chọn ít nhất một trong số chúng.
• =DROP(names,3)
[image: ]
Hình 15-4DROP từ trên xuống: ba hàng đầu tiên bị loại bỏ
• =DROP(all,,4)
sẽ trả về tất cả các hàng của chúng nhưng sẽ bỏ qua, hay loại bỏ, bốn trường đầu tiên, chỉ trả về dữ liệu từ cột 5 mà thôi. Một lần nữa, số 4 không đề cập đến cột số bốn, mà là số lượng cột bị bỏ qua hoặc loại bỏ, bắt đầu từ bên trái của tập dữ liệu.
• =DROP(names,-4)

Hình 15-5Dù theo cách nào, bạn cũng nhận được cùng một danh sách tên: hai công thức, một kết quả
Và một khi bạn nhận ra các lộ trình tương ứng của DROP và TAKE dẫn bạn đến đâu, hai nhận thức sẽ xuất hiện: (1) nhiều kết quả được TAKE sắp đặt cũng có thể đạt được bằng DROP, một khi bạn hiểu cách các đối số của chúng bị đảo ngược, và (2) vì TAKE và DROP chỉ có thể xử lý các hàng liền kề, bạn sẽ rất thường xuyên cần sắp xếp tập dữ liệu trước khi tiếp tục – bởi vì các bản ghi mà bạn muốn lấy hoặc bỏ phải nằm liền nhau, và cũng phải nằm ở vị trí trên cùng hoặc dưới cùng của phạm vi trước mặt bạn.
Một số ứng dụng thực tế
• =SORT(FILTER(All,RANK(Order_Amount,Order_Amount)<=10),5,-1)
• =TAKE(SORT(all,5,-1),10)

Hình 15-6Top ten của TAKE đánh bại top ten của FILTER
Ở đây công thức TAKE bên phải sắp xếp, thông qua tùy chọn từ cao đến thấp (số -1 được đặt bên trong công thức SORT), cột thứ năm của tập dữ liệu – cột chứa số tiền đơn hàng bán. Tiếp theo nó lấy mười hàng đầu tiên của kết quả đã sắp xếp, khớp với kết quả của FILTER với ít thao tác gõ phím hơn đáng kể. (Lưu ý rằng top ten này về mặt kỹ thuật có vấn đề; nếu hai con số bán hàng tương đương cùng giữ vị trí thứ mười, công thức TAKE được mô tả ở trên sẽ chỉ trả về một trong số chúng.)

Hình 15-7Làm việc nhóm: TAKE và CHOOSECOLS mang lại top 10 doanh số theo nhân viên bán hàng
CHOOSECOLS chỉ định rằng chỉ có cột/trường thứ hai (Salesperson) và thứ năm (Order Amount) được trả về.
Một bài tập độc đáo
• =TAKE(SORTBY(SEQUENCE(50),RANDARRAY(50)),10)
[image: ]
Hình 15-8Ngẫu nhiên – và độc nhất – mỗi giá trị nằm đâu đó giữa 1 và 50
Công thức này tạo ra một chuỗi giá trị từ 1 đến 50 (tất nhiên bạn có thể chọn bất kỳ khoảng nào bạn muốn). Nó sắp xếp những giá trị này theo một tập hợp ảo, song song gồm 50 số ngẫu nhiên nhờ RANDARRAY, và khi việc sắp xếp được thực thi, TAKE chỉ đơn giản cắt bỏ mười hàng đầu tiên khỏi 50 kết quả. Vì hàm SEQUENCE cung cấp 50 giá trị liên tiếp từ 1 đến 50, nên theo định nghĩa chúng phải là duy nhất; sắp xếp chúng một cách ngẫu nhiên rồi ném những giá trị đó vào một thứ tự không thể đoán trước, từ đó TAKE lấy ra 10 giá trị đầu tiên.
Xếp hạng thêm – nhưng theo tỷ lệ phần trăm
Ngoài việc lọc dữ liệu để tìm ra top mười giá trị tuyệt đối, TAKE còn có thể tạo ra kết quả mang lại một tỷ lệ phần trăm nhất định của các bản ghi. Tiếp tục với tệp thực hành TAKE – ranking data – giả sử chúng ta muốn phục vụ 15% đơn hàng bán ra cao nhất, một yêu cầu buộc chúng ta phải giải quyết một câu hỏi trước mắt: vì tập dữ liệu gồm 798 bản ghi, 15% trong đó tương đương 119.7, nên ở đâu đó trong công thức phải thực hiện việc làm tròn giá trị đó.
• =TAKE(SORT(all,5,-1),ROWS(all)*0.15)

Hình 15-9Top 15% doanh số, ít nhiều
• =TAKE(SORT(all,5,-1),ROUNDUP(ROWS(all)*0.15,0))
Thay đổi nhỏ đó sẽ nâng 119.7 lên số nguyên tiếp theo – 120 – và xếp hạng bấy nhiêu bản ghi.
• =TAKE(SORT(all,5,-1),ROWS(all)*H3)
Để nó DROP: Loại bỏ điểm thấp nhất
Giả sử bạn là một giáo viên đã giao tám bài kiểm tra cho học sinh trong suốt học kỳ. Vì bạn muốn làm đúng, bạn quyết định tính điểm trung bình của mỗi học sinh dựa trên sáu điểm cao nhất của họ, tức là bạn sẵn sàng loại bỏ hai điểm thấp nhất.
• =DROP(SORT(B2:I2,,,1),,2)

Hình 15-10Bill gặp may: hai điểm thấp nhất của cậu ấy chưa từng tồn tại

Hình 15-11Điểm trung bình của Bill cho cả tám bài kiểm tra: 61.75

Hình 15-12Đạt điểm (số): sáu bài kiểm tra
Tiếp theo
Hàm mảng động thế hệ thứ hai tiếp theo, và cũng là cuối cùng, mà chúng ta sẽ xem xét là một hàm thoạt nhìn có vẻ hơi lạ, một hàm dường như đối lập hoàn toàn với TAKE và DROP. Trong khi những hàm đó thu hẹp dữ liệu mà người dùng muốn làm việc, thì hàm tiếp theo – EXPAND – có thể tạo chỗ cho dữ liệu chưa được nhập vào. Tôi đã nói rằng nó có vẻ lạ; vậy hãy lật trang tiếp theo.
16. EXPAND: Mở rộng dữ liệu
Nếu nói thật lòng, lần đầu tiên tôi biết đến hàm EXPAND có thể gọi là hơi khó hiểu. Trong bài giới thiệu trước về các hàm mảng động thế hệ thứ hai của Excel, nhà phát triển Microsoft Joe McDaid cho chúng ta biết rằng "EXPAND cho phép bạn mở rộng một mảng đến kích thước bạn chọn—bạn chỉ cần cung cấp các kích thước mới và một giá trị để lấp đầy khoảng trống thêm vào."
Ngoài việc để lơ lửng một giới từ, mô tả đó khiến tôi hơi mơ hồ. Chính xác thì mở rộng một mảng (hay vùng) nghĩa là gì, và quan trọng hơn, khả năng đó có thể phục vụ mục đích gì cho bạn và tôi?
Cách viết – và tại sao
• =EXPAND(range/array,rows,columns,pad_with)
Như thường lệ, đối số range/array yêu cầu tọa độ của dữ liệu mà bạn đang làm việc. Đối số rows tùy chọn yêu cầu số hàng mà bạn muốn mở rộng vùng tràn tới; nếu bỏ qua, đối số này sẽ chỉ cung cấp số hàng có trong vùng. Tham số columns tùy chọn tương tự cũng yêu cầu số cột mà vùng tràn EXPAND sẽ mở rộng tới, và như với các hàm khác chúng ta đã thấy ở đây, "pad with" cho phép người dùng đăng một thông báo vào các ô mà nếu không sẽ truyền một thông báo lỗi, như chúng ta sẽ thấy.
Tất cả những điều đó đặt ra một câu hỏi hiển nhiên cho những ai trong chúng ta còn mơ hồ: tại sao bạn lại yêu cầu EXPAND xuất ra một số hàng hoặc cột vượt quá tổng số hàng và/hoặc cột của dữ liệu bạn đã có?

Hình 16-1Mở rộng: dữ liệu sẽ được EXPAND
• =EXPAND(D9:E12,,3)
(Lưu ý rằng vùng được tham chiếu loại trừ hàng tiêu đề, theo thảo luận của chúng ta trong chương về VSTACK và HSTACK. Cũng lưu ý việc bỏ qua đối số rows, khiến kết quả mặc định bằng số hàng trong dữ liệu nguồn.)

Hình 16-2Một cột mới, bốn thông báo #N/A mới
Câu hỏi đó – một lần nữa
Kết quả đó chỉ xác nhận câu hỏi của chúng ta. Ta thấy rằng cột thứ ba mà EXPAND đã tạo ra đang trống rỗng, và vì bảng tính vốn ghét sự trống rỗng, các ô trống của nó đã bị chiếm chỗ bởi những thông báo #N/A xấu xí mà bạn chắc hẳn muốn loại bỏ. Nếu vậy, bạn có thể viết lại EXPAND
• =EXPAND(D9:E12,,3,“no data”)

Hình 16-3Không có dữ liệu, nhưng không có #N/A
Nhưng dù sao, cải thiện về mặt hình thức đó vẫn chưa giải đáp được câu hỏi: tại sao chúng ta lại cần cột thứ ba đó?
• =VSTACK(J5:L8,EXPAND(D9:E12,,3,“no data”))

Hình 16-4Một kết quả phù hợp với VSTACK và EXPAND
Từ đó ta hiểu rằng cột thứ ba ma ảo mà ta đã gắn thêm vào D9:E12 bằng EXPAND giờ đây đưa vùng đó vào thẳng hàng với J5:L8 cũng có ba cột tương tự; và có lẽ quan trọng hơn, chú thích "pad with" lấp đầy cột bằng thông tin hữu ích, dễ trình bày – "no data" – và thực tế, chính sự tô điểm đó hóa ra lại là lý do thực sự để dùng EXPAND.
• =VSTACK(J5:L8,EXPAND(D9:E12,,3))
[image: ]
Hình 16-5Dễ thấy vì sự vắng mặt của nó; không có thông báo "pad with"
• =VSTACK(J5:L8,D9:E12)
Vậy ta thấy rằng bằng cách không gọi đối số "pad with", việc xếp chồng nhiều tập dữ liệu mà không có lỗi có thể sẽ không được kích hoạt – ngay cả khi EXPAND mới mẻ được đưa vào công thức.
Giờ thì nói về những số không đó…

Hình 16-6Chẳng ích gì: số không thay thế các ô trống trong các ô ở đầu ra VSTACK

Hình 16-7Vẫn vậy; EXPAND cũng trả về số không cho một ô trống, nhưng đối số "pad with" là "" chỉ đưa các ô trống vào cột thứ ba được mở rộng mà thôi
Lưu ý ở đây rằng ký tự trống "" áp dụng cho đối số "pad with" có lấp đầy cột thứ ba được mở rộng bằng các ô trống – nhưng nó không xóa được số không trong dữ liệu nguồn thực tế của Mary.

Hình 16-8Địa chỉ không có người ở – các ô trống sẽ được xếp chồng
• =IF(isblank(VSTACK(J5:L8,D9:F12)),“”,VSTACK(J5:L8,D9:F12))
Tất nhiên bạn sẽ để ý rằng EXPAND thậm chí còn không xuất hiện ở đó, vì nó đã bị thay thế bằng một tham chiếu vùng đơn giản: D9:F12 – và đúng là một thứ kỳ lạ, bởi vì dữ liệu thực sự lấp đầy vùng đó chỉ nằm ở cột D và E. Cột F có vẻ chẳng qua chỉ là một chỗ giữ chỗ gian xảo, hư cấu, và đúng là như vậy – ngoại trừ việc nó đại diện cho một cột thứ ba, và do đó mở rộng (lại là từ đó) vùng nhân tạo ấy để nó có thể thẳng hàng với J5:L8 gồm ba cột. Từ D đến F giờ đây có thể thẳng hàng với J đến L – bởi vì mỗi bên đều gồm ba cột.

Hình 16-9Các số không đã được làm trống
Như vậy chúng ta đã xếp chồng các cột một cách đúng đắn, đồng thời loại bỏ được những số không mặc định mà VSTACK gán cho các ô trống.
Vậy có phải chúng ta thậm chí còn cần đến EXPAND không?
Bài tập ở trên – trong đó chúng ta dường như đã đẩy lùi được những số không gây nhầm lẫn mà VSTACK áp cho các ô trống, mà không cần đến hàm EXPAND – lại gợi ý rằng có lẽ chúng ta có thể bỏ hẳn EXPAND; nhưng kết luận đó chưa hẳn đã hợp lý.
Một là, nếu dữ liệu cần xếp chồng được tái cấu trúc thành bảng, thì điều đó có nghĩa là, cùng với những thứ khác, VSTACK sẽ có thể tiếp nhận và xếp chồng các bản ghi mới khi chúng được nhập vào các bảng đóng góp. Và nếu vậy, biểu thức VSTACK sẽ cần đến EXPAND.
[image: ]
Hình 16-10Bảng cho hai
• =VSTACK(Table1,EXPAND(Table2,,3,“”))
[image: ]
Hình 16-11Không có gì để thêm – số không quay trở lại
[image: ]
Hình 16-12Thế là được: Định nghĩa các tập dữ liệu dưới dạng bảng sẽ gọi đến EXPAND để loại bỏ các số không
Biểu thức hơi rối rắm đó cho phép người dùng nhập các bản ghi mới có thể được xếp chồng, đồng thời thay thế các ô trống bằng những số không sẽ xuất hiện trong các ô trống ngay từ đầu. Điểm mấu chốt: trong trường hợp này chúng ta cần đến EXPAND.
Tổng kết
Phần trước đã giải quyết một vấn đề đặc thù của hàm VSTACK, hàm này xếp chồng, hay kết hợp, các tập dữ liệu khác nhau thành một tổng thể mới: việc nó xử lý và trả về các ô trống như thể là số không, làm lan truyền chút thông tin sai lệch, điều này cũng khuyến khích các kết quả công thức sai. Chúng ta đã thấy rằng các số không có thể được thay bằng ô trống thực sự, hoặc khi dữ liệu đóng góp cho một VSTACK tồn tại dưới dạng các tập dữ liệu thông thường, hoặc khi chúng đã được tinh chỉnh thành bảng – trong trường hợp đầu là không cần đến hàm EXPAND, và trong trường hợp sau là khi EXPAND dường như thực sự cần thiết.
Giờ đây, sau khi mọi chuyện đã ngã ngũ, bạn có thể quyết định rằng, xét theo các vai trò quản lý dữ liệu mà EXPAND đảm nhận, có lẽ bạn cũng chẳng dùng nó thường xuyên. Có thể lắm, nhưng còn một thuộc tính khác, hoàn toàn khác biệt của EXPAND mà bạn có thể muốn – và cần – biết đến.
EXPAND và việc giải trục dữ liệu
Nếu bạn vẫn chưa bị thuyết phục về những ưu điểm của EXPAND, thì giờ đây chúng ta sẽ thấy rằng nó có thể mang lại giá trị then chốt cho một giải pháp dựa trên công thức cho cái mà ngày nay người ta gọi là việc "trải phẳng" dữ liệu (unpivoting of data).
[image: ]
Hình 16-13Các đối tượng cần thay đổi: mỗi đối tượng chiếm một trường riêng
[image: ]
Hình 16-14Thu hẹp (các) trường: xuống còn ba, chính xác là vậy. Tuy nhiên dữ liệu vẫn như cũ
(Tên học sinh được đặt tên vùng là stu, môn học là sub, và điểm kiểm tra là sc.)
Việc cố ý thu gọn dữ liệu gốc từ bảy trường xuống còn ba trường – mà không hề loại bỏ bất kỳ dữ liệu nào – là một ví dụ điển hình của việc trải phẳng dữ liệu (unpivoting). Phải nói rõ rằng, "trải phẳng" là một thuật ngữ hơi thiếu chính xác, bởi vì dữ liệu ở đây chưa từng được đưa vào một bảng pivot (pivot table) thực sự, và thực tế người ta không thể trải phẳng dữ liệu đã được lưu trong một bảng pivot. Ý nghĩa thực sự của "trải phẳng" là dữ liệu cần được trải phẳng có hình dáng giống như kết quả của một bảng pivot thông thường, xét về cách tổ chức dữ liệu và sắp xếp các trường; do đó, trải phẳng một tập dữ liệu là cách để kéo dữ liệu lùi lại vài bước và làm cho chúng sẵn sàng cho bảng pivot – nghĩa là đủ điều kiện để tạo bảng pivot. (Lưu ý rằng một cách trải phẳng dựa trên lệnh có thể được thực hiện bằng Power Query Editor của Excel.)
Điểm cốt lõi trong quy trình trải phẳng của chúng ta là việc gom tất cả tên môn học vào một trường duy nhất như ta thấy ở trên, mỗi mục đi kèm với một điểm số cụ thể và học sinh đạt được điểm đó. Vì tập dữ liệu của chúng ta có 66 điểm kiểm tra, nên các trường tên học sinh và môn học tương ứng cũng phải chứa 66 mục sau khi được trải phẳng – mặc dù tập dữ liệu gốc chỉ ghi lại mười một tên học sinh và sáu môn học một lần mỗi thứ. Và đây chính là lúc hàm EXPAND xuất hiện – nó có thể tái tạo tên học sinh và môn học với số lần mong muốn, và với sự hỗ trợ của hàm TOCOL, đổ kết quả xuống một cột duy nhất – tức là vào một trường duy nhất đã được trải phẳng.
Mở rộng tầm nhìn của EXPAND
[image: ]
Hình 16-15Ba trên hai: lại mở rộng một tập dữ liệu thêm một cột
• =EXPAND(D9:D12,,10)
(Lưu ý rằng chúng ta đã bỏ qua đối số "pad with", và ở đây chúng ta chỉ mở rộng một cột dữ liệu.)

Hình 16-16Không, chúng ta không muốn #N/A
Tất cả những điều này lại đặt ra câu hỏi hiển nhiên mà chúng ta đã nêu trước đó trong chương: tại sao tôi lại muốn viết một biểu thức như vậy?
Chà, có lẽ bạn sẽ không muốn, nhưng với một vài chỉnh sửa khôn ngoan, những công thức như công thức trên có thể được làm cho sao chép một vùng giá trị nhiều lần, đặc biệt là các vùng chỉ gồm một cột hoặc một hàng. Và điều đó có nghĩa là EXPAND có thể lấy mười một tên học sinh của chúng ta và nhân bản chúng thành 66 trường hợp mà chúng ta cần.
• =IFNA(EXPAND(stu,,6),stu)
[image: ]
Hình 16-1711 x 6: 66 cái tên – nhờ công của EXPAND, với một chút giúp sức từ IFNA
(Cảm ơn chuyên gia Excel Mike Girvin vì mẹo tinh gọn công thức này.)
• =EXPAND(stu,,6)
[image: ]
Hình 16-1855 tên không khả dụng
Nhưng hàm IFNA, một câu lệnh IF chuyên dụng cho thông báo #N/A, đứng canh chừng EXPAND và thay thế bất kỳ cột nào chứa đầy #N/A bằng dữ liệu từ vùng gốc stu. Nhưng đồng thời, IFNA cũng đảm bảo rằng nếu một cột không có #N/A, thì công thức lồng bên trong – EXPAND(stu,,6) – sẽ tiếp quản và trả về stu. Vì vậy, với IFNA nắm quyền, bạn nhận được dữ liệu từ stu dù #N/A có xuất hiện hay không.
• =IFNA(EXPAND(stu,,COUNTA(sub)),stu)
Chúng ta sắp đến đích rồi
• =TOCOL(IFNA(EXPAND(stu,,6),stu))

Hình 16-19Học sinh xếp thành một hàng dọc
• =TOCOL(IFNA(EXPAND(sub,11),sub))
[image: ]
Hình 16-20Tập hợp lớp học: mỗi học sinh được ghép với mỗi môn học
• =TOCOL(IFNA(EXPAND(stu,,6),stu))
• =TOCOL(IFNA(EXPAND(sub,11),sub))
• =IFNA(EXPAND(sub,11),sub)
[image: ]
Hình 16-21Thay đổi các môn học: mười một hàng theo yêu cầu, sáu cột theo mặc định. Hãy nhớ rằng dữ liệu gốc chỉ gồm một hàng và sáu cột.
Vì dữ liệu học sinh và môn học lần lượt trải theo chiều dọc và chiều ngang, nên kết quả học sinh cho thấy một tên mỗi hàng, trong khi các môn học truyền một tên môn mỗi cột.
• =TOCOL(sc)
[image: ]
Hình 16-22Mọi thứ đã xong, chỉ còn phần tiêu đề
Công thức đơn giản đó hoạt động được vì các điểm kiểm tra vốn dĩ đã có tổng cộng 66 phần tử, nên con số đó không cần phải mở rộng thêm. Tất cả những gì ta cần làm là xếp các giá trị thành một cột duy nhất, và đó chính xác là điều mà TOCOL làm.
Cũng lưu ý rằng toàn bộ hoạt động công thức này giữ cho dữ liệu luôn đồng bộ: điểm của Bill khớp hoàn hảo với các môn học của cậu ấy, cũng như với tất cả các học sinh khác.
Bước tiếp theo và cũng là bước cuối cùng là nhập ba tiêu đề phía trên các cột, và bảng pivot (pivot table) của bạn đã sẵn sàng – với một lưu ý quan trọng: bảng pivot thường được khởi tạo chỉ bằng cách nhấp vào bất kỳ ô nào trong tập dữ liệu, nhưng ở đây, vì mỗi trường là một vùng tràn (spill range) riêng biệt, bạn cần khởi động bảng pivot bằng cách nhấp vào một trong các tên tiêu đề. Làm như vậy sẽ đảm bảo rằng toàn bộ dữ liệu sẽ được đưa vào bảng pivot.
Để được Điểm Cộng…
• =HSTACK(TOCOL(IFNA(EXPAND(stu,,6),stu)),TOCOL(IFNA(EXPAND(sub,11),sub)),TOCOL(sc))
Và đó, thưa quý vị, chính là một công thức mảng động (dynamic array formula) thực thụ.
Mục lục
A, B
C
D
E
F, G
H
I, J, K, L, M, N, O, P, Q
R
S
T
U
V
W, X, Y, Z

=SORTBY(class,RANDARRAY(COUNTA(class)))

RANDARRAY(1000,2,1,6,1)

=RANDARRAY(1000,2,1,6,1)

=SORT(UNIQUE(dice))

Ted 76,Jan 82,Mildred 91,Frank 64
=TEXTSPLIT(15," ",",")

Ted 76,Jan 82,Mildred 91,Frank 64
=SORT(TEXTSPLIT(IS," ",","),2,-1)

Ted 76,Jan 82,Mildred 91,Frank 64
=TEXTSPLIT(I5," ",",")

=TEXTSPLIT(G12,"x",,,1)

=TEXTJOIN("*",,Student&","&Score)

=TEXTSPLIT(D4,",","*")

=TOCOL(G6:J17)

=SORT(UNIQUE(TOCOL(G6:J17,,1)))

=SORT(UNIQUE(TOCOL(G6:117,,1)))

Function Arguments ? X

VLOOKUP

]

Danny Chrissy  Brett Rosa Conor
Conor Brett Nydia Chrissy Robin

Bennie Rob Danny Conor Nancy

Cesar
Melodi
Sherman
Kaye
Shannan
Deloise
Abel
Sona

Aaberg  Nathalie Aaberg
Daquino Hai Daquino
Mccance Joslyn Mccance
Moatz August Moatz
Abbamont: Letty Abbamonte
Corradino Raye Corradino
Lenertz  Princess Lenertz
Haroutunia Ethel Haroutunian
Hemken Raven Hemken
Bruna Modesta Bruna
Oliven Rosann Oliven
Musni Eilene Musni
Castano Cesar Castano
Havermale Melodi Havermale
Arduini  Sherman Arduini
Loyborg Kaye Loyborg
Fairchild Shannan Fairchild
Naughton Deloise Naughton
Librizzi  Abel Librizzi
Haberer  Sona Haberer

Nathalie Aaberg  Raven Hemken Shannan Fairchild Emilio Arkema Alycia Buford

Hai Daquino Modesta Bruna Deloise Naughton Cecila Leverton Judi Cheairs
Joslyn Mccance Rosann Oliven Abel Librizzi Shemeka Kitten Jamey Colosi
August Moatz Eilene Musni Sona Haberer Noel Jelle Felicita Coluccio
Letty Abbamonte Cesar Castano Dane Petteway  Lan Pohlson Wai Baracani
Raye Corradino Melodi Havermale Kyra Pehl Lea Grandon

Princess Lenertz  Sherman Arduini  Ginger Muckley  Mariel Oden
Ethel Haroutunian Kaye Loyborg Robbi Clunie Earl Forlivio




image156.jpg
10

10





image157.jpg
=TOCOL(G6:J17)

Mm O N N I W Mm M g O N O N




image158.jpg
WRAPCOLS(SORT(TOCOL(G6:J17)),12)

10
10




image159.jpg
WRAPROWS(SORT(TOCOL(G6:117)),4)

10

10




image160.jpg
Angelina Jolie _;SORTBY(Al:AlO,TEXTAFTER(A1:A10,“ s 1)
Emily Dickinson George Clooney

George Clooney Emily Dickinson
John Paul Sartre Mick Jagger
LeBron James  LeBronJames

Michael Jordan Ricky Lee Jones
Mick Jagger Michael Jordan
Ricky Lee Jones John Paul Sartre
Sandra Bullock  Mmeryl streep

_Angelina Jolie =WRAPCOLS(SORTBY(A1:A10,TEXTAFTER(A1:A10," ",-1)),5)

=UNIQUE(VSTACK(D8:F11,J4:18))

ID Score
Ted 34 56
Jane 56 89
Mary 12 45
Jack 36 78
Jill 87 91
Amy 13 66

Janet 45 81

Ted 34 56

Jane 56 89

Jack 36

Jack 36 78

Jack 36 78
Jill 87 91
Amy 13 66
Name B4 1D HSc re B4 subjeciid Janet a5 8
Ted 56 English
Jane 56 89 Math
Mary 12 45 Soc
Dan 17 82 Poli Sci
=VSTACK(Tablel,Table2)
34 56 English
Jane 56 89 Math
Mary 12 45 Soc
Dan 17 82 Poli Sci
Jack 36 787 #N/A
Jill 87 917 #n/A
Amy 13 667 #N/A

Janet a5 81" #N/A

=IF(VSTACK(Table1,Table2)=0,"",VSTACK(Table1,Table2))

36 78
Jill 87

Janet 45 81
Ted 34 56

Dan 17 82

Country  Salesperson  Order Date  OrderID  Order Amount
France Buchanan 5/27/2019 10249 £ 2,365.76
Mexico Peacock 5/27/2019 10250 £ 3,597.90
UK Peacock 5/29/2019 10251 £ 1,552.60
UK Dodsworth 5/31/2019 10252 £ 896.35
France Leverling 6/1/2019 10253 £ 654.06
Mexico Peacock 6/2/2019 10254 £ 1,444.80
UK King 6/3/2019 10255 £ 517.80
France Peacock 6/8/2019 10256 £ 1,119.90
Canada Davolio 6/9/2019 10257 £ 1,142.03
UK Callahan 6/11/2019 10258 £ 584.00
Mexico Leverling 6/11/2019 10259 £ 100.80
. |France Peacock 6/15/2019 10260 £ 1,504.65
UK Peacock 6/16/2019 10261 £ 448.00
UK Dodsworth 8/7/2019 10262 £ 1,873.80
Canada Leverling 6/17/2019 10263 £ 346.56

=HSTACK(Country,Salesperson,Order_Amount)
Buchanan 2365.76

Mexico Peacock 3597.90
UK Peacock 1552.60
UK Dodsworth 896.35
France Leverling 654.06
Mexico Peacock 1444.80
UK King 517.80
France Peacock 1119.90
Canada Davolio 1142.03
UK Callahan 584.00
Mexico Leverling 100.80
France Peacock 1504.65
UK Peacock 448.00
UK Dodsworth 1873.80

Canada Leverling 346.56

name soC phil |polisci| art |physics| chem
Bill 75 90 89 72 89 79
Dana 55 68 87 47 56 50
Ed 61 38 46 36 88 66
Jack 34 80 81 56 57 64
Jane 66 83 30 72 66 56
Hortense 41 85 53 719 90 45
Paul J1 59 69 61| 100 12
Ted 66 66 70 35 76 91
Ulysses 59 52 100 94 38 31
Wanda 84 97 35 52 75 86

Angelina Jolie _Jolie =HSTACK(TEXTBEFORE(A1:A10," ",-1), TEXTAFTER(A1:A10," ",-1))

Emily Dickinson Emily Dickinson
George Clooney George Clooney
John Paul Sartre John Paul Sartre
LeBron James  LeBron James
Meryl Streep Meryl Streep
Michael Jordan Michael Jordan
Mick Jagger Mick Jagger
Ricky Lee Jones Ricky Lee Jones

Sandra Bullock sandra Bullock

=CHOOSECOLS(all, 1,3,5)

~ Mexico 43612 3597.9
UK 43614 1552.6
UK 43616 896.35
~ France 43617 654.06
~ Mexico 43618 1444.8
UK 43619 517.8
~ France 43624 1119.9
~ Canada 43625  1142.03
UK 43627 584
~ Mexico 43627 100.8
~ France 43631  1504.65

UK 43632 448

UK 43684 1873.8

Peacock
=FILTER(CHOOSECOLS(all, 1,3,5),Salesperson=12)
43612.00 3597.9

UK 43614.00 1552.6
Mexico 43618.00 1444.8
France 43624.00 1118.9
France 43631.00 1504.65
UK 43632.00 448
Mexico 43639.00 3536.6
UK 43654.00 86.5
France 43654.00 155.4
Mexico 43660.00 1170.37
UK 43667.00 80.1
UK 43669.00 1887.6
Canada 43673.00  591.6
Canada 43677.00 349.5

UK 43697.00 516.8

France
=FILTER(CHOOSECOLS(all, 1,3,5),Country=12)
43612.00 2365.76

France 43617.00 654.06
France 43624.00 1119.9
France 43631.00 1504.65
France 43635.00 1101.2
France 43642.00 642.2
France 43654.00 155.4
France 43670.00 60
France 43671.00 210
France 43675.00 2645
France 43689.00 424
France 43698.00 182.4
France 43704.00 288
France 43708.00 164.4

France 43708.00 982




image183.jpg
Jack 36 78
Jill 87 91
Amy 13 66
Name B4 1D HSc re B4 subjeciid Janet a5 8
Ted 56 English
Jane 56 89 Math
Mary 12 45 Soc
Dan 17 82 Poli Sci
=VSTACK(Tablel,Table2)
34 56 English
Jane 56 89 Math
Mary 12 45 Soc
Dan 17 82 Poli Sci
Jack 36 787 #N/A
Jill 87 917 #n/A
Amy 13 667 #N/A

Janet a5 81" #N/A

ame RdID v ore R4 bjecihd Janet 45 8
Ted 34 56 English
Jane 56 89 Math
Mary 12 45 Soc =CHOOSECOLS(VSTACK(Table1,Table2),1,2,3)
Dan 17 82 Poli Sci Ted 34 56

Jack 36 78

=CHOOSEROWS(all, 1,2,3,4,5)

Buchanan 43612 10248 2365.76
Mexico Peacock 43612 10250 35979
UK Peacock 43614 10251 15526
UK Dodsworth 43616 10252 896.35

France Leverling 43617 10253 654.06

Country Order Date SalespersonOrderID

Order Amount

France 5/27/2019 Buchanan 10249 £ 2,365.76
Mexico  5/27/2019 Peacock 10250 £ 3,597.90
UK 5/29/2019 Peacock 10251 £ 1,552.60
UK 5/31/2019 Dodsworth 10252 £ 896.35
France 6/1/2019 Leverling 10253 £ 654.06
Mexico 6/2/2019 Peacock 10254 £ 1,444.80
UK 6/3/2019 King 10255 £ 517.80
France 6/8/2019 Peacock 10256 £ 1,119.90
Canada 6/9/2019 Davolio 10257 £ 1,142.03
UK 6/11/2019 Callahan 10258 £ 584.00
Mexico  6/11/2019 Leverling 10259 £ 100.80
France @ 6/15/2019 Peacock 10260 £ 1,504.65
UK 6/16/2019 Peacock 10261 £ 448.00
UK 8/7/2019 Dodsworth 10262 £ 1,873.80
Canada 6/17/2019 Leverling 10263 £ 346.56

\Angelina Jolie
'Emily Dickinson

}George Clooney =TAKE(names,6)
John Paul Sartre

1 LeBron James Emily Dickinson
| Meryl Streep George Clooney
I Michael Jordan John Paul Sartre
'Mick Jagger LeBron James
'Ricky Lee Jones Meryl Streep

'Sandra Bullock

Sandra Bullock

=TAKE(names,-3)

Ricky Lee Jones

Angelina Jolie
Emily Dickinson

George Clooney =DROP(names,3)
|John Paul Sartre

LeBron James LeBron James

Meryl Streep Meryl Streep

Michael Jordan Michael Jordan

Mick Jagger Mick Jagger

Ricky Lee Jones Ricky Lee Jones

Sandra Bullock Sandra Bullock

=SORT(FILTER(all, RANK(Order_Amount,Order_Amount)<=10),5,-1) =TAKE(SORT(all,5,-1),10)

Fuller 12/30/2020 10880  16387.5 Fuller 44195 10880 163875

__Mexico Davolio 2/17/2021 10979 15810 Mexico Davolio 44244 10979 15810
_ Canada King 3/14/2021 11042 12615.05 Canada King 44269 11042 12615.1
__Mexico Dodsworth 1/10/2021 10902 11380 Mexico Dodswortl 44206 10902 11380
~ Canada  Peacock 12/15/2019 10432 111884 Canada Peacock 43814 10432 111884
UK Leverling 11/30/2020 10821 10952.84 UK Leverling 44165 10821 109528
UK Leverling 1/12/2021 10905 10835.24 UK Leverling 44208 10905 10835.2
| Canada Leverling 2/6/2020 10487 10495.6 Canada Leverling 43867 10487 104956
UK Leverling 4/30/2020 10572 101%1.7 UK Leverling 43951 10572 101917

_ France Fuller 9/8/2020 10715 10164.8 France Fuller 44082 10715 10164.8

=TAKE(SORT(CHOOSECOLS(all,2,5),2,-1),10)

16387.50
~ Davolio 15810.00
~ King 12615.05
| Dodsworth 11380.00
~ Peacock 11188.40

~ Leverling 10952.84
~ Leverling 10835.24
~ Leverling 10495.60
~ Leverling 10191.70

Fuller 10164.80

=TAKE(SORTBY(SEQUENCE(S50),RANDARRAY(50)),10)

=TAKE(SORT(all,5,-1), ROWS(all)*0.15)

Fuller

44195

43814

44208

44082
43930

43813

43923
43750
44187

10880
10979
11042
10902
10432
10821
10905
10487
10572
10715
10549
10379
10430
11035
10542
10365
10865

16387.5
15810
12615.1
11380
11188.4
10952.8
10835.2
10495.6
10191.7

9921.3
92109
9194.56
8902.5
8623.45
8593.28
8446.45

name 1§ 3 5 8
[gill 87 47 39 64 41 30 86 100-.| 47 64 8 87  100|=DROP(SORT(B2:2,,1),,2)
Dana 76 39 570 48 92 72 93 99
Ed 65 95 76 50] 100] 80 69 88
Jack 4 68 61 78 90 39 38 56
Jane 95 74 57 88 76 63 7 32
Hortense 30 48 68 95 72 52 65 56
Paul 32 87| 43 96 53 72 42 9
Ted 86 39 30 47 91 35 49 91
Ulysses 99 38 50 99 92 75 56 50
Wanda 49 91 67 96| 46| 48 90 35
Jack 87 39 47 97 55 70 77 33





image199.jpg
name

8

Bill

87

47

39

64

41

30

86

100

h=AVERAGE(DROP(SORT(32:12,,,1),,2))

name D 8
Bill 87 47 39 64 41 30 86 100
Dana 76 39 57 48 92 12 93 99
Ed 65 95 76 50 100 80 69 88
Jack 42 68 61 78 90 39 38 56
|Jane 95 74 57 88 76 63 Zl 32
Hortense 30 48 68 95 72 52 65 56
|Paul 32 87 43 96 53 72 42 94
Ted 86 39 30 47 91 35 49 91
Ulysses 99 38 50 99 92 75 56 50
|Wanda 49 91 67 96 46 48 90 35
Jack 87 39 47 97 55 70 77 33

=AVERAGE(DROP(SORT(B2:12,,,1),,2))
81.5 =AVERAGE(DROP(SORT(B3:13,,,1),,2))
84.667 =AVERAGE(DROP(SORT(BA4:14,,,1),,2))
65.833 =AVERAGE(DROP(SORT(B5:15,,,1),,2))
77.833 =AVERAGE(DROP(SORT(B6:16,,,1),,2))
68 =AVERAGE(DROP(SORT(B7:17,,,1),,2))
74.167 =AVERAGE(DROP(SORT(BS:18,,,1),,2))
67.167 =AVERAGE(DROP(SORT(B9:19,,,1),,2))
78.5 =AVERAGE(DROP(SORT(B10:110,,,1),,2))
73.5 =AVERAGE(DROP(SORT(B11:111,,,1),,2))
72.167 =AVERAGE(DROP(SORT(B12:112,,,1),,2))

=EXPAND(D9:E12,,3)

32" #n/A

=EXPAND(DS:E12,,3,"no data")
- 34 no data
Jane 56 no data
Mary 12 no data
Dan 17 no data

=VSTACK(J5:L8,EXPAND(DS:E12,,3,"no data"))

Jack | 3% 7

Jill 87 81
Amy 13 66
Janet 45 81
Ted 34 no data
Jane 56 no data
Mary 12 no data

Dan 17 no data

=VSTACK(J5:L8,EXPAND(DS:E12,,3))

Jack | 3% 78

3ill 87 81
Amy 13 66
Janet 4s 81
Ted 34" #N/A
Jane 56 #N/A
Mary 12: #N/A

Dan 17 #N/A

